See ChangeLog: Thu Jul 22 20:03:03 CEST 1999 Werner Koch
[gnupg.git] / configure.in
1 dnl
2 dnl Configure template for GNUPG
3 dnl
4 dnl (Process this file with autoconf to produce a configure script.)
5 AC_REVISION($Revision$)dnl
6
7 dnl Must reset CDPATH so that bash's cd does not print to stdout
8 CDPATH=
9
10 AC_PREREQ(2.13)
11 AC_INIT(g10/g10.c)
12 AC_CONFIG_AUX_DIR(scripts)
13 AM_CONFIG_HEADER(config.h)
14
15
16 VERSION=`cat $srcdir/VERSION`
17 PACKAGE=gnupg
18 ALL_LINGUAS="de es_ES fr it pl pt_BR ru"
19 static_modules="sha1 md5 rmd160"
20 AC_SUBST(VERSION)
21 AC_SUBST(PACKAGE)
22 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
23 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
24
25 MODULES_IN_CIPHER=`awk '/# MODULES: / { for(i=3;i<=NF;i++) print $i}' \
26                                                 $srcdir/cipher/Makefile.am`
27
28 dnl
29 dnl  Check for random module options
30 dnl
31 dnl  Fixme: get the list of available modules from MODULES_IN_CIPHER
32 dnl         and check against this list
33
34 AC_MSG_CHECKING([which static random module to use])
35 AC_ARG_ENABLE(static-rnd,
36     [  --enable-static-rnd=[egd|unix|linux|none]  ],
37 [use_static_rnd=$enableval], [use_static_rnd=default] )
38
39 if test "$use_static_rnd" = no; then
40     use_static_rnd=default
41 fi
42
43 case "$use_static_rnd" in
44     egd | linux | unix | none | default )
45       AC_MSG_RESULT($use_static_rnd)
46       ;;
47     * )
48       AC_MSG_RESULT(invalid argument)
49       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
50       ;;
51 esac
52
53 dnl
54 dnl See whether the user wants to disable checking for /dev/random
55
56 AC_MSG_CHECKING([whether use of /dev/random is requested])
57 AC_ARG_ENABLE(dev-random,
58 [  --disable-dev-random    disable the use of dev random],
59     try_dev_random=$enableval, try_dev_random=yes)
60 AC_MSG_RESULT($try_dev_random)
61
62
63 dnl
64 dnl  Check other options
65 dnl
66
67 AC_MSG_CHECKING([whether use of extensions is requested])
68 AC_ARG_ENABLE(dynload,
69 [  --disable-dynload       disable use of extensions],
70     try_dynload=$enableval, try_dynload=yes)
71 AC_MSG_RESULT($try_dynload)
72
73 AC_MSG_CHECKING([whether assembler modules are requested])
74 AC_ARG_ENABLE(asm,
75 [  --disable-asm           do not use assembler modules],
76      try_asm_modules=$enableval, try_asm_modules=yes)
77 AC_MSG_RESULT($try_asm_modules)
78
79 AC_MSG_CHECKING([whether memory debugging is requested])
80 AC_ARG_ENABLE(m-debug,
81 [  --enable-m-debug        enable debugging of memory allocation],
82 use_m_debug=$enableval, use_m_debug=no)
83 AC_MSG_RESULT($use_m_debug)
84 if test "$use_m_debug" = yes; then
85     AC_DEFINE(M_DEBUG)
86     use_m_guard=yes
87 else
88     AC_MSG_CHECKING([whether memory guard is requested])
89     AC_ARG_ENABLE(m-guard,
90     [  --enable-m-guard        enable memory guard facility],
91     use_m_guard=$enableval, use_m_guard=no)
92     AC_MSG_RESULT($use_m_guard)
93 fi
94 if test "$use_m_guard" = yes ; then
95     AC_DEFINE(M_GUARD)
96 fi
97
98
99 AC_MSG_CHECKING([whether included zlib is requested])
100 AC_ARG_WITH(included-zlib,
101     [  --with-included-zlib    use the zlib code included here],
102 [g10_force_zlib=yes], [g10_force_zlib=no] )
103 AC_MSG_RESULT($g10_force_zlib)
104
105 dnl
106 dnl Check wether we want to compile libgcrypt
107 dnl
108 AC_MSG_CHECKING([whether compilation of libgcrypt is requested])
109 AC_ARG_ENABLE(libgcrypt,
110     [  --enable-libgcrypt      compile the libgcrypt [default=no]],
111 [compile_libgcrypt="$enableval"],[compile_libgcrypt=no])
112 AC_MSG_RESULT($compile_libgcrypt)
113 if test x$compile_libgcrypt = xyes ; then
114     if test -f $srcdir/gcrypt/gcrypt.h; then
115         :
116     else
117         compile_libgcrypt=no
118         AC_MSG_WARN([[
119 *** LIBGCRYPT is not yet ready for public testing.
120 *** Maybe you have more luck with the next release of GnuPG]])
121     fi
122 fi
123 AM_CONDITIONAL(COMPILE_LIBGCRYPT, test x$compile_libgcrypt = xyes)
124
125
126 dnl
127 dnl Check whether we want to use Linux capabilities
128 dnl
129 AC_MSG_CHECKING([whether use of capabilities is requested])
130 AC_ARG_WITH(capabilities,
131     [  --with-capabilities     use linux capabilities [default=no]],
132 [use_capabilities="$withval"],[use_capabilities=no])
133 AC_MSG_RESULT($use_capabilities)
134
135
136 AM_MAINTAINER_MODE
137
138 dnl Checks for programs.
139
140 AC_CANONICAL_SYSTEM
141 AC_ARG_PROGRAM
142 AC_PROG_MAKE_SET
143 AM_SANITY_CHECK
144 missing_dir=`cd $ac_aux_dir && pwd`
145 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
146 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
147 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
148 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
149 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
150 AC_PROG_CC
151 AC_PROG_CPP
152 AC_ISC_POSIX
153 AC_PROG_INSTALL
154 AC_PROG_AWK
155 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
156 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
157
158
159 dnl
160 dnl Build shared libraries only when compilation of libgcrypt
161 dnl has been requested
162 dnl
163 AM_DISABLE_SHARED
164 enable_shared="$compile_libgcrypt"
165 AM_PROG_LIBTOOL
166
167
168 MPI_OPT_FLAGS=""
169 if test "$GCC" = yes; then
170     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
171 fi
172
173
174 try_gettext=yes
175 try_gdbm=yes
176 case "${target}" in
177     i386--mingw32)
178         # special stuff for Windoze NT
179         cross_compiling=yes
180         CC="i386--mingw32-gcc"
181         CPP="i386--mingw32-gcc -E"
182         RANLIB="i386--mingw32-ranlib"
183         ac_cv_have_dev_random=no
184         AC_DEFINE(USE_ONLY_8DOT3)
185         AC_DEFINE(HAVE_DRIVE_LETTERS)
186         AC_DEFINE(HAVE_DOSISH_SYSTEM)
187         try_gettext="no"
188         try_gdbm="no"
189         ;;
190     i386-emx-os2 | i[3456]86-pc-os2*emx )
191         # OS/2 with the EMX environment
192         ac_cv_have_dev_random=no
193         AC_DEFINE(HAVE_DRIVE_LETTERS)
194         AC_DEFINE(HAVE_DOSISH_SYSTEM)
195         try_gettext="no"
196         try_gdbm="no"
197         ;;
198
199     *-*-hpux*)
200         if test -z "$GCC" ; then
201             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
202         fi
203         ;;
204     *-dec-osf4*)
205         if test -z "$GCC" ; then
206             # Suppress all warnings
207             # to get rid of the unsigned/signed char mismatch warnings.
208             CFLAGS="$CFLAGS -w"
209         fi
210         ;;
211     m68k-atari-mint)
212         ;;
213     *)
214        ;;
215 esac
216
217 AC_SUBST(MPI_OPT_FLAGS)
218 GNUPG_SYS_SYMBOL_UNDERSCORE
219 GNUPG_CHECK_PIC
220 GNUPG_CHECK_RDYNAMIC
221 if test "$NO_PIC" = yes; then
222     try_dynload=no
223 fi
224
225
226 case "${target}" in
227     i386--mingw32)
228         PRINTABLE_OS_NAME="MingW32"
229         ;;
230     i386-emx-os2 | i[3456]86-pc-os2*emx )
231         PRINTABLE_OS_NAME="OS/2"
232         ;;
233     *-linux*)
234         PRINTABLE_OS_NAME="GNU/Linux"
235         ;;
236     *)
237         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
238         ;;
239 esac
240 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME")
241
242 dnl  Fixme: Are these the best flags for OpenBSD????
243 dnl (I have removed the -lc from * ...CFLAGS for test purposes.)
244 case "${target}" in
245     *-openbsd*)
246         NAME_OF_DEV_RANDOM="/dev/srandom"
247         NAME_OF_DEV_URANDOM="/dev/urandom"
248         DYNLINK_MOD_CFLAGS="-shared -rdynamic -fpic -Wl,-Bshareable -Wl,-x"
249         ;;
250     *)
251         NAME_OF_DEV_RANDOM="/dev/random"
252         NAME_OF_DEV_URANDOM="/dev/urandom"
253         DYNLINK_MOD_CFLAGS="-shared $CFLAGS_PIC"
254         ;;
255 esac
256 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM")
257 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM")
258 AC_SUBST(MPI_OPT_FLAGS)
259
260
261 dnl Checks for libraries.
262
263 if test "$try_gettext" = yes; then
264 AM_GNU_GETTEXT
265 else
266 USE_NLS=no
267 USE_INCLUDED_LIBINTL=no
268 AC_SUBST(USE_NLS)
269 AC_SUBST(USE_INCLUDED_LIBINTL)
270 fi
271
272 dnl
273 dnl There are lot of misconfigured systems.  We include
274 dnl gdbm support only if the lib and the header is installed.
275 dnl
276 if test "$try_gdbm" = yes; then
277 AC_CHECK_HEADERS(gdbm.h)
278 if test "$ac_cv_header_gdbm_h" = yes ; then
279   AC_CHECK_LIB(gdbm,gdbm_firstkey)
280 fi
281 fi
282
283
284 dnl Solaris needs -lsocket and -lnsl. Unisys system includes
285 dnl gethostbyname in libsocket but needs libnsl for socket.
286 AC_CHECK_LIB(nsl, gethostbyname)
287 AC_CHECK_LIB(socket, socket, ac_need_libsocket=1, ac_try_nsl=1)
288 if test x$ac_need_libsocket = x1; then
289     LIBS="$LIBS -lsocket"
290 fi
291 if test x$ac_try_nsl = x1; then
292     AC_CHECK_LIB(nsl, gethostbyname, ac_need_libnsl=1)
293     if test x$ac_need_libnsl = x1
294     then
295         LIBS="$LIBS -lnsl"
296     fi
297 fi
298
299
300 if test "$try_dynload" = yes ; then
301   AC_CHECK_LIB(dl,dlopen)
302   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
303     AC_DEFINE(USE_DYNAMIC_LINKING)
304     AC_DEFINE(HAVE_DL_DLOPEN)
305     DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
306     use_gnupg_extensions=yes
307   else
308     AC_CHECK_LIB(c,dlopen)
309     if test "$ac_cv_lib_c_dlopen" = "yes"; then
310       AC_DEFINE(USE_DYNAMIC_LINKING)
311       AC_DEFINE(HAVE_DL_DLOPEN)
312       DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
313       use_gnupg_extensions=yes
314     else
315       AC_CHECK_LIB(dld,shl_load)
316       if test "$ac_cv_lib_dld_shl_load" = "yes"; then
317         AC_DEFINE(USE_DYNAMIC_LINKING)
318         AC_DEFINE(HAVE_DL_SHL_LOAD)
319         DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
320         use_gnupg_extensions=yes
321 dnl -----------------
322 dnl  DLD is not ready for use. So I better disable this test
323 dnl
324 dnl    AC_CHECK_LIB(dld,dld_link)
325 dnl    if test "$ac_cv_lib_dld_dld_link" = "yes"; then
326 dnl      AC_DEFINE(USE_DYNAMIC_LINKING)
327 dnl      AC_DEFINE(HAVE_DLD_DLD_LINK)
328 dnl      DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
329 dnl      use_gnupg_extensions=yes
330 dnl ---------------
331       fi
332     fi
333   fi
334 else
335   AC_MSG_CHECKING(for dynamic loading)
336   DYNLINK_LDFLAGS=
337   DYNLINK_MOD_CFLAGS=
338   use_gnupg_extensions=no
339   AC_MSG_RESULT(has been disabled)
340 fi
341
342 AM_CONDITIONAL(ENABLE_GNUPG_EXTENSIONS, test "$use_gnupg_extensions" = yes )
343 AC_SUBST(DYNLINK_LDFLAGS)
344 AC_SUBST(DYNLINK_MOD_CFLAGS)
345
346
347 dnl Checks for header files.
348 AC_HEADER_STDC
349 AC_CHECK_HEADERS(unistd.h langinfo.h)
350
351
352 dnl Checks for typedefs, structures, and compiler characteristics.
353 AC_C_CONST
354 AC_C_INLINE
355 AC_TYPE_SIZE_T
356 AC_TYPE_SIGNAL
357 AC_DECL_SYS_SIGLIST
358
359 GNUPG_CHECK_ENDIAN
360
361
362 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
363 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
364 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
365 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
366 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
367
368 AC_CHECK_SIZEOF(unsigned short, 2)
369 AC_CHECK_SIZEOF(unsigned int, 4)
370 AC_CHECK_SIZEOF(unsigned long, 4)
371
372 if test "$ac_cv_sizeof_unsigned_short" = "0" \
373    || test "$ac_cv_sizeof_unsigned_int" = "0" \
374    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
375     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
376 fi
377
378
379
380 dnl Checks for library functions.
381 AC_FUNC_VPRINTF
382 AC_CHECK_FUNCS(strerror stpcpy strlwr stricmp tcgetattr rand strtoul mmap)
383 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime setrlimit)
384 AC_CHECK_FUNCS(memicmp atexit raise getpagesize strftime nl_langinfo)
385
386 GNUPG_CHECK_MLOCK
387
388 dnl
389 dnl Check whether we can use Linux capabilities as requested
390 dnl
391 if test "$use_capabilities" = "yes" ; then
392 use_capabilities=no
393 AC_CHECK_HEADERS(sys/capability.h)
394 if test "$ac_cv_header_sys_capability_h" = "yes" ; then
395   AC_CHECK_LIB(cap, cap_init, ac_need_libcap=1)
396   if test "$ac_cv_lib_cap_cap_init" = "yes"; then
397      AC_DEFINE(USE_CAPABILITIES)
398      use_capabilities=yes
399   fi
400 fi
401 if test "$use_capabilities" = "no" ; then
402     AC_MSG_WARN([[
403 *** The use of capabilities on this system is not possible.
404 *** You need a recent Linux kernel and some patches:
405 ***   fcaps-2.2.9-990610.patch      (kernel patch for 2.2.9)
406 ***   fcap-module-990613.tar.gz     (kernel module)
407 ***   libcap-1.92.tar.gz            (user mode library and utilities)
408 *** And you have to configure the kernel with CONFIG_VFS_CAP_PLUGIN
409 *** set (filesystems menu). Be warned: This code is *really* ALPHA.]])
410 fi
411 fi
412
413
414 GNUPG_CHECK_IPC
415 if test "$ac_cv_header_sys_shm_h" = "yes"; then
416   AC_DEFINE(USE_SHM_COPROCESSING)
417 fi
418
419 dnl
420 dnl check whether we have a random device
421 dnl
422 if test "$try_dev_random" = yes ; then
423     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
424     [if test -c "$NAME_OF_DEV_RANDOM" && test -c "$NAME_OF_DEV_URANDOM" ; then
425       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
426     if test "$ac_cv_have_dev_random" = yes; then
427         AC_DEFINE(HAVE_DEV_RANDOM)
428     fi
429 else
430     AC_MSG_CHECKING(for random device)
431     ac_cv_have_dev_random=no
432     AC_MSG_RESULT(has been disabled)
433 fi
434
435 dnl
436 dnl and whether this device supports ioctl
437 dnl (Note, that we should do a real test here)
438 dnl
439 if test "$ac_cv_have_dev_random" = yes ; then
440     AC_CHECK_HEADERS(linux/random.h)
441     AC_CACHE_CHECK(for random device ioctl, ac_cv_have_dev_random_ioctl,
442       [ if test "$ac_cv_header_linux_random_h" = yes ; then
443           ac_cv_have_dev_random_ioctl=yes;
444         else
445           ac_cv_have_dev_random_ioctl=no;
446         fi
447       ])
448     if test "$ac_cv_have_dev_random_ioctl" = yes; then
449         AC_DEFINE(HAVE_DEV_RANDOM_IOCTL)
450     fi
451 fi
452
453
454 dnl
455 dnl Figure out the default linkage mode for cipher modules
456 dnl
457 dnl (We always need a static rmd160)
458 static_modules="$static_modules rmd160"
459 if test "$use_static_rnd" = default; then
460   if test "$ac_cv_have_dev_random" = yes; then
461       static_modules="$static_modules rndlinux"
462   else
463       case "${target}" in
464           i386--mingw32)
465               static_modules="$static_modules rndw32"
466               ;;
467           i386-emx-os2|i[3456]86-pc-os2*emx)
468               static_modules="$static_modules rndos2"
469               ;;
470           m68k-atari-mint)
471               static_modules="$static_modules rndatari"
472               ;;
473           *)
474               static_modules="$static_modules rndunix"
475              ;;
476       esac
477   fi
478 else
479   if test "$use_static_rnd" = none; then
480     :
481   else
482     static_modules="$static_modules rnd$use_static_rnd"
483   fi
484 fi
485
486 dnl
487 dnl Parse the modules list and build the list
488 dnl of static and dymically linked modules
489 dnl
490 STATIC_CIPHER_NAMES=""
491 STATIC_CIPHER_OBJS=""
492 DYNAMIC_CIPHER_MODS=""
493 GNUPG_MSG_PRINT([dynamically linked cipher modules:])
494 for name in $MODULES_IN_CIPHER; do
495     x="no"
496     for i in $static_modules; do
497         if test "$name" = "$i" ; then
498             x="yes"
499         fi
500     done;
501     if test $x = yes; then
502         STATIC_CIPHER_NAMES="$STATIC_CIPHER_NAMES $name"
503         STATIC_CIPHER_OBJS="$STATIC_CIPHER_OBJS $name.lo"
504     else
505         DYNAMIC_CIPHER_MODS="$DYNAMIC_CIPHER_MODS $name"
506         GNUPG_MSG_PRINT([$name])
507     fi
508 done
509 AC_MSG_RESULT()
510 AC_SUBST(STATIC_CIPHER_OBJS)
511 AC_SUBST(STATIC_CIPHER_NAMES)
512 AC_SUBST(DYNAMIC_CIPHER_MODS)
513
514 dnl
515 dnl And build the constructor file
516 dnl
517
518 test -d cipher || mkdir cipher
519 cat <<G10EOF >cipher/construct.c
520 /* automatically generated by configure - do not edit */
521
522 G10EOF
523 GNUPG_MSG_PRINT([statically linked cipher modules:])
524 for name in $STATIC_CIPHER_NAMES; do
525     echo "void ${name}_constructor(void);" >>cipher/construct.c
526     GNUPG_MSG_PRINT([$name])
527 done
528 AC_MSG_RESULT()
529 cat <<G10EOF >>cipher/construct.c
530
531 void
532 cipher_modules_constructor(void)
533 {
534     static int done = 0;
535     if( done )
536         return;
537     done = 1;
538
539 G10EOF
540 for name in $STATIC_CIPHER_NAMES; do
541     echo "   ${name}_constructor();" >>cipher/construct.c
542 done
543 echo '}' >>cipher/construct.c
544
545
546
547
548 dnl
549 dnl Figure how to link the cipher modules
550 dnl
551 AC_SUBST(STATIC_CIPHER_OBJS)
552 AC_SUBST(DYNAMIC_CIPHER_MODS)
553
554
555 dnl setup assembler stuff
556 AC_MSG_CHECKING(for mpi assembler functions)
557 if test -f $srcdir/mpi/config.links ; then
558     . $srcdir/mpi/config.links
559     GNUPG_LINK_FILES($mpi_ln_src, $mpi_ln_dst)
560     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
561     ac_cv_mpi_sflags="$mpi_sflags"
562     ac_cv_mpi_config_done="yes"
563     AC_MSG_RESULT(done)
564 else
565     AC_MSG_RESULT(failed)
566     AC_MSG_ERROR([mpi/config.links missing!])
567 fi
568 MPI_EXTRA_ASM_OBJS=""
569 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
570 GNUPG_MSG_PRINT([mpi extra asm functions:])
571 for i in $ac_cv_mpi_extra_asm_modules; do
572     GNUPG_MSG_PRINT([$i])
573     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.lo"
574 done
575 AC_MSG_RESULT()
576 fi
577 AC_SUBST(MPI_EXTRA_ASM_OBJS)
578 MPI_SFLAGS="$ac_cv_mpi_sflags"
579 AC_SUBST(MPI_SFLAGS)
580
581 dnl Do we have zlib? Must do it here because Solaris failed
582 dnl when compiling a conftest (due to the "-lz" from LIBS).
583 use_local_zlib=yes
584 if test "$g10_force_zlib" = "yes"; then
585   :
586 else
587   AC_CHECK_HEADERS(zlib.h)
588   if test "$ac_cv_header_zlib_h" = yes ; then
589       AC_CHECK_LIB(z,deflateInit2_,use_local_zlib=no,:)
590   fi
591 fi
592
593 if test "$use_local_zlib" = yes ; then
594     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
595     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
596     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
597     ZLIBS="../zlib/libzlib.a"
598 else
599     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
600     ZLIBS=
601     LIBS="-lz $LIBS"
602 fi
603 AC_SUBST(ZLIBS)
604
605
606 changequote(,)dnl
607 tmp_pat='[a-zA-Z]'
608 changequote([,])dnl
609 if echo "$VERSION" | grep $tmp_pat >/dev/null ; then
610     AC_DEFINE(IS_DEVELOPMENT_VERSION)
611 fi
612
613 GNUPG_DO_LINK_FILES
614
615
616 AC_OUTPUT_COMMANDS([
617 cat >g10defs.tmp <<G10EOF
618 /* Generated automatically by configure */
619 #ifdef HAVE_DRIVE_LETTERS
620   #define G10_LOCALEDIR "c:/lib/gnupg/locale"
621   #define GNUPG_LIBDIR  "c:/lib/gnupg"
622   #define GNUPG_DATADIR "c:/lib/gnupg"
623 #else
624   #define G10_LOCALEDIR "${prefix}/${DATADIRNAME}/locale"
625   #define GNUPG_LIBDIR  "${libdir}/gnupg"
626   #define GNUPG_DATADIR "${datadir}/gnupg"
627 #endif
628 G10EOF
629 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
630     echo "g10defs.h is unchanged"
631     rm -f g10defs.tmp
632 else
633     rm -f g10defs.h
634     mv g10defs.tmp g10defs.h
635     echo "g10defs.h created"
636 fi
637 ],[
638 prefix=$prefix
639 exec_prefix=$exec_prefix
640 libdir=$libdir
641 datadir=$datadir
642 DATADIRNAME=$DATADIRNAME
643 ])
644
645
646 AC_OUTPUT([
647 Makefile
648 intl/Makefile
649 po/Makefile.in
650 util/Makefile
651 mpi/Makefile
652 cipher/Makefile
653 g10/Makefile
654 doc/Makefile
655 tools/Makefile
656 zlib/Makefile
657 checks/Makefile
658 gcrypt/Makefile
659 ])
660
661 dnl *-*wedit:notab*-*  Please keep this as the last line.