See ChangeLog: Sat Jun 26 13:54:43 CEST 1999 Werner Koch
[gnupg.git] / configure.in
1 dnl
2 dnl Configure template for GNUPG
3 dnl
4 dnl (Process this file with autoconf to produce a configure script.)
5 AC_REVISION($Revision$)dnl
6
7 dnl Must reset CDPATH so that bash's cd does not print to stdout
8 CDPATH=
9
10 AC_PREREQ(2.13)
11 AC_INIT(g10/g10.c)
12 AC_CONFIG_AUX_DIR(scripts)
13 AM_CONFIG_HEADER(config.h)
14
15
16 VERSION=`cat $srcdir/VERSION`
17 PACKAGE=gnupg
18 ALL_LINGUAS="de es_ES fr it pl pt_BR ru"
19 static_modules="sha1 md5 rmd160"
20 AC_SUBST(VERSION)
21 AC_SUBST(PACKAGE)
22 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
23 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
24
25 MODULES_IN_CIPHER=`awk '/# MODULES: / { for(i=3;i<=NF;i++) print $i}' \
26                                                 $srcdir/cipher/Makefile.am`
27
28 dnl
29 dnl  Check for random module options
30 dnl
31 dnl  Fixme: get the list of available modules from MODULES_IN_CIPHER
32 dnl         and check against this list
33
34 AC_MSG_CHECKING([which static random module to use])
35 AC_ARG_ENABLE(static-rnd,
36     [  --enable-static-rnd=[egd|unix|linux|none]  ],
37 [use_static_rnd=$enableval], [use_static_rnd=default] )
38
39 if test "$use_static_rnd" = no; then
40     use_static_rnd=default
41 fi
42
43 case "$use_static_rnd" in
44     egd | linux | unix | none | default )
45       AC_MSG_RESULT($use_static_rnd)
46       ;;
47     * )
48       AC_MSG_RESULT(invalid argument)
49       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
50       ;;
51 esac
52
53 dnl
54 dnl See whether the user wants to disable checking for /dev/random
55
56 AC_MSG_CHECKING([whether use of /dev/random is requested])
57 AC_ARG_ENABLE(dev-random,
58 [  --disable-dev-random    disable the use of dev random],
59     try_dev_random=$enableval, try_dev_random=yes)
60 AC_MSG_RESULT($try_dev_random)
61
62
63 dnl
64 dnl  Check other options
65 dnl
66
67 AC_MSG_CHECKING([whether use of extensions is requested])
68 AC_ARG_ENABLE(dynload,
69 [  --disable-dynload       disable use of extensions],
70     try_dynload=$enableval, try_dynload=yes)
71 AC_MSG_RESULT($try_dynload)
72
73 AC_MSG_CHECKING([whether assembler modules are requested])
74 AC_ARG_ENABLE(asm,
75 [  --disable-asm           do not use assembler modules],
76      try_asm_modules=$enableval, try_asm_modules=yes)
77 AC_MSG_RESULT($try_asm_modules)
78
79 AC_MSG_CHECKING([whether memory debugging is requested])
80 AC_ARG_ENABLE(m-debug,
81 [  --enable-m-debug        enable debugging of memory allocation],
82 use_m_debug=$enableval, use_m_debug=no)
83 AC_MSG_RESULT($use_m_debug)
84 if test "$use_m_debug" = yes; then
85     AC_DEFINE(M_DEBUG)
86     use_m_guard=yes
87 else
88     AC_MSG_CHECKING([whether memory guard is requested])
89     AC_ARG_ENABLE(m-guard,
90     [  --enable-m-guard        enable memory guard facility],
91     use_m_guard=$enableval, use_m_guard=no)
92     AC_MSG_RESULT($use_m_guard)
93 fi
94 if test "$use_m_guard" = yes ; then
95     AC_DEFINE(M_GUARD)
96 fi
97
98
99 AC_MSG_CHECKING([whether included zlib is requested])
100 AC_ARG_WITH(included-zlib,
101     [  --with-included-zlib    use the zlib code included here],
102 [g10_force_zlib=yes], [g10_force_zlib=no] )
103 AC_MSG_RESULT($g10_force_zlib)
104
105 dnl This does not work because automakes install tareget still needs libtool
106 dnl dnl
107 dnl dnl Check wether we want to compile libgcrypt
108 dnl dnl
109 dnl AC_MSG_CHECKING([whether compilation of libgcrypt is requested])
110 dnl AC_ARG_ENABLE(libgcrypt,
111 dnl     [  --enable-libgcrypt      compile the libgcrypt [default=no]],
112 dnl [compile_libgcrypt="$enableval"],[compile_libgcrypt=no])
113 dnl AM_CONDITIONAL(COMPILE_LIBGCRYPT, test x$compile_libgcrypt = xyes)
114 dnl AC_MSG_RESULT($compile_libgcrypt)
115
116
117 dnl Checks for programs.
118
119 AC_CANONICAL_SYSTEM
120 AC_ARG_PROGRAM
121 AC_PROG_MAKE_SET
122 AM_SANITY_CHECK
123 missing_dir=`cd $ac_aux_dir && pwd`
124 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
125 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
126 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
127 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
128 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
129 AC_PROG_CC
130 AC_PROG_CPP
131 AC_ISC_POSIX
132 AC_PROG_INSTALL
133 AC_PROG_RANLIB
134 AC_CHECK_PROG(DOCBOOK_TO_MAN, docbook-to-man, yes, no)
135 AM_CONDITIONAL(HAVE_DOCBOOK_TO_MAN, test "$ac_cv_prog_DOCBOOK_TO_MAN" = yes)
136
137
138
139 dnl if test x$compile_libgcrypt = xyes; then
140 dnl    dnl Don't default to build shared libs
141 dnl    AM_DISABLE_SHARED
142 dnl    AM_PROG_LIBTOOL
143 dnl fi
144
145
146 MPI_OPT_FLAGS=""
147 if test "$GCC" = yes; then
148     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
149 fi
150
151
152 try_gettext=yes
153 try_gdbm=yes
154 case "${target}" in
155     i386--mingw32)
156         # special stuff for Windoze NT
157         cross_compiling=yes
158         CC="i386--mingw32-gcc"
159         CPP="i386--mingw32-gcc -E"
160         RANLIB="i386--mingw32-ranlib"
161         ac_cv_have_dev_random=no
162         AC_DEFINE(USE_ONLY_8DOT3)
163         AC_DEFINE(HAVE_DRIVE_LETTERS)
164         AC_DEFINE(HAVE_DOSISH_SYSTEM)
165         try_gettext="no"
166         try_gdbm="no"
167         ;;
168     i386-emx-os2 | i[3456]86-pc-os2emx )
169         # OS/2 with the EMX environment
170         ac_cv_have_dev_random=no
171         AC_DEFINE(HAVE_DRIVE_LETTERS)
172         AC_DEFINE(HAVE_DOSISH_SYSTEM)
173         try_gettext="no"
174         try_gdbm="no"
175         ;;
176     *-*-hpux*)
177         if test -z "$GCC" ; then
178             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
179         fi
180         ;;
181     *-dec-osf4*)
182         if test -z "$GCC" ; then
183             # Suppress all warnings
184             # to get rid of the unsigned/signed char mismatch warnings.
185             CFLAGS="$CFLAGS -w"
186         fi
187         ;;
188     m68k-atari-mint)
189         ;;
190     *)
191        ;;
192 esac
193
194 AC_SUBST(MPI_OPT_FLAGS)
195 GNUPG_SYS_SYMBOL_UNDERSCORE
196 GNUPG_CHECK_PIC
197 GNUPG_CHECK_RDYNAMIC
198 if test "$NO_PIC" = yes; then
199     try_dynload=no
200 fi
201
202
203 case "${target}" in
204     i386--mingw32)
205         PRINTABLE_OS_NAME="MingW32"
206         ;;
207     i386-emx-os2 | i[3456]86-pc-os2emx)
208         PRINTABLE_OS_NAME="OS/2"
209         ;;
210     *-linux*)
211         PRINTABLE_OS_NAME="GNU/Linux"
212         ;;
213     *)
214         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
215         ;;
216 esac
217 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME")
218
219 dnl  Fixme: Are these the best flags for OpenBSD????
220 dnl (I have removed the -lc from * ...CFLAGS for test purposes.)
221 case "${target}" in
222     *-openbsd*)
223         NAME_OF_DEV_RANDOM="/dev/srandom"
224         NAME_OF_DEV_URANDOM="/dev/urandom"
225         DYNLINK_MOD_CFLAGS="-shared -rdynamic -fpic -Wl,-Bshareable -Wl,-x"
226         ;;
227     *)
228         NAME_OF_DEV_RANDOM="/dev/random"
229         NAME_OF_DEV_URANDOM="/dev/urandom"
230         DYNLINK_MOD_CFLAGS="-shared $CFLAGS_PIC"
231         ;;
232 esac
233 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM")
234 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM")
235 AC_SUBST(MPI_OPT_FLAGS)
236
237
238 dnl Checks for libraries.
239
240 if test "$try_gettext" = yes; then
241 AM_GNU_GETTEXT
242 else
243 USE_NLS=no
244 USE_INCLUDED_LIBINTL=no
245 AC_SUBST(USE_NLS)
246 AC_SUBST(USE_INCLUDED_LIBINTL)
247 fi
248
249 dnl
250 dnl There are lot of misconfigured systems.  We include
251 dnl gdbm support only if the lib and the header is installed.
252 dnl
253 if test "$try_gdbm" = yes; then
254 AC_CHECK_HEADERS(gdbm.h)
255 if test "$ac_cv_header_gdbm_h" = yes ; then
256   AC_CHECK_LIB(gdbm,gdbm_firstkey)
257 fi
258 fi
259
260
261 dnl Solaris needs -lsocket and -lnsl. Unisys system includes
262 dnl gethostbyname in libsocket but needs libnsl for socket.
263 AC_CHECK_LIB(nsl, gethostbyname)
264 AC_CHECK_LIB(socket, socket, ac_need_libsocket=1, ac_try_nsl=1)
265 if test x$ac_need_libsocket = x1; then
266     LIBS="$LIBS -lsocket"
267 fi
268 if test x$ac_try_nsl = x1; then
269     AC_CHECK_LIB(nsl, gethostbyname, ac_need_libnsl=1)
270     if test x$ac_need_libnsl = x1
271     then
272         LIBS="$LIBS -lnsl"
273     fi
274 fi
275
276
277 if test "$try_dynload" = yes ; then
278   AC_CHECK_LIB(dl,dlopen)
279   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
280     AC_DEFINE(USE_DYNAMIC_LINKING)
281     AC_DEFINE(HAVE_DL_DLOPEN)
282     DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
283     use_gnupg_extensions=yes
284   else
285     AC_CHECK_LIB(c,dlopen)
286     if test "$ac_cv_lib_c_dlopen" = "yes"; then
287       AC_DEFINE(USE_DYNAMIC_LINKING)
288       AC_DEFINE(HAVE_DL_DLOPEN)
289       DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
290       use_gnupg_extensions=yes
291     else
292       AC_CHECK_LIB(dld,shl_load)
293       if test "$ac_cv_lib_dld_shl_load" = "yes"; then
294         AC_DEFINE(USE_DYNAMIC_LINKING)
295         AC_DEFINE(HAVE_DL_SHL_LOAD)
296         DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
297         use_gnupg_extensions=yes
298 dnl -----------------
299 dnl  DLD is not ready for use. So I better disable this test
300 dnl
301 dnl    AC_CHECK_LIB(dld,dld_link)
302 dnl    if test "$ac_cv_lib_dld_dld_link" = "yes"; then
303 dnl      AC_DEFINE(USE_DYNAMIC_LINKING)
304 dnl      AC_DEFINE(HAVE_DLD_DLD_LINK)
305 dnl      DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
306 dnl      use_gnupg_extensions=yes
307 dnl ---------------
308       fi
309     fi
310   fi
311 else
312   AC_MSG_CHECKING(for dynamic loading)
313   DYNLINK_LDFLAGS=
314   DYNLINK_MOD_CFLAGS=
315   use_gnupg_extensions=no
316   AC_MSG_RESULT(has been disabled)
317 fi
318
319 AM_CONDITIONAL(ENABLE_GNUPG_EXTENSIONS, test "$use_gnupg_extensions" = yes )
320 AC_SUBST(DYNLINK_LDFLAGS)
321 AC_SUBST(DYNLINK_MOD_CFLAGS)
322
323
324 dnl Checks for header files.
325 AC_HEADER_STDC
326 AC_CHECK_HEADERS(unistd.h langinfo.h)
327
328
329 dnl Checks for typedefs, structures, and compiler characteristics.
330 AC_C_CONST
331 AC_C_INLINE
332 AC_TYPE_SIZE_T
333 AC_TYPE_SIGNAL
334 AC_DECL_SYS_SIGLIST
335
336 GNUPG_CHECK_ENDIAN
337
338
339 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
340 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
341 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
342 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
343 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
344
345 AC_CHECK_SIZEOF(unsigned short, 2)
346 AC_CHECK_SIZEOF(unsigned int, 4)
347 AC_CHECK_SIZEOF(unsigned long, 4)
348
349 if test "$ac_cv_sizeof_unsigned_short" = "0" \
350    || test "$ac_cv_sizeof_unsigned_int" = "0" \
351    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
352     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
353 fi
354
355
356
357 dnl Checks for library functions.
358 AC_FUNC_VPRINTF
359 AC_CHECK_FUNCS(strerror stpcpy strlwr tcgetattr rand strtoul mmap)
360 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime setrlimit)
361 AC_CHECK_FUNCS(memicmp atexit raise getpagesize strftime nl_langinfo)
362
363 GNUPG_CHECK_MLOCK
364
365 GNUPG_CHECK_IPC
366 if test "$ac_cv_header_sys_shm_h" = "yes"; then
367   AC_DEFINE(USE_SHM_COPROCESSING)
368 fi
369
370 dnl
371 dnl check whether we have a random device
372 dnl
373 if test "$try_dev_random" = yes ; then
374     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
375     [if test -c "$NAME_OF_DEV_RANDOM" && test -c "$NAME_OF_DEV_URANDOM" ; then
376       ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
377     if test "$ac_cv_have_dev_random" = yes; then
378         AC_DEFINE(HAVE_DEV_RANDOM)
379     fi
380 else
381     AC_MSG_CHECKING(for random device)
382     ac_cv_have_dev_random=no
383     AC_MSG_RESULT(has been disabled)
384 fi
385
386 dnl
387 dnl and whether this device supports ioctl
388 dnl (Note, that we should do a real test here)
389 dnl
390 if test "$ac_cv_have_dev_random" = yes ; then
391     AC_CHECK_HEADERS(linux/random.h)
392     AC_CACHE_CHECK(for random device ioctl, ac_cv_have_dev_random_ioctl,
393       [ if test "$ac_cv_header_linux_random_h" = yes ; then
394           ac_cv_have_dev_random_ioctl=yes;
395         else
396           ac_cv_have_dev_random_ioctl=no;
397         fi
398       ])
399     if test "$ac_cv_have_dev_random_ioctl" = yes; then
400         AC_DEFINE(HAVE_DEV_RANDOM_IOCTL)
401     fi
402 fi
403
404
405 dnl
406 dnl Figure out the default linkage mode for cipher modules
407 dnl
408 dnl (We always need a static rmd160)
409 static_modules="$static_modules rmd160"
410 if test "$use_static_rnd" = default; then
411   if test "$ac_cv_have_dev_random" = yes; then
412       static_modules="$static_modules rndlinux"
413   else
414       case "${target}" in
415           i386--mingw32)
416               static_modules="$static_modules rndw32"
417               ;;
418           i386-emx-os2|i[3456]86-pc-os2emx)
419               static_modules="$static_modules rndos2"
420               ;;
421           m68k-atari-mint)
422               static_modules="$static_modules rndatari"
423               ;;
424           *)
425               static_modules="$static_modules rndunix"
426              ;;
427       esac
428   fi
429 else
430   if test "$use_static_rnd" = none; then
431     :
432   else
433     static_modules="$static_modules rnd$use_static_rnd"
434   fi
435 fi
436
437 dnl
438 dnl Parse the modules list and build the list
439 dnl of static and dymically linked modules
440 dnl
441 STATIC_CIPHER_NAMES=""
442 STATIC_CIPHER_OBJS=""
443 DYNAMIC_CIPHER_MODS=""
444 GNUPG_MSG_PRINT([dynamically linked cipher modules:])
445 for name in $MODULES_IN_CIPHER; do
446     x="no"
447     for i in $static_modules; do
448         if test "$name" = "$i" ; then
449             x="yes"
450         fi
451     done;
452     if test $x = yes; then
453         STATIC_CIPHER_NAMES="$STATIC_CIPHER_NAMES $name"
454         STATIC_CIPHER_OBJS="$STATIC_CIPHER_OBJS $name.o"
455     else
456         DYNAMIC_CIPHER_MODS="$DYNAMIC_CIPHER_MODS $name"
457         GNUPG_MSG_PRINT([$name])
458     fi
459 done
460 AC_MSG_RESULT()
461 AC_SUBST(STATIC_CIPHER_OBJS)
462 AC_SUBST(STATIC_CIPHER_NAMES)
463 AC_SUBST(DYNAMIC_CIPHER_MODS)
464
465 dnl
466 dnl And build the constructor file
467 dnl
468
469 test -d cipher || mkdir cipher
470 cat <<G10EOF >cipher/construct.c
471 /* automatically generated by configure - do not edit */
472
473 G10EOF
474 GNUPG_MSG_PRINT([statically linked cipher modules:])
475 for name in $STATIC_CIPHER_NAMES; do
476     echo "void ${name}_constructor(void);" >>cipher/construct.c
477     GNUPG_MSG_PRINT([$name])
478 done
479 AC_MSG_RESULT()
480 cat <<G10EOF >>cipher/construct.c
481
482 void
483 cipher_modules_constructor(void)
484 {
485     static int done = 0;
486     if( done )
487         return;
488     done = 1;
489
490 G10EOF
491 for name in $STATIC_CIPHER_NAMES; do
492     echo "   ${name}_constructor();" >>cipher/construct.c
493 done
494 echo '}' >>cipher/construct.c
495
496
497
498
499 dnl
500 dnl Figure how to link the cipher modules
501 dnl
502 AC_SUBST(STATIC_CIPHER_OBJS)
503 AC_SUBST(DYNAMIC_CIPHER_MODS)
504
505
506 dnl setup assembler stuff
507 AC_MSG_CHECKING(for mpi assembler functions)
508 if test -f $srcdir/mpi/config.links ; then
509     . $srcdir/mpi/config.links
510     GNUPG_LINK_FILES($mpi_ln_src, $mpi_ln_dst)
511     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
512     ac_cv_mpi_sflags="$mpi_sflags"
513     ac_cv_mpi_config_done="yes"
514     AC_MSG_RESULT(done)
515 else
516     AC_MSG_RESULT(failed)
517     AC_MSG_ERROR([mpi/config.links missing!])
518 fi
519 MPI_EXTRA_ASM_OBJS=""
520 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
521 GNUPG_MSG_PRINT([mpi extra asm functions:])
522 for i in $ac_cv_mpi_extra_asm_modules; do
523     GNUPG_MSG_PRINT([$i])
524     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
525 done
526 AC_MSG_RESULT()
527 fi
528 AC_SUBST(MPI_EXTRA_ASM_OBJS)
529 MPI_SFLAGS="$ac_cv_mpi_sflags"
530 AC_SUBST(MPI_SFLAGS)
531
532 dnl Do we have zlib? Must do it here because Solaris failed
533 dnl when compiling a conftest (due to the "-lz" from LIBS).
534 use_local_zlib=yes
535 if test "$g10_force_zlib" = "yes"; then
536   :
537 else
538   AC_CHECK_HEADERS(zlib.h)
539   if test "$ac_cv_header_zlib_h" = yes ; then
540       AC_CHECK_LIB(z,deflateInit2_,use_local_zlib=no,:)
541   fi
542 fi
543
544 if test "use_local_zlib" = yes ; then
545     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
546     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
547     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
548     ZLIBS="../zlib/libzlib.a"
549 else
550     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
551     ZLIBS=
552     LIBS="-lz $LIBS"
553 fi
554 AC_SUBST(ZLIBS)
555
556
557 changequote(,)dnl
558 tmp_pat='[a-zA-Z]'
559 changequote([,])dnl
560 if echo "$VERSION" | grep $tmp_pat >/dev/null ; then
561     AC_DEFINE(IS_DEVELOPMENT_VERSION)
562 fi
563
564 GNUPG_DO_LINK_FILES
565
566
567 AC_OUTPUT_COMMANDS([
568 cat >g10defs.tmp <<G10EOF
569 /* Generated automatically by configure */
570 #ifdef HAVE_DRIVE_LETTERS
571   #define G10_LOCALEDIR "c:/lib/gnupg/locale"
572   #define GNUPG_LIBDIR  "c:/lib/gnupg"
573   #define GNUPG_DATADIR "c:/lib/gnupg"
574 #else
575   #define G10_LOCALEDIR "${prefix}/${DATADIRNAME}/locale"
576   #define GNUPG_LIBDIR  "${libdir}/gnupg"
577   #define GNUPG_DATADIR "${datadir}/gnupg"
578 #endif
579 G10EOF
580 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
581     echo "g10defs.h is unchanged"
582     rm -f g10defs.tmp
583 else
584     rm -f g10defs.h
585     mv g10defs.tmp g10defs.h
586     echo "g10defs.h created"
587 fi
588 ],[
589 prefix=$prefix
590 exec_prefix=$exec_prefix
591 libdir=$libdir
592 datadir=$datadir
593 DATADIRNAME=$DATADIRNAME
594 ])
595
596
597 AC_OUTPUT([
598 Makefile
599 intl/Makefile
600 po/Makefile.in
601 util/Makefile
602 mpi/Makefile
603 cipher/Makefile
604 g10/Makefile
605 doc/Makefile
606 tools/Makefile
607 zlib/Makefile
608 checks/Makefile
609 gcrypt/Makefile
610 ])
611
612 dnl *-*wedit:notab*-*  Please keep this as the last line.