*** empty log message ***
[gnupg.git] / configure.in
1 dnl
2 dnl Configure template for GNUPG
3 dnl
4 dnl (Process this file with autoconf to produce a configure script.)
5
6 AC_INIT(g10/g10.c)
7 AC_CONFIG_AUX_DIR(scripts)
8 AM_CONFIG_HEADER(config.h)
9
10
11 if test "x$exec_prefix" = xNONE ; then
12     if test "x$prefix" = xNONE ; then
13         g10_prefix="$ac_default_prefix"
14     else
15         g10_prefix="$prefix"
16     fi
17 else
18     g10_prefix="$exec_prefix"
19 fi
20
21
22 VERSION=`cat $srcdir/VERSION`
23 PACKAGE=gnupg
24 ALL_LINGUAS="en de it fr"
25 AC_SUBST(VERSION)
26 AC_SUBST(PACKAGE)
27 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
28 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
29
30 AC_ARG_ENABLE(dev-random,
31 [  --disable-dev-random    disable the use of dev random],
32     try_dev_random=$enableval, try_dev_random=yes)
33
34 AC_ARG_ENABLE(dynload,
35 [  --disable-dynload       disable dynamic loading],
36     try_dynload=$enableval, try_dynload=yes)
37
38 AC_MSG_CHECKING([whether memory debugging is requested])
39 AC_ARG_ENABLE(m-debug,
40 [  --enable-m-debug        enable debugging of memory allocation],
41 use_m_debug=$enableval, use_m_debug=no)
42 AC_MSG_RESULT($use_m_debug)
43 if test "$use_m_debug" = yes; then
44     AC_DEFINE(M_DEBUG)
45     use_m_guard=yes
46 else
47     AC_MSG_CHECKING([whether memory guard is requested])
48     AC_ARG_ENABLE(m-guard,
49     [  --disable-m-guard       disable memory guard facility],
50     use_m_guard=$enableval, use_m_guard=yes)
51     AC_MSG_RESULT($use_m_guard)
52 fi
53 if test "$use_m_guard" = yes ; then
54     AC_DEFINE(M_GUARD)
55     CFLAGS="-g -Wall"
56 else
57     CFLAGS="-O2 -Wall"
58 fi
59
60
61 AC_MSG_CHECKING([whether included zlib is requested])
62 AC_ARG_WITH(included-zlib,
63     [  --with-included-zlib    use the zlib code included here],
64 [g10_force_zlib=yes], [g10_force_zlib=no] )
65 AC_MSG_RESULT($g10_force_zlib)
66
67
68 AC_CANONICAL_SYSTEM
69 WK_CHECK_CACHE
70
71 dnl Checks for programs.
72
73 AC_PROG_MAKE_SET
74 AC_ARG_PROGRAM
75
76 missing_dir=`cd $ac_aux_dir && pwd`
77 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
78 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
79 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
80 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
81 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
82 AC_ISC_POSIX
83
84 case "${target}" in
85     i386--mingw32)
86         # special stuff for Windoze NT
87         cross_compiling=yes
88         CC="i386--mingw32-gcc"
89         CPP="i386--mingw32-gcc -E"
90         RANLIB="i386--mingw32-ranlib"
91         ac_cv_have_dev_random=no
92         AC_DEFINE(USE_RAND_W32)
93         GNUPG_LIBDIR="c:/lib/gnupg"
94         ;;
95     *)
96 AC_PROG_RANLIB
97 AC_PROG_INSTALL
98 AC_PROG_CC
99 AC_PROG_CPP
100         AC_DEFINE(USE_RAND_UNIX)
101         GNUPG_LIBDIR="$g10_prefix/lib/gnupg"
102        ;;
103 esac
104 AC_DEFINE_UNQUOTED(GNUPG_LIBDIR, "$GNUPG_LIBDIR")
105
106 case "${target}" in
107     i386--mingw32)
108         PRINTABLE_OS_NAME="MingW32"
109         ;;
110     *-linux*)
111         PRINTABLE_OS_NAME="GNU/Linux"
112         ;;
113     *)
114         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
115         ;;
116 esac
117 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME")
118
119 dnl Checks for libraries.
120
121
122 if test "$try_dynload" = yes ; then
123 AC_CHECK_LIB(dl,dlopen)
124 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
125   AC_DEFINE(USE_DYNAMIC_LINKING)
126   AC_DEFINE(HAVE_DL_DLOPEN)
127   DYNLINK_LDFLAGS=-rdynamic
128   use_gnupg_extensions=yes
129 else
130 AC_CHECK_LIB(dld,dld_link)
131 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
132   AC_DEFINE(USE_DYNAMIC_LINKING)
133   AC_DEFINE(HAVE_DLD_DLD_LINK)
134   DYNLINK_LDFLAGS=-rdynamic
135   use_gnupg_extensions=yes
136 fi
137 fi
138 else
139   AC_MSG_CHECKING(for dynamic loading)
140   DYNLINK_LDFLAGS=
141   use_gnupg_extensions=no
142   AC_MSG_RESULT(has been disabled)
143 fi
144
145 AM_CONDITIONAL(ENABLE_GNUPG_EXTENSIONS, test "$use_gnupg_extensions" = yes )
146 AC_SUBST(DYNLINK_LDFLAGS)
147
148 dnl Checks for header files.
149 AC_HEADER_STDC
150 AC_CHECK_HEADERS(unistd.h)
151
152
153 dnl Checks for typedefs, structures, and compiler characteristics.
154 AC_C_CONST
155 AC_C_INLINE
156 AC_TYPE_SIZE_T
157 AC_TYPE_SIGNAL
158 AC_DECL_SYS_SIGLIST
159
160 WK_CHECK_ENDIAN
161
162
163 WK_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
164 WK_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
165 WK_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
166 WK_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
167 WK_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
168
169 AC_CHECK_SIZEOF(unsigned short, 2)
170 AC_CHECK_SIZEOF(unsigned int, 4)
171 AC_CHECK_SIZEOF(unsigned long, 4)
172
173 if test "$ac_cv_sizeof_unsigned_short" = "0" \
174    || test "$ac_cv_sizeof_unsigned_int" = "0" \
175    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
176     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
177 fi
178
179
180
181 dnl Checks for library functions.
182 AC_FUNC_VPRINTF
183 AC_CHECK_FUNCS(strerror stpcpy strlwr tcgetattr rand strtoul mlock mmap)
184 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime setrlimit)
185
186 WK_CHECK_IPC
187 if test "$ac_cv_header_sys_shm_h" = "yes"; then
188   AC_DEFINE(USE_SHM_COPROCESSING)
189 fi
190
191 dnl check whether we have a random device
192 if test "$try_dev_random" = yes ; then
193 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
194 [if test -c /dev/random && test -c /dev/urandom ; then
195   ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
196 if test "$ac_cv_have_dev_random" = yes; then
197     AC_DEFINE(HAVE_DEV_RANDOM)
198 fi
199 else
200     AC_MSG_CHECKING(for random device)
201     ac_cv_have_dev_random=no
202     AC_MSG_RESULT(has been disabled)
203 fi
204
205
206
207
208 dnl setup assembler stuff
209 AC_MSG_CHECKING(for mpi assembler functions)
210 if test -f $srcdir/mpi/config.links ; then
211     . $srcdir/mpi/config.links
212     WK_LINK_FILES($mpi_ln_src, $mpi_ln_dst)
213     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
214     ac_cv_mpi_config_done="yes"
215     AC_MSG_RESULT(done)
216 else
217     AC_MSG_RESULT(failed)
218     AC_MSG_ERROR([mpi/config.links missing!])
219 fi
220 MPI_EXTRA_ASM_OBJS=""
221 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
222 WK_MSG_PRINT([mpi extra asm functions:])
223 for i in $ac_cv_mpi_extra_asm_modules; do
224     WK_MSG_PRINT([$i])
225     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
226 done
227 AC_MSG_RESULT()
228 fi
229 AC_SUBST(MPI_EXTRA_ASM_OBJS)
230
231 dnl Do we have zlib? Must do it here because Solaris failed
232 dnl when compiling a conftest (due to the "-lz" from LIBS).
233 if test "$g10_force_zlib" = "yes"; then
234     ZLIBS="../zlib/libzlib.a"
235     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
236     WK_LINK_FILES(zlib/zlib.h, zlib.h )
237     WK_LINK_FILES(zlib/zconf.h, zconf.h )
238 else
239 AC_CHECK_HEADERS(zlib.h)
240 if test "$ac_cv_header_zlib_h" = yes ; then
241     LIBS="$LIBS -lz"
242     ZLIBS=
243     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
244 else
245     ZLIBS="../zlib/libzlib.a"
246     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
247     WK_LINK_FILES(zlib/zlib.h, zlib.h )
248     WK_LINK_FILES(zlib/zconf.h, zconf.h )
249 fi
250 fi
251 AC_SUBST(ZLIBS)
252
253
254 AM_GNU_GETTEXT
255 G10_LOCALEDIR="$g10_prefix/$DATADIRNAME/locale"
256 AC_SUBST(G10_LOCALEDIR)
257 AC_DEFINE_UNQUOTED(G10_LOCALEDIR, "$G10_LOCALEDIR")
258 WK_LINK_FILES($nls_cv_header_libgt, $nls_cv_header_intl )
259
260 WK_DO_LINK_FILES
261
262 AC_OUTPUT([
263 Makefile
264 intl/Makefile
265 po/Makefile.in
266 util/Makefile
267 mpi/Makefile
268 cipher/Makefile
269 g10/Makefile
270 doc/Makefile
271 tools/Makefile
272 zlib/Makefile
273 checks/Makefile
274 ],[echo timestamp >stamp-h; sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
275