See ChangeLog: Sat May 22 22:47:26 CEST 1999 Werner Koch
[gnupg.git] / configure.in
1 dnl
2 dnl Configure template for GNUPG
3 dnl
4 dnl (Process this file with autoconf to produce a configure script.)
5 AC_REVISION($Revision$)dnl
6
7 dnl Must reset CDPATH so that bash's cd does not print to stdout
8 CDPATH=
9
10 AC_PREREQ(2.13)
11 AC_INIT(g10/g10.c)
12 AC_CONFIG_AUX_DIR(scripts)
13 AM_CONFIG_HEADER(config.h)
14
15
16 VERSION=`cat $srcdir/VERSION`
17 PACKAGE=gnupg
18 ALL_LINGUAS="de es_ES fr it pl pt_BR ru"
19 static_modules="sha1 md5 rmd160"
20 AC_SUBST(VERSION)
21 AC_SUBST(PACKAGE)
22 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
23 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
24
25 MODULES_IN_CIPHER=`awk '/# MODULES: / { for(i=3;i<=NF;i++) print $i}' \
26                                                 $srcdir/cipher/Makefile.am`
27
28 dnl
29 dnl  Check for random module options
30 dnl
31 dnl  Fixme: get the list of available modules from MODULES_IN_CIPHER
32 dnl         and check against this list
33
34 AC_MSG_CHECKING([which static random module to use])
35 AC_ARG_ENABLE(static-rnd,
36     [  --enable-static-rnd=[egd|unix|linux|none]  ],
37 [use_static_rnd=$enableval], [use_static_rnd=default] )
38
39 if test "$use_static_rnd" = no; then
40     use_static_rnd=default
41 fi
42
43 case "$use_static_rnd" in
44     egd | linux | unix | none | default )
45       AC_MSG_RESULT($use_static_rnd)
46       ;;
47     * )
48       AC_MSG_RESULT(invalid argument)
49       AC_MSG_ERROR(there is no random module rnd$use_static_rnd)
50       ;;
51 esac
52
53 dnl
54 dnl See whether the user wants to disable checking for /dev/random
55
56 AC_MSG_CHECKING([whether use of /dev/random is requested])
57 AC_ARG_ENABLE(dev-random,
58 [  --disable-dev-random    disable the use of dev random],
59     try_dev_random=$enableval, try_dev_random=yes)
60 AC_MSG_RESULT($try_dev_random)
61
62
63 dnl
64 dnl  Check other options
65 dnl
66
67 AC_MSG_CHECKING([whether use of extensions is requested])
68 AC_ARG_ENABLE(dynload,
69 [  --disable-dynload       disable use of extensions],
70     try_dynload=$enableval, try_dynload=yes)
71 AC_MSG_RESULT($try_dynload)
72
73 AC_MSG_CHECKING([whether assembler modules are requested])
74 AC_ARG_ENABLE(asm,
75 [  --disable-asm           do not use assembler modules],
76      try_asm_modules=$enableval, try_asm_modules=yes)
77 AC_MSG_RESULT($try_asm_modules)
78
79 AC_MSG_CHECKING([whether memory debugging is requested])
80 AC_ARG_ENABLE(m-debug,
81 [  --enable-m-debug        enable debugging of memory allocation],
82 use_m_debug=$enableval, use_m_debug=no)
83 AC_MSG_RESULT($use_m_debug)
84 if test "$use_m_debug" = yes; then
85     AC_DEFINE(M_DEBUG)
86     use_m_guard=yes
87 else
88     AC_MSG_CHECKING([whether memory guard is requested])
89     AC_ARG_ENABLE(m-guard,
90     [  --enable-m-guard        enable memory guard facility],
91     use_m_guard=$enableval, use_m_guard=no)
92     AC_MSG_RESULT($use_m_guard)
93 fi
94 if test "$use_m_guard" = yes ; then
95     AC_DEFINE(M_GUARD)
96 fi
97
98
99 AC_MSG_CHECKING([whether included zlib is requested])
100 AC_ARG_WITH(included-zlib,
101     [  --with-included-zlib    use the zlib code included here],
102 [g10_force_zlib=yes], [g10_force_zlib=no] )
103 AC_MSG_RESULT($g10_force_zlib)
104
105
106 dnl Checks for programs.
107
108 AC_CANONICAL_SYSTEM
109 AC_ARG_PROGRAM
110 AC_PROG_MAKE_SET
111 AM_SANITY_CHECK
112 missing_dir=`cd $ac_aux_dir && pwd`
113 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
114 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
115 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
116 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
117 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
118 AC_PROG_CC
119 AC_PROG_CPP
120 AC_ISC_POSIX
121 AC_PROG_INSTALL
122 AC_PROG_RANLIB
123
124 MPI_OPT_FLAGS=""
125 if test "$GCC" = yes; then
126     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
127 fi
128
129
130 try_gettext=yes
131 try_gdbm=yes
132 case "${target}" in
133     i386--mingw32)
134         # special stuff for Windoze NT
135         cross_compiling=yes
136         CC="i386--mingw32-gcc"
137         CPP="i386--mingw32-gcc -E"
138         RANLIB="i386--mingw32-ranlib"
139         ac_cv_have_dev_random=no
140         AC_DEFINE(USE_ONLY_8DOT3)
141         AC_DEFINE(HAVE_DRIVE_LETTERS)
142         AC_DEFINE(HAVE_DOSISH_SYSTEM)
143         try_gettext="no"
144         try_gdbm="no"
145         ;;
146     i386-emx-os2 | i[3456]86-pc-os2emx )
147         # OS/2 with the EMX environment
148         ac_cv_have_dev_random=no
149         AC_DEFINE(HAVE_DRIVE_LETTERS)
150         AC_DEFINE(HAVE_DOSISH_SYSTEM)
151         try_gettext="no"
152         try_gdbm="no"
153         ;;
154     *-*-hpux*)
155         if test -z "$GCC" ; then
156             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
157         fi
158         ;;
159     *-dec-osf4*)
160         if test -z "$GCC" ; then
161             # Suppress all warnings
162             # to get rid of the unsigned/signed char mismatch warnings.
163             CFLAGS="$CFLAGS -w"
164         fi
165         ;;
166     m68k-atari-mint)
167         ;;
168     *)
169        ;;
170 esac
171
172 AC_SUBST(MPI_OPT_FLAGS)
173 GNUPG_SYS_SYMBOL_UNDERSCORE
174 GNUPG_CHECK_PIC
175 GNUPG_CHECK_RDYNAMIC
176 if test "$NO_PIC" = yes; then
177     try_dynload=no
178 fi
179
180
181 case "${target}" in
182     i386--mingw32)
183         PRINTABLE_OS_NAME="MingW32"
184         ;;
185     i386-emx-os2 | i[3456]86-pc-os2emx)
186         PRINTABLE_OS_NAME="OS/2"
187         ;;
188     *-linux*)
189         PRINTABLE_OS_NAME="GNU/Linux"
190         ;;
191     *)
192         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
193         ;;
194 esac
195 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME")
196
197 dnl  Fixme: Are these the best flags for OpenBSD????
198 dnl (I have removed the -lc from * ...CFLAGS for test purposes.)
199 case "${target}" in
200     *-openbsd*)
201         NAME_OF_DEV_RANDOM="/dev/srandom"
202         NAME_OF_DEV_URANDOM="/dev/urandom"
203         DYNLINK_MOD_CFLAGS="-shared -rdynamic -fpic -Wl,-Bshareable -Wl,-x"
204         ;;
205     *)
206         NAME_OF_DEV_RANDOM="/dev/random"
207         NAME_OF_DEV_URANDOM="/dev/urandom"
208         DYNLINK_MOD_CFLAGS="-shared $CFLAGS_PIC"
209         ;;
210 esac
211 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM")
212 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM")
213 AC_SUBST(MPI_OPT_FLAGS)
214
215
216 dnl Checks for libraries.
217
218 if test "$try_gettext" = yes; then
219 AM_GNU_GETTEXT
220 fi
221
222 if test "$try_gdbm" = yes; then
223 AC_CHECK_LIB(gdbm,gdbm_firstkey)
224 fi
225
226 dnl Solaris needs -lsocket and -lnsl. Unisys system includes
227 dnl gethostbyname in libsocket but needs libnsl for socket.
228 AC_CHECK_LIB(nsl, gethostbyname)
229 AC_CHECK_LIB(socket, socket, ac_need_libsocket=1, ac_try_nsl=1)
230 if test x$ac_need_libsocket = x1; then
231     LIBS="$LIBS -lsocket"
232 fi
233 if test x$ac_try_nsl = x1; then
234     AC_CHECK_LIB(nsl, gethostbyname, ac_need_libnsl=1)
235     if test x$ac_need_libnsl = x1
236     then
237         LIBS="$LIBS -lnsl"
238     fi
239 fi
240
241
242 if test "$try_dynload" = yes ; then
243   AC_CHECK_LIB(dl,dlopen)
244   if test "$ac_cv_lib_dl_dlopen" = "yes"; then
245     AC_DEFINE(USE_DYNAMIC_LINKING)
246     AC_DEFINE(HAVE_DL_DLOPEN)
247     DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
248     use_gnupg_extensions=yes
249   else
250     AC_CHECK_LIB(c,dlopen)
251     if test "$ac_cv_lib_c_dlopen" = "yes"; then
252       AC_DEFINE(USE_DYNAMIC_LINKING)
253       AC_DEFINE(HAVE_DL_DLOPEN)
254       DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
255       use_gnupg_extensions=yes
256 dnl else
257 dnl
258 dnl  DLD is not ready for use. So I better disable this test
259 dnl
260 dnl    AC_CHECK_LIB(dld,dld_link)
261 dnl    if test "$ac_cv_lib_dld_dld_link" = "yes"; then
262 dnl      AC_DEFINE(USE_DYNAMIC_LINKING)
263 dnl      AC_DEFINE(HAVE_DLD_DLD_LINK)
264 dnl      DYNLINK_LDFLAGS="$CFLAGS_RDYNAMIC"
265 dnl      use_gnupg_extensions=yes
266 dnl    fi
267     fi
268   fi
269 else
270   AC_MSG_CHECKING(for dynamic loading)
271   DYNLINK_LDFLAGS=
272   DYNLINK_MOD_CFLAGS=
273   use_gnupg_extensions=no
274   AC_MSG_RESULT(has been disabled)
275 fi
276
277 AM_CONDITIONAL(ENABLE_GNUPG_EXTENSIONS, test "$use_gnupg_extensions" = yes )
278 AC_SUBST(DYNLINK_LDFLAGS)
279 AC_SUBST(DYNLINK_MOD_CFLAGS)
280
281
282 dnl Checks for header files.
283 AC_HEADER_STDC
284 AC_CHECK_HEADERS(unistd.h langinfo.h)
285
286
287 dnl Checks for typedefs, structures, and compiler characteristics.
288 AC_C_CONST
289 AC_C_INLINE
290 AC_TYPE_SIZE_T
291 AC_TYPE_SIGNAL
292 AC_DECL_SYS_SIGLIST
293
294 GNUPG_CHECK_ENDIAN
295
296
297 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
298 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
299 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
300 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
301 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
302
303 AC_CHECK_SIZEOF(unsigned short, 2)
304 AC_CHECK_SIZEOF(unsigned int, 4)
305 AC_CHECK_SIZEOF(unsigned long, 4)
306
307 if test "$ac_cv_sizeof_unsigned_short" = "0" \
308    || test "$ac_cv_sizeof_unsigned_int" = "0" \
309    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
310     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
311 fi
312
313
314
315 dnl Checks for library functions.
316 AC_FUNC_VPRINTF
317 AC_CHECK_FUNCS(strerror stpcpy strlwr tcgetattr rand strtoul mmap)
318 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime setrlimit)
319 AC_CHECK_FUNCS(memicmp atexit raise getpagesize strftime nl_langinfo)
320
321 GNUPG_CHECK_MLOCK
322
323 GNUPG_CHECK_IPC
324 if test "$ac_cv_header_sys_shm_h" = "yes"; then
325   AC_DEFINE(USE_SHM_COPROCESSING)
326 fi
327
328 dnl check whether we have a random device
329 if test "$try_dev_random" = yes ; then
330 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
331 [if test -c "$NAME_OF_DEV_RANDOM" && test -c "$NAME_OF_DEV_URANDOM" ; then
332   ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
333 if test "$ac_cv_have_dev_random" = yes; then
334     AC_DEFINE(HAVE_DEV_RANDOM)
335 fi
336 else
337     AC_MSG_CHECKING(for random device)
338     ac_cv_have_dev_random=no
339     AC_MSG_RESULT(has been disabled)
340 fi
341
342
343 dnl
344 dnl Figure out the default linkage mode for cipher modules
345 dnl
346 dnl (We always need a static rmd160)
347 static_modules="$static_modules rmd160"
348 if test "$use_static_rnd" = default; then
349   if test "$ac_cv_have_dev_random" = yes; then
350       static_modules="$static_modules rndlinux"
351   else
352       case "${target}" in
353           i386--mingw32)
354               static_modules="$static_modules rndw32"
355               ;;
356           i386-emx-os2|i[3456]86-pc-os2emx)
357               static_modules="$static_modules rndos2"
358               ;;
359           m68k-atari-mint)
360               static_modules="$static_modules rndatari"
361               ;;
362           *)
363               static_modules="$static_modules rndunix"
364              ;;
365       esac
366   fi
367 else
368   if test "$use_static_rnd" = none; then
369     :
370   else
371     static_modules="$static_modules rnd$use_static_rnd"
372   fi
373 fi
374
375 dnl
376 dnl Parse the modules list and build the list
377 dnl of static and dymically linked modules
378 dnl
379 STATIC_CIPHER_NAMES=""
380 STATIC_CIPHER_OBJS=""
381 DYNAMIC_CIPHER_MODS=""
382 GNUPG_MSG_PRINT([dynamically linked cipher modules:])
383 for name in $MODULES_IN_CIPHER; do
384     x="no"
385     for i in $static_modules; do
386         if test "$name" = "$i" ; then
387             x="yes"
388         fi
389     done;
390     if test $x = yes; then
391         STATIC_CIPHER_NAMES="$STATIC_CIPHER_NAMES $name"
392         STATIC_CIPHER_OBJS="$STATIC_CIPHER_OBJS $name.o"
393     else
394         DYNAMIC_CIPHER_MODS="$DYNAMIC_CIPHER_MODS $name"
395         GNUPG_MSG_PRINT([$name])
396     fi
397 done
398 AC_MSG_RESULT()
399 AC_SUBST(STATIC_CIPHER_OBJS)
400 AC_SUBST(STATIC_CIPHER_NAMES)
401 AC_SUBST(DYNAMIC_CIPHER_MODS)
402
403 dnl
404 dnl And build the constructor file
405 dnl
406
407 test -d cipher || mkdir cipher
408 cat <<G10EOF >cipher/construct.c
409 /* automatically generated by configure - do not edit */
410
411 G10EOF
412 GNUPG_MSG_PRINT([statically linked cipher modules:])
413 for name in $STATIC_CIPHER_NAMES; do
414     echo "void ${name}_constructor(void);" >>cipher/construct.c
415     GNUPG_MSG_PRINT([$name])
416 done
417 AC_MSG_RESULT()
418 cat <<G10EOF >>cipher/construct.c
419
420 void
421 cipher_modules_constructor(void)
422 {
423     static int done = 0;
424     if( done )
425         return;
426     done = 1;
427
428 G10EOF
429 for name in $STATIC_CIPHER_NAMES; do
430     echo "   ${name}_constructor();" >>cipher/construct.c
431 done
432 echo '}' >>cipher/construct.c
433
434
435
436
437 dnl
438 dnl Figure how to link the cipher modules
439 dnl
440 AC_SUBST(STATIC_CIPHER_OBJS)
441 AC_SUBST(DYNAMIC_CIPHER_MODS)
442
443
444 dnl setup assembler stuff
445 AC_MSG_CHECKING(for mpi assembler functions)
446 if test -f $srcdir/mpi/config.links ; then
447     . $srcdir/mpi/config.links
448     GNUPG_LINK_FILES($mpi_ln_src, $mpi_ln_dst)
449     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
450     ac_cv_mpi_sflags="$mpi_sflags"
451     ac_cv_mpi_config_done="yes"
452     AC_MSG_RESULT(done)
453 else
454     AC_MSG_RESULT(failed)
455     AC_MSG_ERROR([mpi/config.links missing!])
456 fi
457 MPI_EXTRA_ASM_OBJS=""
458 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
459 GNUPG_MSG_PRINT([mpi extra asm functions:])
460 for i in $ac_cv_mpi_extra_asm_modules; do
461     GNUPG_MSG_PRINT([$i])
462     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
463 done
464 AC_MSG_RESULT()
465 fi
466 AC_SUBST(MPI_EXTRA_ASM_OBJS)
467 MPI_SFLAGS="$ac_cv_mpi_sflags"
468 AC_SUBST(MPI_SFLAGS)
469
470 dnl Do we have zlib? Must do it here because Solaris failed
471 dnl when compiling a conftest (due to the "-lz" from LIBS).
472 if test "$g10_force_zlib" = "yes"; then
473     ZLIBS="../zlib/libzlib.a"
474     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
475     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
476     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
477 else
478 AC_CHECK_HEADERS(zlib.h)
479 if test "$ac_cv_header_zlib_h" = yes ; then
480     LIBS="$LIBS -lz"
481     ZLIBS=
482     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
483 else
484     ZLIBS="../zlib/libzlib.a"
485     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
486     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
487     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
488 fi
489 fi
490 AC_SUBST(ZLIBS)
491
492 if echo "$VERSION" | grep '[a-zA-Z]' >/dev/null ; then
493     AC_DEFINE(IS_DEVELOPMENT_VERSION)
494 fi
495
496 GNUPG_DO_LINK_FILES
497
498
499 AC_OUTPUT_COMMANDS([
500 cat >g10defs.tmp <<G10EOF
501 /* Generated automatically by configure */
502 #ifdef HAVE_DRIVE_LETTERS
503   #define G10_LOCALEDIR "c:/lib/gnupg/locale"
504   #define GNUPG_LIBDIR  "c:/lib/gnupg"
505   #define GNUPG_DATADIR "c:/lib/gnupg"
506 #else
507   #define G10_LOCALEDIR "${prefix}/${DATADIRNAME}/locale"
508   #define GNUPG_LIBDIR  "${libdir}/gnupg"
509   #define GNUPG_DATADIR "${datadir}/gnupg"
510 #endif
511 G10EOF
512 if cmp -s g10defs.h g10defs.tmp 2>/dev/null; then
513     echo "g10defs.h is unchanged"
514     rm -f g10defs.tmp
515 else
516     rm -f g10defs.h
517     mv g10defs.tmp g10defs.h
518     echo "g10defs.h created"
519 fi
520 ],[
521 prefix=$prefix
522 exec_prefix=$exec_prefix
523 libdir=$libdir
524 datadir=$datadir
525 DATADIRNAME=$DATADIRNAME
526 ])
527
528
529 AC_OUTPUT([
530 Makefile
531 intl/Makefile
532 po/Makefile.in
533 util/Makefile
534 mpi/Makefile
535 cipher/Makefile
536 g10/Makefile
537 doc/Makefile
538 tools/Makefile
539 zlib/Makefile
540 checks/Makefile
541 ])
542
543 dnl *-*wedit:notab*-*  Please keep this as the last line.