release 0.2.3
[gnupg.git] / configure.in
1 dnl
2 dnl Configure template for G10
3 dnl
4 dnl (Process this file with autoconf to produce a configure script.)
5
6 AC_INIT(g10/g10.c)
7 AC_CONFIG_AUX_DIR(scripts)
8 AM_CONFIG_HEADER(config.h)
9
10
11 if test "x$exec_prefix" = xNONE ; then
12     if test "x$prefix" = xNONE ; then
13         g10_prefix="$ac_default_prefix"
14     else
15         g10_prefix="$prefix"
16     fi
17 else
18     g10_prefix="$exec_prefix"
19 fi
20
21
22 VERSION=`cat $srcdir/VERSION`
23 PACKAGE=g10
24 ALL_LINGUAS="de"
25 AC_SUBST(VERSION)
26 AC_SUBST(PACKAGE)
27 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
28 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
29
30 AC_ARG_ENABLE(m-debug,
31 [  --enable-m-debug       Enable debugging of memory allocation])
32 if test "$enableval" = y || test "$enableval" = yes; then
33     AC_DEFINE(M_DEBUG)
34 fi
35
36 dnl Some systems have a broken zlib. "--disable-zlib" avoids it's usage
37 enableval=yes
38 AC_ARG_ENABLE(zlib,
39 [  --disable-zlib         Avoid usage of zlib])
40 if test "$enableval" = y || test "$enableval" = yes; then
41     g10_use_zlib=yes
42 else
43     g10_use_zlib=no
44 fi
45 CFLAGS="-g -Wall"
46
47
48
49 AC_CANONICAL_SYSTEM
50 WK_CHECK_CACHE
51
52 dnl Checks for programs.
53
54 AC_PROG_MAKE_SET
55 AC_ARG_PROGRAM
56
57 missing_dir=`cd $ac_aux_dir && pwd`
58 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
59 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
60 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
61 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
62 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
63
64 case "${target}" in
65     i386--mingw32)
66         # special stuff for Windoze NT
67         cross_compiling=yes
68         CC="i386--mingw32-gcc"
69         CPP="i386--mingw32-gcc -E"
70         RANLIB="i386--mingw32-ranlib"
71         ac_cv_have_dev_random=no
72         ;;
73     *)
74 AC_PROG_RANLIB
75 AC_PROG_INSTALL
76 AC_PROG_CC
77 AC_PROG_CPP
78        ;;
79 esac
80
81
82 dnl Checks for libraries.
83
84 dnl Checks for header files.
85 AC_HEADER_STDC
86 AC_CHECK_HEADERS(unistd.h)
87
88 AM_GNU_GETTEXT
89 G10_LOCALEDIR="$g10_prefix/$DATADIRNAME/locale"
90 AC_SUBST(G10_LOCALEDIR)
91 AC_DEFINE_UNQUOTED(G10_LOCALEDIR, "$G10_LOCALEDIR")
92
93 WK_LINK_FILES($nls_cv_header_libgt, $nls_cv_header_intl )
94
95 dnl Checks for typedefs, structures, and compiler characteristics.
96 AC_C_CONST
97 AC_C_INLINE
98 AC_TYPE_SIZE_T
99
100 WK_CHECK_ENDIAN
101
102
103 WK_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
104 WK_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
105 WK_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
106 WK_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
107 WK_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
108
109 AC_CHECK_SIZEOF(unsigned short, 2)
110 AC_CHECK_SIZEOF(unsigned int, 4)
111 AC_CHECK_SIZEOF(unsigned long, 4)
112
113 if test "$ac_cv_sizeof_unsigned_short" = "0" \
114    || test "$ac_cv_sizeof_unsigned_int" = "0" \
115    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
116     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
117 fi
118
119
120
121 dnl Checks for library functions.
122 AC_FUNC_VPRINTF
123 AC_CHECK_FUNCS(strerror stpcpy strlwr tcgetattr rand strtoul mlock mmap)
124
125
126
127
128 dnl check wether we have a random device
129 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
130 [if test -c /dev/random && test -c /dev/urandom ; then
131   ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
132 if test "$ac_cv_have_dev_random" = yes; then
133     AC_DEFINE(HAVE_DEV_RANDOM)
134 fi
135
136
137 dnl setup assembler stuff
138 AC_MSG_CHECKING(for mpi assembler functions)
139 mpi_config_done="no"
140 AC_CACHE_VAL(ac_cv_mpi_config_done,
141              [ ac_cv_mpi_config_done="$mpi_config_done" ])
142 if test "$ac_cv_mpi_config_done" = yes; then
143     AC_MSG_RESULT(done)
144 else
145 ac_cv_mpi_config_done=""
146 if test -f $srcdir/mpi/config.links ; then
147     . $srcdir/mpi/config.links
148     WK_LINK_FILES($mpi_ln_src, $mpi_ln_dst)
149     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
150     ac_cv_mpi_config_done="yes"
151     AC_MSG_RESULT(done)
152 else
153     AC_MSG_RESULT(failed)
154     AC_MSG_ERROR([mpi/config.links missing!])
155 fi
156 fi
157 MPI_EXTRA_ASM_OBJS=""
158 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
159 WK_MSG_PRINT([mpi extra asm functions:])
160 for i in $ac_cv_mpi_extra_asm_modules; do
161     WK_MSG_PRINT([$i])
162     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
163 done
164 AC_MSG_RESULT()
165 fi
166 AC_SUBST(MPI_EXTRA_ASM_OBJS)
167
168 dnl Do we have zlib? Must do it here because Solaris failed
169 dnl when compiling a conftest (due to the "-lz" from LIBS).
170 if test "$g10_use_zlib" = "yes"; then
171 AC_CHECK_HEADERS(zlib.h,
172                  [LIBS="$LIBS -lz"],
173                  AC_MSG_WARN([zlib missing - creating without ZLIB support!])
174                 )
175 fi
176 AC_SUBST(HAVE_ZLIB_H)
177
178 dnl checking whether we have other cipher source files
179 CIPHER_EXTRA_OBJS=""
180 CIPHER_EXTRA_DIST=""
181 AC_CACHE_CHECK(for extra cipher modules, ac_cv_have_rsa_cipher,
182 [if test -f $srcdir/cipher/rsa.c && test -f $srcdir/cipher/rsa.h; then
183   ac_cv_have_rsa_cipher=yes; else ac_cv_have_rsa_cipher=no; fi])
184 if test $ac_cv_have_rsa_cipher = yes; then
185     AC_DEFINE(HAVE_RSA_CIPHER)
186     CIPHER_EXTRA_OBJS="rsa.o"
187     CIPHER_EXTRA_DIST="rsa.c rsa.h"
188 fi
189 AC_SUBST(CIPHER_EXTRA_OBJS)
190 AC_SUBST(CIPHER_EXTRA_DIST)
191
192 dnl
193 dnl If no gettext is found, default to gnu gettext
194 dnl
195 if test x$ac_cv_func_gettext = xno; then
196     LIBS="$LIBS -lintl -L\$(topbuilddir)/intl"
197 fi
198
199
200 WK_DO_LINK_FILES
201
202 AC_OUTPUT([
203 Makefile
204 intl/Makefile
205 po/Makefile.in
206 util/Makefile
207 mpi/Makefile
208 cipher/Makefile
209 g10/Makefile
210 tools/Makefile
211 ],[echo timestamp >stamp-h; sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
212