gpg: Lowercase mailbox for PKA lookups.
[gnupg.git] / m4 / gpg-error.m4
1 # gpg-error.m4 - autoconf macro to detect libgpg-error.
2 # Copyright (C) 2002, 2003, 2004, 2011, 2014 g10 Code GmbH
3 #
4 # This file is free software; as a special exception the author gives
5 # unlimited permission to copy and/or distribute it, with or without
6 # modifications, as long as this notice is preserved.
7 #
8 # This file is distributed in the hope that it will be useful, but
9 # WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
10 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
11 #
12 # Last-changed: 2014-10-02
13
14
15 dnl AM_PATH_GPG_ERROR([MINIMUM-VERSION,
16 dnl                   [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
17 dnl
18 dnl Test for libgpg-error and define GPG_ERROR_CFLAGS, GPG_ERROR_LIBS,
19 dnl GPG_ERROR_MT_CFLAGS, and GPG_ERROR_MT_LIBS.  The _MT_ variants are
20 dnl used for programs requireing real multi thread support.
21 dnl
22 dnl If a prefix option is not used, the config script is first
23 dnl searched in $SYSROOT/bin and then along $PATH.  If the used
24 dnl config script does not match the host specification the script
25 dnl is added to the gpg_config_script_warn variable.
26 dnl
27 AC_DEFUN([AM_PATH_GPG_ERROR],
28 [ AC_REQUIRE([AC_CANONICAL_HOST])
29   dnl --with-libgpg-error-prefix=PFX is the preferred name for this option,
30   dnl since that is consistent with how our three siblings use the directory/
31   dnl package name in --with-$dir_name-prefix=PFX.
32   AC_ARG_WITH(libgpg-error-prefix,
33             AC_HELP_STRING([--with-libgpg-error-prefix=PFX],
34                            [prefix where GPG Error is installed (optional)]),
35      gpg_error_config_prefix="$withval", gpg_error_config_prefix="")
36
37   dnl Accept --with-gpg-error-prefix and make it work the same as
38   dnl --with-libgpg-error-prefix above, for backwards compatibility,
39   dnl but do not document this old, inconsistently-named option.
40   AC_ARG_WITH(gpg-error-prefix,,
41      gpg_error_config_prefix="$withval", gpg_error_config_prefix="")
42
43   if test x"${GPG_ERROR_CONFIG}" = x ; then
44      if test x"${gpg_error_config_prefix}" != x ; then
45         GPG_ERROR_CONFIG="${gpg_error_config_prefix}/bin/gpg-error-config"
46      else
47        case "${SYSROOT}" in
48          /*)
49            if test -x "${SYSROOT}/bin/gpg-error-config" ; then
50              GPG_ERROR_CONFIG="${SYSROOT}/bin/gpg-error-config"
51            fi
52            ;;
53          '')
54            ;;
55           *)
56            AC_MSG_WARN([Ignoring \$SYSROOT as it is not an absolute path.])
57            ;;
58        esac
59      fi
60   fi
61
62   AC_PATH_PROG(GPG_ERROR_CONFIG, gpg-error-config, no)
63   min_gpg_error_version=ifelse([$1], ,0.0,$1)
64   AC_MSG_CHECKING(for GPG Error - version >= $min_gpg_error_version)
65   ok=no
66   if test "$GPG_ERROR_CONFIG" != "no" ; then
67     req_major=`echo $min_gpg_error_version | \
68                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
69     req_minor=`echo $min_gpg_error_version | \
70                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
71     gpg_error_config_version=`$GPG_ERROR_CONFIG $gpg_error_config_args --version`
72     major=`echo $gpg_error_config_version | \
73                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
74     minor=`echo $gpg_error_config_version | \
75                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
76     if test "$major" -gt "$req_major"; then
77         ok=yes
78     else
79         if test "$major" -eq "$req_major"; then
80             if test "$minor" -ge "$req_minor"; then
81                ok=yes
82             fi
83         fi
84     fi
85   fi
86   if test $ok = yes; then
87     GPG_ERROR_CFLAGS=`$GPG_ERROR_CONFIG $gpg_error_config_args --cflags`
88     GPG_ERROR_LIBS=`$GPG_ERROR_CONFIG $gpg_error_config_args --libs`
89     GPG_ERROR_MT_CFLAGS=`$GPG_ERROR_CONFIG $gpg_error_config_args --mt --cflags 2>/dev/null`
90     GPG_ERROR_MT_LIBS=`$GPG_ERROR_CONFIG $gpg_error_config_args --mt --libs 2>/dev/null`
91     AC_MSG_RESULT([yes ($gpg_error_config_version)])
92     ifelse([$2], , :, [$2])
93     gpg_error_config_host=`$GPG_ERROR_CONFIG $gpg_error_config_args --host 2>/dev/null || echo none`
94     if test x"$gpg_error_config_host" != xnone ; then
95       if test x"$gpg_error_config_host" != x"$host" ; then
96   AC_MSG_WARN([[
97 ***
98 *** The config script $GPG_ERROR_CONFIG was
99 *** built for $gpg_error_config_host and thus may not match the
100 *** used host $host.
101 *** You may want to use the configure option --with-gpg-error-prefix
102 *** to specify a matching config script or use \$SYSROOT.
103 ***]])
104         gpg_config_script_warn="$gpg_config_script_warn libgpg-error"
105       fi
106     fi
107   else
108     GPG_ERROR_CFLAGS=""
109     GPG_ERROR_LIBS=""
110     GPG_ERROR_MT_CFLAGS=""
111     GPG_ERROR_MT_LIBS=""
112     AC_MSG_RESULT(no)
113     ifelse([$3], , :, [$3])
114   fi
115   AC_SUBST(GPG_ERROR_CFLAGS)
116   AC_SUBST(GPG_ERROR_LIBS)
117   AC_SUBST(GPG_ERROR_MT_CFLAGS)
118   AC_SUBST(GPG_ERROR_MT_LIBS)
119 ])