Update some M4 files and AUTHORS.
[gnupg.git] / m4 / gpg-error.m4
1 # gpg-error.m4 - autoconf macro to detect libgpg-error.
2 # Copyright (C) 2002, 2003, 2004, 2011 g10 Code GmbH
3 #
4 # This file is free software; as a special exception the author gives
5 # unlimited permission to copy and/or distribute it, with or without
6 # modifications, as long as this notice is preserved.
7 #
8 # This file is distributed in the hope that it will be useful, but
9 # WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
10 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
11
12 dnl AM_PATH_GPG_ERROR([MINIMUM-VERSION,
13 dnl                   [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
14 dnl Test for libgpg-error and define GPG_ERROR_CFLAGS and GPG_ERROR_LIBS
15 dnl
16 AC_DEFUN([AM_PATH_GPG_ERROR],
17 [ AC_REQUIRE([AC_CANONICAL_HOST])
18   AC_ARG_WITH(gpg-error-prefix,
19             AC_HELP_STRING([--with-gpg-error-prefix=PFX],
20                            [prefix where GPG Error is installed (optional)]),
21      gpg_error_config_prefix="$withval", gpg_error_config_prefix="")
22   if test x$gpg_error_config_prefix != x ; then
23      if test x${GPG_ERROR_CONFIG+set} != xset ; then
24         GPG_ERROR_CONFIG=$gpg_error_config_prefix/bin/gpg-error-config
25      fi
26   fi
27
28   AC_PATH_TOOL(GPG_ERROR_CONFIG, gpg-error-config, no)
29   min_gpg_error_version=ifelse([$1], ,0.0,$1)
30   AC_MSG_CHECKING(for GPG Error - version >= $min_gpg_error_version)
31   ok=no
32   if test "$GPG_ERROR_CONFIG" != "no" ; then
33     req_major=`echo $min_gpg_error_version | \
34                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
35     req_minor=`echo $min_gpg_error_version | \
36                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
37     gpg_error_config_version=`$GPG_ERROR_CONFIG $gpg_error_config_args --version`
38     major=`echo $gpg_error_config_version | \
39                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
40     minor=`echo $gpg_error_config_version | \
41                sed 's/\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
42     if test "$major" -gt "$req_major"; then
43         ok=yes
44     else
45         if test "$major" -eq "$req_major"; then
46             if test "$minor" -ge "$req_minor"; then
47                ok=yes
48             fi
49         fi
50     fi
51   fi
52   if test $ok = yes; then
53     GPG_ERROR_CFLAGS=`$GPG_ERROR_CONFIG $gpg_error_config_args --cflags`
54     GPG_ERROR_LIBS=`$GPG_ERROR_CONFIG $gpg_error_config_args --libs`
55     AC_MSG_RESULT([yes ($gpg_error_config_version)])
56     ifelse([$2], , :, [$2])
57     gpg_error_config_host=`$GPG_ERROR_CONFIG $gpg_error_config_args --host 2>/dev/null || echo none`
58     if test x"$gpg_error_config_host" != xnone ; then
59       if test x"$gpg_error_config_host" != x"$host" ; then
60   AC_MSG_WARN([[
61 ***
62 *** The config script $GPG_ERROR_CONFIG was
63 *** built for $gpg_error_config_host and thus may not match the
64 *** used host $host.
65 *** You may want to use the configure option --with-gpg-error-prefix
66 *** to specify a matching config script.
67 ***]])
68       fi
69     fi
70   else
71     GPG_ERROR_CFLAGS=""
72     GPG_ERROR_LIBS=""
73     AC_MSG_RESULT(no)
74     ifelse([$3], , :, [$3])
75   fi
76   AC_SUBST(GPG_ERROR_CFLAGS)
77   AC_SUBST(GPG_ERROR_LIBS)
78 ])