Fixed regression in libcurl.m4
[gnupg.git] / m4 / libcurl.m4
1 # LIBCURL_CHECK_CONFIG ([DEFAULT-ACTION], [MINIMUM-VERSION],
2 #                       [ACTION-IF-YES], [ACTION-IF-NO])
3 # ----------------------------------------------------------
4 #      David Shaw <dshaw@jabberwocky.com>   May-09-2006
5 #
6 # Checks for libcurl.  DEFAULT-ACTION is the string yes or no to
7 # specify whether to default to --with-libcurl or --without-libcurl.
8 # If not supplied, DEFAULT-ACTION is yes.  MINIMUM-VERSION is the
9 # minimum version of libcurl to accept.  Pass the version as a regular
10 # version number like 7.10.1. If not supplied, any version is
11 # accepted.  ACTION-IF-YES is a list of shell commands to run if
12 # libcurl was successfully found and passed the various tests.
13 # ACTION-IF-NO is a list of shell commands that are run otherwise.
14 # Note that using --without-libcurl does run ACTION-IF-NO.
15 #
16 # This macro #defines HAVE_LIBCURL if a working libcurl setup is
17 # found, and sets @LIBCURL@ and @LIBCURL_CPPFLAGS@ to the necessary
18 # values.  Other useful defines are LIBCURL_FEATURE_xxx where xxx are
19 # the various features supported by libcurl, and LIBCURL_PROTOCOL_yyy
20 # where yyy are the various protocols supported by libcurl.  Both xxx
21 # and yyy are capitalized.  See the list of AH_TEMPLATEs at the top of
22 # the macro for the complete list of possible defines.  Shell
23 # variables $libcurl_feature_xxx and $libcurl_protocol_yyy are also
24 # defined to 'yes' for those features and protocols that were found.
25 # Note that xxx and yyy keep the same capitalization as in the
26 # curl-config list (e.g. it's "HTTP" and not "http").
27 #
28 # Users may override the detected values by doing something like:
29 # LIBCURL="-lcurl" LIBCURL_CPPFLAGS="-I/usr/myinclude" ./configure
30 #
31 # For the sake of sanity, this macro assumes that any libcurl that is
32 # found is after version 7.7.2, the first version that included the
33 # curl-config script.  Note that it is very important for people
34 # packaging binary versions of libcurl to include this script!
35 # Without curl-config, we can only guess what protocols are available,
36 # or use curl_version_info to figure it out at runtime.
37
38 AC_DEFUN([LIBCURL_CHECK_CONFIG],
39 [
40   AH_TEMPLATE([LIBCURL_FEATURE_SSL],[Defined if libcurl supports SSL])
41   AH_TEMPLATE([LIBCURL_FEATURE_KRB4],[Defined if libcurl supports KRB4])
42   AH_TEMPLATE([LIBCURL_FEATURE_IPV6],[Defined if libcurl supports IPv6])
43   AH_TEMPLATE([LIBCURL_FEATURE_LIBZ],[Defined if libcurl supports libz])
44   AH_TEMPLATE([LIBCURL_FEATURE_ASYNCHDNS],[Defined if libcurl supports AsynchDNS])
45   AH_TEMPLATE([LIBCURL_FEATURE_IDN],[Defined if libcurl supports IDN])
46   AH_TEMPLATE([LIBCURL_FEATURE_SSPI],[Defined if libcurl supports SSPI])
47   AH_TEMPLATE([LIBCURL_FEATURE_NTLM],[Defined if libcurl supports NTLM])
48
49   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTP],[Defined if libcurl supports HTTP])
50   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTPS],[Defined if libcurl supports HTTPS])
51   AH_TEMPLATE([LIBCURL_PROTOCOL_FTP],[Defined if libcurl supports FTP])
52   AH_TEMPLATE([LIBCURL_PROTOCOL_FTPS],[Defined if libcurl supports FTPS])
53   AH_TEMPLATE([LIBCURL_PROTOCOL_FILE],[Defined if libcurl supports FILE])
54   AH_TEMPLATE([LIBCURL_PROTOCOL_TELNET],[Defined if libcurl supports TELNET])
55   AH_TEMPLATE([LIBCURL_PROTOCOL_LDAP],[Defined if libcurl supports LDAP])
56   AH_TEMPLATE([LIBCURL_PROTOCOL_DICT],[Defined if libcurl supports DICT])
57   AH_TEMPLATE([LIBCURL_PROTOCOL_TFTP],[Defined if libcurl supports TFTP])
58
59   AC_ARG_WITH(libcurl,
60      AC_HELP_STRING([--with-libcurl=DIR],[look for the curl library in DIR]),
61      [_libcurl_with=$withval],[_libcurl_with=m4_if([$1],,[yes],[$1])])
62
63   if test "$_libcurl_with" != "no" ; then
64
65      AC_PROG_AWK
66
67      _libcurl_version_parse="eval $AWK '{split(\$NF,A,\".\"); X=256*256*A[[1]]+256*A[[2]]+A[[3]]; print X;}'"
68
69      _libcurl_try_link=yes
70
71      if test -d "$_libcurl_with" ; then
72         LIBCURL_CPPFLAGS="-I$withval/include"
73         _libcurl_ldflags="-L$withval/lib"
74         AC_PATH_PROG([_libcurl_config],["$withval/bin/curl-config"])
75      else
76         AC_PATH_PROG([_libcurl_config],[curl-config])
77      fi
78
79      if test x$_libcurl_config != "x" ; then
80         AC_CACHE_CHECK([for the version of libcurl],
81            [libcurl_cv_lib_curl_version],
82            [libcurl_cv_lib_curl_version=`$_libcurl_config --version | $AWK '{print $[]2}'`])
83
84         _libcurl_version=`echo $libcurl_cv_lib_curl_version | $_libcurl_version_parse`
85         _libcurl_wanted=`echo m4_if([$2],,[0],[$2]) | $_libcurl_version_parse`
86
87         if test $_libcurl_wanted -gt 0 ; then
88            AC_CACHE_CHECK([for libcurl >= version $2],
89               [libcurl_cv_lib_version_ok],
90               [
91               if test $_libcurl_version -ge $_libcurl_wanted ; then
92                  libcurl_cv_lib_version_ok=yes
93               else
94                  libcurl_cv_lib_version_ok=no
95               fi
96               ])
97         fi
98
99         if test $_libcurl_wanted -eq 0 || test x$libcurl_cv_lib_version_ok = xyes ; then
100            if test x"$LIBCURL_CPPFLAGS" = "x" ; then
101               LIBCURL_CPPFLAGS=`$_libcurl_config --cflags`
102            fi
103            if test x"$LIBCURL" = "x" ; then
104               LIBCURL=`$_libcurl_config --libs`
105
106               # This is so silly, but Apple actually has a bug in their
107               # curl-config script.  Fixed in Tiger, but there are still
108               # lots of Panther installs around.
109               case "${host}" in
110                  powerpc-apple-darwin7*)
111                     LIBCURL=`echo $LIBCURL | sed -e 's|-arch i386||g'`
112                  ;;
113               esac
114            fi
115
116            # All curl-config scripts support --feature
117            _libcurl_features=`$_libcurl_config --feature`
118
119            # Is it modern enough to have --protocols? (7.12.4)
120            if test $_libcurl_version -ge 461828 ; then
121               _libcurl_protocols=`$_libcurl_config --protocols`
122            fi
123         else
124            _libcurl_try_link=no
125         fi
126
127         unset _libcurl_wanted
128      fi
129
130      if test $_libcurl_try_link = yes ; then
131
132         # we didn't find curl-config, so let's see if the user-supplied
133         # link line (or failing that, "-lcurl") is enough.
134         LIBCURL=${LIBCURL-"$_libcurl_ldflags -lcurl"}
135
136         AC_CACHE_CHECK([whether libcurl is usable],
137            [libcurl_cv_lib_curl_usable],
138            [
139            _libcurl_save_cppflags=$CPPFLAGS
140            CPPFLAGS="$LIBCURL_CPPFLAGS $CPPFLAGS"
141            _libcurl_save_libs=$LIBS
142            LIBS="$LIBCURL $LIBS"
143
144            AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <curl/curl.h>]],[[
145 /* Try and use a few common options to force a failure if we are
146    missing symbols or cannot link. */
147 int x;
148 curl_easy_setopt(NULL,CURLOPT_URL,NULL);
149 x=CURL_ERROR_SIZE;
150 x=CURLOPT_WRITEFUNCTION;
151 x=CURLOPT_FILE;
152 x=CURLOPT_ERRORBUFFER;
153 x=CURLOPT_STDERR;
154 x=CURLOPT_VERBOSE;
155 ]])],[libcurl_cv_lib_curl_usable=yes],[libcurl_cv_lib_curl_usable=no])
156
157            CPPFLAGS=$_libcurl_save_cppflags
158            LIBS=$_libcurl_save_libs
159            unset _libcurl_save_cppflags
160            unset _libcurl_save_libs
161            ])
162
163         if test $libcurl_cv_lib_curl_usable = yes ; then
164
165            # Does curl_free() exist in this version of libcurl?
166            # If not, fake it with free()
167
168            _libcurl_save_cppflags=$CPPFLAGS
169            CPPFLAGS="$CPPFLAGS $LIBCURL_CPPFLAGS"
170            _libcurl_save_libs=$LIBS
171            LIBS="$LIBS $LIBCURL"
172
173            AC_CHECK_FUNC(curl_free,,
174               AC_DEFINE(curl_free,free,
175                 [Define curl_free() as free() if our version of curl lacks curl_free.]))
176
177            CPPFLAGS=$_libcurl_save_cppflags
178            LIBS=$_libcurl_save_libs
179            unset _libcurl_save_cppflags
180            unset _libcurl_save_libs
181
182            AC_DEFINE(HAVE_LIBCURL,1,
183              [Define to 1 if you have a functional curl library.])
184            AC_SUBST(LIBCURL_CPPFLAGS)
185            AC_SUBST(LIBCURL)
186
187            for _libcurl_feature in $_libcurl_features ; do
188               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_feature_$_libcurl_feature),[1])
189               eval AS_TR_SH(libcurl_feature_$_libcurl_feature)=yes
190            done
191
192            if test "x$_libcurl_protocols" = "x" ; then
193
194               # We don't have --protocols, so just assume that all
195               # protocols are available
196               _libcurl_protocols="HTTP FTP FILE TELNET LDAP DICT"
197
198               if test x$libcurl_feature_SSL = xyes ; then
199                  _libcurl_protocols="$_libcurl_protocols HTTPS"
200
201                  # FTPS wasn't standards-compliant until version
202                  # 7.11.0
203                  if test $_libcurl_version -ge 461568; then
204                     _libcurl_protocols="$_libcurl_protocols FTPS"
205                  fi
206               fi
207            fi
208
209            for _libcurl_protocol in $_libcurl_protocols ; do
210               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_protocol_$_libcurl_protocol),[1])
211               eval AS_TR_SH(libcurl_protocol_$_libcurl_protocol)=yes
212            done
213         else
214            unset LIBCURL
215            unset LIBCURL_CPPFLAGS
216         fi
217      fi
218
219      unset _libcurl_try_link
220      unset _libcurl_version_parse
221      unset _libcurl_config
222      unset _libcurl_feature
223      unset _libcurl_features
224      unset _libcurl_protocol
225      unset _libcurl_protocols
226      unset _libcurl_version
227      unset _libcurl_ldflags
228   fi
229
230   if test x$_libcurl_with = xno || test x$libcurl_cv_lib_curl_usable != xyes ; then
231      # This is the IF-NO path
232      m4_if([$4],,:,[$4])
233   else
234      # This is the IF-YES path
235      m4_if([$3],,:,[$3])
236   fi
237
238   unset _libcurl_with
239 ])dnl