ab87c9e7461c49a887860dee98c474f37b0feedf
[gnupg.git] / m4 / libcurl.m4
1 # LIBCURL_CHECK_CONFIG ([DEFAULT-ACTION], [MINIMUM-VERSION],
2 #                       [ACTION-IF-YES], [ACTION-IF-NO])
3 # ----------------------------------------------------------
4 #      David Shaw <dshaw@jabberwocky.com>   Dec-24-2004
5 #
6 # Checks for libcurl.  DEFAULT-ACTION is yes or no whether to default
7 # to --with-libcurl or --without-libcurl.  If not supplied,
8 # DEFAULT-ACTION is yes.  MINIMUM-VERSION is the minimum version of
9 # libcurl to accept.  If not supplied, any version is accepted.
10 # ACTION-IF-YES is a list of shell commands to run if libcurl was
11 # successfully found and passed the various tests.  ACTION-IF-NO is a
12 # list of shell commands that are run otherwise.  Note that using
13 # --without-libcurl does run ACTION-IF-NO.
14 #
15 # This macro defines HAVE_LIBCURL if a working libcurl setup is found,
16 # and sets @LIBCURL@ and @LIBCURL_CPPFLAGS@ to the necessary values.
17 # Other useful defines are LIBCURL_FEATURE_xxx where xxx are the
18 # various features supported by libcurl, and LIBCURL_PROTOCOL_yyy
19 # where yyy are the various protocols supported by libcurl.  Both xxx
20 # and yyy are capitalized.  See the list of AH_TEMPLATEs at the top of
21 # the macro for the complete list of possible defines.  Shell
22 # variables $libcurl_feature_xxx and $libcurl_protocol_yyy are also
23 # defined to 'yes' for those features and protocols that were found.
24 # Note that xxx and yyy keep the same capitalization as in the
25 # curl-config list (i.e. it's "HTTP" and not "http").
26
27 AC_DEFUN([LIBCURL_CHECK_CONFIG],
28 [
29   AH_TEMPLATE([LIBCURL_FEATURE_SSL],[Defined if libcurl supports SSL])
30   AH_TEMPLATE([LIBCURL_FEATURE_KRB4],[Defined if libcurl supports KRB4])
31   AH_TEMPLATE([LIBCURL_FEATURE_IPV6],[Defined if libcurl supports IPv6])
32   AH_TEMPLATE([LIBCURL_FEATURE_LIBZ],[Defined if libcurl supports libz])
33   AH_TEMPLATE([LIBCURL_FEATURE_ASYNCHDNS],[Defined if libcurl supports AsynchDNS])
34
35   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTP],[Defined if libcurl supports HTTP])
36   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTPS],[Defined if libcurl supports HTTPS])
37   AH_TEMPLATE([LIBCURL_PROTOCOL_FTP],[Defined if libcurl supports FTP])
38   AH_TEMPLATE([LIBCURL_PROTOCOL_FTPS],[Defined if libcurl supports FTPS])
39   AH_TEMPLATE([LIBCURL_PROTOCOL_GOPHER],[Defined if libcurl supports GOPHER])
40   AH_TEMPLATE([LIBCURL_PROTOCOL_FILE],[Defined if libcurl supports FILE])
41   AH_TEMPLATE([LIBCURL_PROTOCOL_TELNET],[Defined if libcurl supports TELNET])
42   AH_TEMPLATE([LIBCURL_PROTOCOL_LDAP],[Defined if libcurl supports LDAP])
43   AH_TEMPLATE([LIBCURL_PROTOCOL_DICT],[Defined if libcurl supports DICT])
44
45   AC_ARG_WITH(libcurl,
46      AC_HELP_STRING([--with-libcurl=DIR],[look for the curl library in DIR]),
47      [_libcurl_with=$withval],[_libcurl_with=ifelse([$1],,[yes],[$1])])
48
49   if test "$_libcurl_with" != "no" ; then
50
51      AC_PROG_AWK
52
53      _libcurl_version_parse="eval $AWK '{split(\$NF,A,\".\"); X=256*256*A[[1]]+256*A[[2]]+A[[3]]; print X;}'"
54
55      _libcurl_try_link=yes
56
57      if test -d "$_libcurl_with" ; then
58         CPPFLAGS="${CPPFLAGS} -I$withval/include"
59         LDFLAGS="${LDFLAGS} -L$withval/lib"
60      fi
61
62      AC_PATH_PROG([_libcurl_config],[curl-config])
63
64      if test x$_libcurl_config != "x" ; then
65         AC_CACHE_CHECK([for the version of libcurl],
66            [libcurl_cv_lib_curl_version],
67            [libcurl_cv_lib_curl_version=`$_libcurl_config --version | $AWK '{print $[]2}'`])
68
69         _libcurl_version=`echo $libcurl_cv_lib_curl_version | $_libcurl_version_parse`
70         _libcurl_wanted=`echo ifelse([$2],,[0],[$2]) | $_libcurl_version_parse`
71
72         if test $_libcurl_wanted -gt 0 ; then
73            AC_CACHE_CHECK([for libcurl >= version $2],
74               [libcurl_cv_lib_version_ok],
75               [
76               if test $_libcurl_version -ge $_libcurl_wanted ; then
77                  libcurl_cv_lib_version_ok=yes
78               else
79                  libcurl_cv_lib_version_ok=no
80               fi
81               ])
82         fi
83
84         if test $_libcurl_wanted -eq 0 || test x$libcurl_cv_lib_version_ok = xyes ; then
85            if test x"$LIBCURL_CPPFLAGS" = "x" ; then
86               LIBCURL_CPPFLAGS=`$_libcurl_config --cflags`
87            fi
88            if test x"$LIBCURL" = "x" ; then
89               LIBCURL=`$_libcurl_config --libs`
90
91               # This is so silly, but Apple actually has a bug in their
92               # curl-config script!
93               case "${host}" in
94                  powerpc-apple-darwin*)
95                     LIBCURL=`echo $LIBCURL | sed -e 's|-arch i386||g'`
96                  ;;
97               esac
98            fi
99
100            # Is it modern enough to have --feature?
101            if test $_libcurl_version -ge 0 ; then
102               _libcurl_features=`$_libcurl_config --feature`
103            fi
104
105            # Is it modern enough to have --protocols? (7.12.4)
106            if test $_libcurl_version -ge 461828 ; then
107               _libcurl_protocols=`$_libcurl_config --protocols`
108            fi
109         else
110            _libcurl_try_link=no
111         fi
112
113         unset _libcurl_wanted
114         unset _libcurl_version
115      fi
116
117      if test $_libcurl_try_link = yes ; then
118
119         # we didn't find curl-config, so let's see if the user-supplied
120         # link line (or failing that, "-lcurl") is enough.
121         LIBCURL=${LIBCURL-"-lcurl"}
122
123         AC_CACHE_CHECK([whether libcurl is usable],
124            [libcurl_cv_lib_curl_usable],
125            [
126            _libcurl_save_cppflags=$CPPFLAGS
127            CPPFLAGS="$CPPFLAGS $LIBCURL_CPPFLAGS"
128            _libcurl_save_ldflags=$LDFLAGS
129            LDFLAGS="$LDFLAGS $LIBCURL"
130
131            AC_LINK_IFELSE(AC_LANG_PROGRAM([#include <curl/curl.h>],[
132 /* Try and use a few common options to force a failure if we are
133    missing symbols or can't link. */
134 int x;
135 curl_easy_setopt(NULL,CURLOPT_URL,NULL);
136 x=CURL_ERROR_SIZE;
137 x=CURLOPT_WRITEFUNCTION;
138 x=CURLOPT_FILE;
139 x=CURLOPT_ERRORBUFFER;
140 x=CURLOPT_STDERR;
141 x=CURLOPT_VERBOSE;
142 ]),libcurl_cv_lib_curl_usable=yes,libcurl_cv_lib_curl_usable=no)
143
144            CPPFLAGS=$_libcurl_save_cppflags
145            LDFLAGS=$_libcurl_save_ldflags
146            unset _libcurl_save_cppflags
147            unset _libcurl_save_ldflags
148            ])
149
150         if test $libcurl_cv_lib_curl_usable = yes ; then
151            AC_DEFINE(HAVE_LIBCURL,1,
152              [Define to 1 if you have a functional curl library.])
153            AC_SUBST(LIBCURL_CPPFLAGS)
154            AC_SUBST(LIBCURL)
155
156            for _libcurl_feature in $_libcurl_features ; do
157               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_feature_$_libcurl_feature),[1])
158               eval AS_TR_SH(libcurl_feature_$_libcurl_feature)=yes
159            done
160
161            if test "x$_libcurl_protocols" = "x" ; then
162               # We don't have --protocols, so just assume that all protocols
163               # are available
164
165               _libcurl_protocols="HTTP FTP GOPHER FILE TELNET LDAP DICT"
166
167               if test x$libcurl_feature_SSL = xyes ; then
168                  _libcurl_protocols="$_libcurl_protocols HTTPS FTPS"
169               fi
170            fi
171
172            for _libcurl_protocol in $_libcurl_protocols ; do
173               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_protocol_$_libcurl_protocol),[1])
174               eval AS_TR_SH(libcurl_protocol_$_libcurl_protocol)=yes
175            done
176         fi
177      fi
178
179      unset _libcurl_try_link
180      unset _libcurl_version_parse
181      unset _libcurl_config
182      unset _libcurl_feature
183      unset _libcurl_features
184      unset _libcurl_protocol
185      unset _libcurl_protocols
186   fi
187
188   if test x$_libcurl_with = xno || test x$libcurl_cv_lib_curl_usable != xyes ; then
189      # This is the IF-NO path
190      ifelse([$4],,:,[$4])
191   else
192      # This is the IF-YES path
193      ifelse([$3],,:,[$3])
194   fi
195
196   unset _libcurl_with
197 ])dnl