Use gcc pragmas to suppress some warnings.
[gnupg.git] / m4 / libcurl.m4
1 # LIBCURL_CHECK_CONFIG ([DEFAULT-ACTION], [MINIMUM-VERSION],
2 #                       [ACTION-IF-YES], [ACTION-IF-NO])
3 # ----------------------------------------------------------
4 #      David Shaw <dshaw@jabberwocky.com>   Jan-16-2007
5 #
6 # Checks for libcurl.  DEFAULT-ACTION is the string yes or no to
7 # specify whether to default to --with-libcurl or --without-libcurl.
8 # If not supplied, DEFAULT-ACTION is yes.  MINIMUM-VERSION is the
9 # minimum version of libcurl to accept.  Pass the version as a regular
10 # version number like 7.10.1. If not supplied, any version is
11 # accepted.  ACTION-IF-YES is a list of shell commands to run if
12 # libcurl was successfully found and passed the various tests.
13 # ACTION-IF-NO is a list of shell commands that are run otherwise.
14 # Note that using --without-libcurl does run ACTION-IF-NO.
15 #
16 # This macro #defines HAVE_LIBCURL if a working libcurl setup is
17 # found, and sets @LIBCURL@ and @LIBCURL_CPPFLAGS@ to the necessary
18 # values.  Other useful defines are LIBCURL_FEATURE_xxx where xxx are
19 # the various features supported by libcurl, and LIBCURL_PROTOCOL_yyy
20 # where yyy are the various protocols supported by libcurl.  Both xxx
21 # and yyy are capitalized.  See the list of AH_TEMPLATEs at the top of
22 # the macro for the complete list of possible defines.  Shell
23 # variables $libcurl_feature_xxx and $libcurl_protocol_yyy are also
24 # defined to 'yes' for those features and protocols that were found.
25 # Note that xxx and yyy keep the same capitalization as in the
26 # curl-config list (e.g. it's "HTTP" and not "http").
27 #
28 # Users may override the detected values by doing something like:
29 # LIBCURL="-lcurl" LIBCURL_CPPFLAGS="-I/usr/myinclude" ./configure
30 #
31 # For the sake of sanity, this macro assumes that any libcurl that is
32 # found is after version 7.7.2, the first version that included the
33 # curl-config script.  Note that it is very important for people
34 # packaging binary versions of libcurl to include this script!
35 # Without curl-config, we can only guess what protocols are available,
36 # or use curl_version_info to figure it out at runtime.
37
38 AC_DEFUN([LIBCURL_CHECK_CONFIG],
39 [
40   AH_TEMPLATE([LIBCURL_FEATURE_SSL],[Defined if libcurl supports SSL])
41   AH_TEMPLATE([LIBCURL_FEATURE_KRB4],[Defined if libcurl supports KRB4])
42   AH_TEMPLATE([LIBCURL_FEATURE_IPV6],[Defined if libcurl supports IPv6])
43   AH_TEMPLATE([LIBCURL_FEATURE_LIBZ],[Defined if libcurl supports libz])
44   AH_TEMPLATE([LIBCURL_FEATURE_ASYNCHDNS],[Defined if libcurl supports AsynchDNS])
45   AH_TEMPLATE([LIBCURL_FEATURE_IDN],[Defined if libcurl supports IDN])
46   AH_TEMPLATE([LIBCURL_FEATURE_SSPI],[Defined if libcurl supports SSPI])
47   AH_TEMPLATE([LIBCURL_FEATURE_NTLM],[Defined if libcurl supports NTLM])
48
49   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTP],[Defined if libcurl supports HTTP])
50   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTPS],[Defined if libcurl supports HTTPS])
51   AH_TEMPLATE([LIBCURL_PROTOCOL_FTP],[Defined if libcurl supports FTP])
52   AH_TEMPLATE([LIBCURL_PROTOCOL_FTPS],[Defined if libcurl supports FTPS])
53   AH_TEMPLATE([LIBCURL_PROTOCOL_FILE],[Defined if libcurl supports FILE])
54   AH_TEMPLATE([LIBCURL_PROTOCOL_TELNET],[Defined if libcurl supports TELNET])
55   AH_TEMPLATE([LIBCURL_PROTOCOL_LDAP],[Defined if libcurl supports LDAP])
56   AH_TEMPLATE([LIBCURL_PROTOCOL_DICT],[Defined if libcurl supports DICT])
57   AH_TEMPLATE([LIBCURL_PROTOCOL_TFTP],[Defined if libcurl supports TFTP])
58
59   AC_ARG_WITH(libcurl,
60      AC_HELP_STRING([--with-libcurl=DIR],[look for the curl library in DIR]),
61      [_libcurl_with=$withval],[_libcurl_with=m4_if([$1],,[yes],[$1])])
62
63   if test "$_libcurl_with" != "no" ; then
64
65      AC_PROG_AWK
66
67      _libcurl_version_parse="eval $AWK '{split(\$NF,A,\".\"); X=256*256*A[[1]]+256*A[[2]]+A[[3]]; print X;}'"
68
69      _libcurl_try_link=yes
70
71      if test -d "$_libcurl_with" ; then
72         LIBCURL_CPPFLAGS="-I$withval/include"
73         _libcurl_ldflags="-L$withval/lib"
74         AC_PATH_PROG([_libcurl_config],["$withval/bin/curl-config"])
75      else
76         AC_PATH_PROG([_libcurl_config],[curl-config])
77      fi
78
79      if test x$_libcurl_config != "x" ; then
80         AC_CACHE_CHECK([for the version of libcurl],
81            [libcurl_cv_lib_curl_version],
82            [libcurl_cv_lib_curl_version=`$_libcurl_config --version | $AWK '{print $[]2}'`])
83
84         _libcurl_version=`echo $libcurl_cv_lib_curl_version | $_libcurl_version_parse`
85         _libcurl_wanted=`echo m4_if([$2],,[0],[$2]) | $_libcurl_version_parse`
86
87         if test $_libcurl_wanted -gt 0 ; then
88            AC_CACHE_CHECK([for libcurl >= version $2],
89               [libcurl_cv_lib_version_ok],
90               [
91               if test $_libcurl_version -ge $_libcurl_wanted ; then
92                  libcurl_cv_lib_version_ok=yes
93               else
94                  libcurl_cv_lib_version_ok=no
95               fi
96               ])
97         fi
98
99         if test $_libcurl_wanted -eq 0 || test x$libcurl_cv_lib_version_ok = xyes ; then
100            if test x"$LIBCURL_CPPFLAGS" = "x" ; then
101               LIBCURL_CPPFLAGS=`$_libcurl_config --cflags`
102            fi
103            if test x"$LIBCURL" = "x" ; then
104               LIBCURL=`$_libcurl_config --libs`
105
106               # This is so silly, but Apple actually has a bug in their
107               # curl-config script.  Fixed in Tiger, but there are still
108               # lots of Panther installs around.
109               case "${host}" in
110                  powerpc-apple-darwin7*)
111                     LIBCURL=`echo $LIBCURL | sed -e 's|-arch i386||g'`
112                  ;;
113               esac
114            fi
115
116            # All curl-config scripts support --feature
117            _libcurl_features=`$_libcurl_config --feature`
118
119            # Is it modern enough to have --protocols? (7.12.4)
120            if test $_libcurl_version -ge 461828 ; then
121               _libcurl_protocols=`$_libcurl_config --protocols`
122            fi
123         else
124            _libcurl_try_link=no
125         fi
126
127         unset _libcurl_wanted
128      fi
129
130      if test $_libcurl_try_link = yes ; then
131
132         # we didn't find curl-config, so let's see if the user-supplied
133         # link line (or failing that, "-lcurl") is enough.
134         LIBCURL=${LIBCURL-"$_libcurl_ldflags -lcurl"}
135
136         AC_CACHE_CHECK([whether libcurl is usable],
137            [libcurl_cv_lib_curl_usable],
138            [
139            _libcurl_save_cppflags=$CPPFLAGS
140            CPPFLAGS="$LIBCURL_CPPFLAGS $CPPFLAGS"
141            _libcurl_save_libs=$LIBS
142            LIBS="$LIBCURL $LIBS"
143
144            AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <curl/curl.h>]],[[
145 /* Try and use a few common options to force a failure if we are
146    missing symbols or can't link. */
147 int x;
148 curl_easy_setopt(NULL,CURLOPT_URL,NULL);
149 x=CURL_ERROR_SIZE;
150 x=CURLOPT_WRITEFUNCTION;
151 x=CURLOPT_FILE;
152 x=CURLOPT_ERRORBUFFER;
153 x=CURLOPT_STDERR;
154 x=CURLOPT_VERBOSE;
155 ]])],libcurl_cv_lib_curl_usable=yes,libcurl_cv_lib_curl_usable=no)
156
157            CPPFLAGS=$_libcurl_save_cppflags
158            LIBS=$_libcurl_save_libs
159            unset _libcurl_save_cppflags
160            unset _libcurl_save_libs
161            ])
162
163         if test $libcurl_cv_lib_curl_usable = yes ; then
164
165            _libcurl_save_cppflags=$CPPFLAGS
166            CPPFLAGS="$CPPFLAGS $LIBCURL_CPPFLAGS"
167            _libcurl_save_libs=$LIBS
168            LIBS="$LIBS $LIBCURL"
169
170            # Check for some libcurl functions that aren't in all
171            # versions.
172
173            AC_CHECK_FUNCS([curl_free curl_easy_escape curl_easy_unescape])
174
175            AH_BOTTOM([
176 #ifdef HAVE_LIBCURL
177
178 /* Define curl_free() via free() if our version of curl lacks
179    curl_free() */
180 #if !defined(curl_free) && !defined(HAVE_CURL_FREE)
181 #define curl_free(a) free((a))
182 #endif
183
184 /* Define curl_easy_escape() via curl_escape() if our version of curl
185    lacks curl_easy_escape() */
186 #if !defined(curl_easy_escape) && !defined(HAVE_CURL_EASY_ESCAPE)
187 #define curl_easy_escape(a,b,c) curl_escape((b),(c))
188 #endif
189
190 /* Define curl_easy_unescape() via curl_unescape() if our version of
191    curl lacks curl_easy_unescape() */
192 #if !defined(curl_easy_unescape) && !defined(HAVE_CURL_EASY_UNESCAPE)
193 #define curl_easy_unescape(a,b,c) curl_unescape((b),(c))
194 #endif
195
196 #endif /* HAVE_LIBCURL */
197 ])
198
199            CPPFLAGS=$_libcurl_save_cppflags
200            LIBS=$_libcurl_save_libs
201            unset _libcurl_save_cppflags
202            unset _libcurl_save_libs
203
204            AC_DEFINE(HAVE_LIBCURL,1,
205              [Define to 1 if you have a functional curl library.])
206            AC_SUBST(LIBCURL_CPPFLAGS)
207            AC_SUBST(LIBCURL)
208
209            for _libcurl_feature in $_libcurl_features ; do
210               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_feature_$_libcurl_feature),[1])
211               eval AS_TR_SH(libcurl_feature_$_libcurl_feature)=yes
212            done
213
214            if test "x$_libcurl_protocols" = "x" ; then
215
216               # We don't have --protocols, so just assume that all
217               # protocols are available
218               _libcurl_protocols="HTTP FTP FILE TELNET LDAP DICT"
219
220               if test x$libcurl_feature_SSL = xyes ; then
221                  _libcurl_protocols="$_libcurl_protocols HTTPS"
222
223                  # FTPS wasn't standards-compliant until version
224                  # 7.11.0
225                  if test $_libcurl_version -ge 461568; then
226                     _libcurl_protocols="$_libcurl_protocols FTPS"
227                  fi
228               fi
229            fi
230
231            for _libcurl_protocol in $_libcurl_protocols ; do
232               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_protocol_$_libcurl_protocol),[1])
233               eval AS_TR_SH(libcurl_protocol_$_libcurl_protocol)=yes
234            done
235         else
236            unset LIBCURL
237            unset LIBCURL_CPPFLAGS
238         fi
239      fi
240
241      unset _libcurl_try_link
242      unset _libcurl_version_parse
243      unset _libcurl_config
244      unset _libcurl_feature
245      unset _libcurl_features
246      unset _libcurl_protocol
247      unset _libcurl_protocols
248      unset _libcurl_version
249      unset _libcurl_ldflags
250   fi
251
252   if test x$_libcurl_with = xno || test x$libcurl_cv_lib_curl_usable != xyes ; then
253      # This is the IF-NO path
254      m4_if([$4],,:,[$4])
255   else
256      # This is the IF-YES path
257      m4_if([$3],,:,[$3])
258   fi
259
260   unset _libcurl_with
261 ])dnl