Improve libcurl detection.
[gnupg.git] / m4 / libcurl.m4
1 # LIBCURL_CHECK_CONFIG ([DEFAULT-ACTION], [MINIMUM-VERSION],
2 #                       [ACTION-IF-YES], [ACTION-IF-NO])
3 # ----------------------------------------------------------
4 #      David Shaw <dshaw@jabberwocky.com>   May-09-2006
5 #
6 # Checks for libcurl.  DEFAULT-ACTION is the string yes or no to
7 # specify whether to default to --with-libcurl or --without-libcurl.
8 # If not supplied, DEFAULT-ACTION is yes.  MINIMUM-VERSION is the
9 # minimum version of libcurl to accept.  Pass the version as a regular
10 # version number like 7.10.1. If not supplied, any version is
11 # accepted.  ACTION-IF-YES is a list of shell commands to run if
12 # libcurl was successfully found and passed the various tests.
13 # ACTION-IF-NO is a list of shell commands that are run otherwise.
14 # Note that using --without-libcurl does run ACTION-IF-NO.
15 #
16 # This macro #defines HAVE_LIBCURL if a working libcurl setup is
17 # found, and sets @LIBCURL@ and @LIBCURL_CPPFLAGS@ to the necessary
18 # values.  Other useful defines are LIBCURL_FEATURE_xxx where xxx are
19 # the various features supported by libcurl, and LIBCURL_PROTOCOL_yyy
20 # where yyy are the various protocols supported by libcurl.  Both xxx
21 # and yyy are capitalized.  See the list of AH_TEMPLATEs at the top of
22 # the macro for the complete list of possible defines.  Shell
23 # variables $libcurl_feature_xxx and $libcurl_protocol_yyy are also
24 # defined to 'yes' for those features and protocols that were found.
25 # Note that xxx and yyy keep the same capitalization as in the
26 # curl-config list (e.g. it's "HTTP" and not "http").
27 #
28 # Users may override the detected values by doing something like:
29 # LIBCURL="-lcurl" LIBCURL_CPPFLAGS="-I/usr/myinclude" ./configure
30 #
31 # For the sake of sanity, this macro assumes that any libcurl that is
32 # found is after version 7.7.2, the first version that included the
33 # curl-config script.  Note that it is very important for people
34 # packaging binary versions of libcurl to include this script!
35 # Without curl-config, we can only guess what protocols are available,
36 # or use curl_version_info to figure it out at runtime.
37
38 AC_DEFUN([LIBCURL_CHECK_CONFIG],
39 [
40   AH_TEMPLATE([LIBCURL_FEATURE_SSL],[Defined if libcurl supports SSL])
41   AH_TEMPLATE([LIBCURL_FEATURE_KRB4],[Defined if libcurl supports KRB4])
42   AH_TEMPLATE([LIBCURL_FEATURE_IPV6],[Defined if libcurl supports IPv6])
43   AH_TEMPLATE([LIBCURL_FEATURE_LIBZ],[Defined if libcurl supports libz])
44   AH_TEMPLATE([LIBCURL_FEATURE_ASYNCHDNS],[Defined if libcurl supports AsynchDNS])
45   AH_TEMPLATE([LIBCURL_FEATURE_IDN],[Defined if libcurl supports IDN])
46   AH_TEMPLATE([LIBCURL_FEATURE_SSPI],[Defined if libcurl supports SSPI])
47   AH_TEMPLATE([LIBCURL_FEATURE_NTLM],[Defined if libcurl supports NTLM])
48
49   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTP],[Defined if libcurl supports HTTP])
50   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTPS],[Defined if libcurl supports HTTPS])
51   AH_TEMPLATE([LIBCURL_PROTOCOL_FTP],[Defined if libcurl supports FTP])
52   AH_TEMPLATE([LIBCURL_PROTOCOL_FTPS],[Defined if libcurl supports FTPS])
53   AH_TEMPLATE([LIBCURL_PROTOCOL_FILE],[Defined if libcurl supports FILE])
54   AH_TEMPLATE([LIBCURL_PROTOCOL_TELNET],[Defined if libcurl supports TELNET])
55   AH_TEMPLATE([LIBCURL_PROTOCOL_LDAP],[Defined if libcurl supports LDAP])
56   AH_TEMPLATE([LIBCURL_PROTOCOL_DICT],[Defined if libcurl supports DICT])
57   AH_TEMPLATE([LIBCURL_PROTOCOL_TFTP],[Defined if libcurl supports TFTP])
58
59   AC_ARG_WITH(libcurl,
60      AC_HELP_STRING([--with-libcurl=DIR],[look for the curl library in DIR]),
61      [_libcurl_with=$withval],[_libcurl_with=m4_if([$1],,[yes],[$1])])
62
63   if test "$_libcurl_with" != "no" ; then
64
65      AC_PROG_AWK
66
67      _libcurl_version_parse="eval $AWK '{split(\$NF,A,\".\"); X=256*256*A[[1]]+256*A[[2]]+A[[3]]; print X;}'"
68
69      _libcurl_try_link=yes
70
71      if test -d "$_libcurl_with" ; then
72         LIBCURL_CPPFLAGS="-I$withval/include"
73         _libcurl_ldflags="-L$withval/lib"
74         if test -x "$withval/bin/curl-config" ; then
75           _libcurl_config="$withval/bin/curl-config"
76         else
77           _libcurl_config=
78         fi
79      else
80         AC_PATH_PROG([_libcurl_config],[curl-config])
81      fi
82
83      if test x$_libcurl_config != "x" ; then
84         AC_CACHE_CHECK([for the version of libcurl],
85            [libcurl_cv_lib_curl_version],
86            [libcurl_cv_lib_curl_version=`$_libcurl_config --version | $AWK '{print $[]2}'`])
87
88         _libcurl_version=`echo $libcurl_cv_lib_curl_version | $_libcurl_version_parse`
89         _libcurl_wanted=`echo m4_if([$2],,[0],[$2]) | $_libcurl_version_parse`
90
91         if test $_libcurl_wanted -gt 0 ; then
92            AC_CACHE_CHECK([for libcurl >= version $2],
93               [libcurl_cv_lib_version_ok],
94               [
95               if test $_libcurl_version -ge $_libcurl_wanted ; then
96                  libcurl_cv_lib_version_ok=yes
97               else
98                  libcurl_cv_lib_version_ok=no
99               fi
100               ])
101         fi
102
103         if test $_libcurl_wanted -eq 0 || test x$libcurl_cv_lib_version_ok = xyes ; then
104            if test x"$LIBCURL_CPPFLAGS" = "x" ; then
105               LIBCURL_CPPFLAGS=`$_libcurl_config --cflags`
106            fi
107            if test x"$LIBCURL" = "x" ; then
108               LIBCURL=`$_libcurl_config --libs`
109
110               # This is so silly, but Apple actually has a bug in their
111               # curl-config script.  Fixed in Tiger, but there are still
112               # lots of Panther installs around.
113               case "${host}" in
114                  powerpc-apple-darwin7*)
115                     LIBCURL=`echo $LIBCURL | sed -e 's|-arch i386||g'`
116                  ;;
117               esac
118            fi
119
120            # All curl-config scripts support --feature
121            _libcurl_features=`$_libcurl_config --feature`
122
123            # Is it modern enough to have --protocols? (7.12.4)
124            if test $_libcurl_version -ge 461828 ; then
125               _libcurl_protocols=`$_libcurl_config --protocols`
126            fi
127         else
128            _libcurl_try_link=no
129         fi
130
131         unset _libcurl_wanted
132      fi
133
134      if test $_libcurl_try_link = yes ; then
135
136         # we didn't find curl-config, so let's see if the user-supplied
137         # link line (or failing that, "-lcurl") is enough.
138         LIBCURL=${LIBCURL-"$_libcurl_ldflags -lcurl"}
139
140         AC_CACHE_CHECK([whether libcurl is usable],
141            [libcurl_cv_lib_curl_usable],
142            [
143            _libcurl_save_cppflags=$CPPFLAGS
144            CPPFLAGS="$LIBCURL_CPPFLAGS $CPPFLAGS"
145            _libcurl_save_libs=$LIBS
146            LIBS="$LIBCURL $LIBS"
147
148            AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <curl/curl.h>]],[[
149 /* Try and use a few common options to force a failure if we are
150    missing symbols or cannot link. */
151 int x;
152 curl_easy_setopt(NULL,CURLOPT_URL,NULL);
153 x=CURL_ERROR_SIZE;
154 x=CURLOPT_WRITEFUNCTION;
155 x=CURLOPT_FILE;
156 x=CURLOPT_ERRORBUFFER;
157 x=CURLOPT_STDERR;
158 x=CURLOPT_VERBOSE;
159 ]])],[libcurl_cv_lib_curl_usable=yes],[libcurl_cv_lib_curl_usable=no])
160
161            CPPFLAGS=$_libcurl_save_cppflags
162            LIBS=$_libcurl_save_libs
163            unset _libcurl_save_cppflags
164            unset _libcurl_save_libs
165            ])
166
167         if test $libcurl_cv_lib_curl_usable = yes ; then
168
169            # Does curl_free() exist in this version of libcurl?
170            # If not, fake it with free()
171
172            _libcurl_save_cppflags=$CPPFLAGS
173            CPPFLAGS="$CPPFLAGS $LIBCURL_CPPFLAGS"
174            _libcurl_save_libs=$LIBS
175            LIBS="$LIBS $LIBCURL"
176
177            AC_CHECK_FUNC(curl_free,,
178               AC_DEFINE(curl_free,free,
179                 [Define curl_free() as free() if our version of curl lacks curl_free.]))
180
181            CPPFLAGS=$_libcurl_save_cppflags
182            LIBS=$_libcurl_save_libs
183            unset _libcurl_save_cppflags
184            unset _libcurl_save_libs
185
186            AC_DEFINE(HAVE_LIBCURL,1,
187              [Define to 1 if you have a functional curl library.])
188            AC_SUBST(LIBCURL_CPPFLAGS)
189            AC_SUBST(LIBCURL)
190
191            for _libcurl_feature in $_libcurl_features ; do
192               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_feature_$_libcurl_feature),[1])
193               eval AS_TR_SH(libcurl_feature_$_libcurl_feature)=yes
194            done
195
196            if test "x$_libcurl_protocols" = "x" ; then
197
198               # We don't have --protocols, so just assume that all
199               # protocols are available
200               _libcurl_protocols="HTTP FTP FILE TELNET LDAP DICT"
201
202               if test x$libcurl_feature_SSL = xyes ; then
203                  _libcurl_protocols="$_libcurl_protocols HTTPS"
204
205                  # FTPS wasn't standards-compliant until version
206                  # 7.11.0
207                  if test $_libcurl_version -ge 461568; then
208                     _libcurl_protocols="$_libcurl_protocols FTPS"
209                  fi
210               fi
211            fi
212
213            for _libcurl_protocol in $_libcurl_protocols ; do
214               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_protocol_$_libcurl_protocol),[1])
215               eval AS_TR_SH(libcurl_protocol_$_libcurl_protocol)=yes
216            done
217         else
218            unset LIBCURL
219            unset LIBCURL_CPPFLAGS
220         fi
221      fi
222
223      unset _libcurl_try_link
224      unset _libcurl_version_parse
225      unset _libcurl_config
226      unset _libcurl_feature
227      unset _libcurl_features
228      unset _libcurl_protocol
229      unset _libcurl_protocols
230      unset _libcurl_version
231      unset _libcurl_ldflags
232   fi
233
234   if test x$_libcurl_with = xno || test x$libcurl_cv_lib_curl_usable != xyes ; then
235      # This is the IF-NO path
236      m4_if([$4],,:,[$4])
237   else
238      # This is the IF-YES path
239      m4_if([$3],,:,[$3])
240   fi
241
242   unset _libcurl_with
243 ])dnl