* libcurl.m4: Add a check for curl_free() since older versions of
[gnupg.git] / m4 / libcurl.m4
1 # LIBCURL_CHECK_CONFIG ([DEFAULT-ACTION], [MINIMUM-VERSION],
2 #                       [ACTION-IF-YES], [ACTION-IF-NO])
3 # ----------------------------------------------------------
4 #      David Shaw <dshaw@jabberwocky.com>   Apr-21-2005
5 #
6 # Checks for libcurl.  DEFAULT-ACTION is the string yes or no to
7 # specify whether to default to --with-libcurl or --without-libcurl.
8 # If not supplied, DEFAULT-ACTION is yes.  MINIMUM-VERSION is the
9 # minimum version of libcurl to accept.  Pass the version as a regular
10 # version number like 7.10.1. If not supplied, any version is
11 # accepted.  ACTION-IF-YES is a list of shell commands to run if
12 # libcurl was successfully found and passed the various tests.
13 # ACTION-IF-NO is a list of shell commands that are run otherwise.
14 # Note that using --without-libcurl does run ACTION-IF-NO.
15 #
16 # This macro defines HAVE_LIBCURL if a working libcurl setup is found,
17 # and sets @LIBCURL@ and @LIBCURL_CPPFLAGS@ to the necessary values.
18 # Other useful defines are LIBCURL_FEATURE_xxx where xxx are the
19 # various features supported by libcurl, and LIBCURL_PROTOCOL_yyy
20 # where yyy are the various protocols supported by libcurl.  Both xxx
21 # and yyy are capitalized.  See the list of AH_TEMPLATEs at the top of
22 # the macro for the complete list of possible defines.  Shell
23 # variables $libcurl_feature_xxx and $libcurl_protocol_yyy are also
24 # defined to 'yes' for those features and protocols that were found.
25 # Note that xxx and yyy keep the same capitalization as in the
26 # curl-config list (e.g. it's "HTTP" and not "http").
27 #
28 # Users may override the detected values by doing something like:
29 # LIBCURL="-lcurl" LIBCURL_CPPFLAGS="-I/usr/myinclude" ./configure
30 #
31 # For the sake of sanity, this macro assumes that any libcurl that is
32 # found is after version 7.7.2, the first version that included the
33 # curl-config script.  Note that it is very important for people
34 # packaging binary versions of libcurl to include this script!
35 # Without curl-config, we can only guess what protocols are available.
36
37 AC_DEFUN([LIBCURL_CHECK_CONFIG],
38 [
39   AH_TEMPLATE([LIBCURL_FEATURE_SSL],[Defined if libcurl supports SSL])
40   AH_TEMPLATE([LIBCURL_FEATURE_KRB4],[Defined if libcurl supports KRB4])
41   AH_TEMPLATE([LIBCURL_FEATURE_IPV6],[Defined if libcurl supports IPv6])
42   AH_TEMPLATE([LIBCURL_FEATURE_LIBZ],[Defined if libcurl supports libz])
43   AH_TEMPLATE([LIBCURL_FEATURE_ASYNCHDNS],[Defined if libcurl supports AsynchDNS])
44
45   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTP],[Defined if libcurl supports HTTP])
46   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTPS],[Defined if libcurl supports HTTPS])
47   AH_TEMPLATE([LIBCURL_PROTOCOL_FTP],[Defined if libcurl supports FTP])
48   AH_TEMPLATE([LIBCURL_PROTOCOL_FTPS],[Defined if libcurl supports FTPS])
49   AH_TEMPLATE([LIBCURL_PROTOCOL_GOPHER],[Defined if libcurl supports GOPHER])
50   AH_TEMPLATE([LIBCURL_PROTOCOL_FILE],[Defined if libcurl supports FILE])
51   AH_TEMPLATE([LIBCURL_PROTOCOL_TELNET],[Defined if libcurl supports TELNET])
52   AH_TEMPLATE([LIBCURL_PROTOCOL_LDAP],[Defined if libcurl supports LDAP])
53   AH_TEMPLATE([LIBCURL_PROTOCOL_DICT],[Defined if libcurl supports DICT])
54
55   AC_ARG_WITH(libcurl,
56      AC_HELP_STRING([--with-libcurl=DIR],[look for the curl library in DIR]),
57      [_libcurl_with=$withval],[_libcurl_with=ifelse([$1],,[yes],[$1])])
58
59   if test "$_libcurl_with" != "no" ; then
60
61      AC_PROG_AWK
62
63      _libcurl_version_parse="eval $AWK '{split(\$NF,A,\".\"); X=256*256*A[[1]]+256*A[[2]]+A[[3]]; print X;}'"
64
65      _libcurl_try_link=yes
66
67      if test -d "$_libcurl_with" ; then
68         CPPFLAGS="${CPPFLAGS} -I$withval/include"
69         LDFLAGS="${LDFLAGS} -L$withval/lib"
70      fi
71
72      AC_PATH_PROG([_libcurl_config],[curl-config])
73
74      if test x$_libcurl_config != "x" ; then
75         AC_CACHE_CHECK([for the version of libcurl],
76            [libcurl_cv_lib_curl_version],
77            [libcurl_cv_lib_curl_version=`$_libcurl_config --version | $AWK '{print $[]2}'`])
78
79         _libcurl_version=`echo $libcurl_cv_lib_curl_version | $_libcurl_version_parse`
80         _libcurl_wanted=`echo ifelse([$2],,[0],[$2]) | $_libcurl_version_parse`
81
82         if test $_libcurl_wanted -gt 0 ; then
83            AC_CACHE_CHECK([for libcurl >= version $2],
84               [libcurl_cv_lib_version_ok],
85               [
86               if test $_libcurl_version -ge $_libcurl_wanted ; then
87                  libcurl_cv_lib_version_ok=yes
88               else
89                  libcurl_cv_lib_version_ok=no
90               fi
91               ])
92         fi
93
94         if test $_libcurl_wanted -eq 0 || test x$libcurl_cv_lib_version_ok = xyes ; then
95            if test x"$LIBCURL_CPPFLAGS" = "x" ; then
96               LIBCURL_CPPFLAGS=`$_libcurl_config --cflags`
97            fi
98            if test x"$LIBCURL" = "x" ; then
99               LIBCURL=`$_libcurl_config --libs`
100
101               # This is so silly, but Apple actually has a bug in their
102               # curl-config script!
103               case "${host}" in
104                  powerpc-apple-darwin*)
105                     LIBCURL=`echo $LIBCURL | sed -e 's|-arch i386||g'`
106                  ;;
107               esac
108            fi
109
110            # All curl-config scripts support --feature
111            _libcurl_features=`$_libcurl_config --feature`
112
113            # Is it modern enough to have --protocols? (7.12.4)
114            if test $_libcurl_version -ge 461828 ; then
115               _libcurl_protocols=`$_libcurl_config --protocols`
116            fi
117         else
118            _libcurl_try_link=no
119         fi
120
121         unset _libcurl_wanted
122      fi
123
124      if test $_libcurl_try_link = yes ; then
125
126         # we didn't find curl-config, so let's see if the user-supplied
127         # link line (or failing that, "-lcurl") is enough.
128         LIBCURL=${LIBCURL-"-lcurl"}
129
130         AC_CACHE_CHECK([whether libcurl is usable],
131            [libcurl_cv_lib_curl_usable],
132            [
133            _libcurl_save_cppflags=$CPPFLAGS
134            CPPFLAGS="$CPPFLAGS $LIBCURL_CPPFLAGS"
135            _libcurl_save_libs=$LIBS
136            LIBS="$LIBS $LIBCURL"
137
138            AC_LINK_IFELSE(AC_LANG_PROGRAM([#include <curl/curl.h>],[
139 /* Try and use a few common options to force a failure if we are
140    missing symbols or can't link. */
141 int x;
142 curl_easy_setopt(NULL,CURLOPT_URL,NULL);
143 x=CURL_ERROR_SIZE;
144 x=CURLOPT_WRITEFUNCTION;
145 x=CURLOPT_FILE;
146 x=CURLOPT_ERRORBUFFER;
147 x=CURLOPT_STDERR;
148 x=CURLOPT_VERBOSE;
149 ]),libcurl_cv_lib_curl_usable=yes,libcurl_cv_lib_curl_usable=no)
150
151            CPPFLAGS=$_libcurl_save_cppflags
152            LIBS=$_libcurl_save_libs
153            unset _libcurl_save_cppflags
154            unset _libcurl_save_libs
155            ])
156
157         if test $libcurl_cv_lib_curl_usable = yes ; then
158
159            # Does curl_free() exist in this version of libcurl?
160            # If not, fake it with free()
161
162            _libcurl_save_cppflags=$CPPFLAGS
163            CPPFLAGS="$CPPFLAGS $LIBCURL_CPPFLAGS"
164            _libcurl_save_libs=$LIBS
165            LIBS="$LIBS $LIBCURL"
166
167            AC_CHECK_FUNC(curl_free,,
168               AC_DEFINE(curl_free,free,
169                 [Define curl_free() as free() if our version of curl lacks curl_free.]))
170
171            CPPFLAGS=$_libcurl_save_cppflags
172            LIBS=$_libcurl_save_libs
173            unset _libcurl_save_cppflags
174            unset _libcurl_save_libs
175
176            AC_DEFINE(HAVE_LIBCURL,1,
177              [Define to 1 if you have a functional curl library.])
178            AC_SUBST(LIBCURL_CPPFLAGS)
179            AC_SUBST(LIBCURL)
180
181            for _libcurl_feature in $_libcurl_features ; do
182               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_feature_$_libcurl_feature),[1])
183               eval AS_TR_SH(libcurl_feature_$_libcurl_feature)=yes
184            done
185
186            if test "x$_libcurl_protocols" = "x" ; then
187
188               # We don't have --protocols, so just assume that all
189               # protocols are available
190               _libcurl_protocols="HTTP FTP GOPHER FILE TELNET LDAP DICT"
191
192               if test x$libcurl_feature_SSL = xyes ; then
193                  _libcurl_protocols="$_libcurl_protocols HTTPS"
194
195                  # FTPS wasn't standards-compliant until version
196                  # 7.11.0
197                  if test $_libcurl_version -ge 461568; then
198                     _libcurl_protocols="$_libcurl_protocols FTPS"
199                  fi
200               fi
201            fi
202
203            for _libcurl_protocol in $_libcurl_protocols ; do
204               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_protocol_$_libcurl_protocol),[1])
205               eval AS_TR_SH(libcurl_protocol_$_libcurl_protocol)=yes
206            done
207         fi
208      fi
209
210      unset _libcurl_try_link
211      unset _libcurl_version_parse
212      unset _libcurl_config
213      unset _libcurl_feature
214      unset _libcurl_features
215      unset _libcurl_protocol
216      unset _libcurl_protocols
217      unset _libcurl_version
218   fi
219
220   if test x$_libcurl_with = xno || test x$libcurl_cv_lib_curl_usable != xyes ; then
221      # This is the IF-NO path
222      ifelse([$4],,:,[$4])
223   else
224      # This is the IF-YES path
225      ifelse([$3],,:,[$3])
226   fi
227
228   unset _libcurl_with
229 ])dnl