* libcurl.m4: Remove GOPHER, as that is not supported in libcurl any
[gnupg.git] / m4 / libcurl.m4
1 # LIBCURL_CHECK_CONFIG ([DEFAULT-ACTION], [MINIMUM-VERSION],
2 #                       [ACTION-IF-YES], [ACTION-IF-NO])
3 # ----------------------------------------------------------
4 #      David Shaw <dshaw@jabberwocky.com>   Jan-16-2006
5 #
6 # Checks for libcurl.  DEFAULT-ACTION is the string yes or no to
7 # specify whether to default to --with-libcurl or --without-libcurl.
8 # If not supplied, DEFAULT-ACTION is yes.  MINIMUM-VERSION is the
9 # minimum version of libcurl to accept.  Pass the version as a regular
10 # version number like 7.10.1. If not supplied, any version is
11 # accepted.  ACTION-IF-YES is a list of shell commands to run if
12 # libcurl was successfully found and passed the various tests.
13 # ACTION-IF-NO is a list of shell commands that are run otherwise.
14 # Note that using --without-libcurl does run ACTION-IF-NO.
15 #
16 # This macro defines HAVE_LIBCURL if a working libcurl setup is found,
17 # and sets @LIBCURL@ and @LIBCURL_CPPFLAGS@ to the necessary values.
18 # Other useful defines are LIBCURL_FEATURE_xxx where xxx are the
19 # various features supported by libcurl, and LIBCURL_PROTOCOL_yyy
20 # where yyy are the various protocols supported by libcurl.  Both xxx
21 # and yyy are capitalized.  See the list of AH_TEMPLATEs at the top of
22 # the macro for the complete list of possible defines.  Shell
23 # variables $libcurl_feature_xxx and $libcurl_protocol_yyy are also
24 # defined to 'yes' for those features and protocols that were found.
25 # Note that xxx and yyy keep the same capitalization as in the
26 # curl-config list (e.g. it's "HTTP" and not "http").
27 #
28 # Users may override the detected values by doing something like:
29 # LIBCURL="-lcurl" LIBCURL_CPPFLAGS="-I/usr/myinclude" ./configure
30 #
31 # For the sake of sanity, this macro assumes that any libcurl that is
32 # found is after version 7.7.2, the first version that included the
33 # curl-config script.  Note that it is very important for people
34 # packaging binary versions of libcurl to include this script!
35 # Without curl-config, we can only guess what protocols are available,
36 # or use curl_version_info to figure it out at runtime.
37
38 AC_DEFUN([LIBCURL_CHECK_CONFIG],
39 [
40   AH_TEMPLATE([LIBCURL_FEATURE_SSL],[Defined if libcurl supports SSL])
41   AH_TEMPLATE([LIBCURL_FEATURE_KRB4],[Defined if libcurl supports KRB4])
42   AH_TEMPLATE([LIBCURL_FEATURE_IPV6],[Defined if libcurl supports IPv6])
43   AH_TEMPLATE([LIBCURL_FEATURE_LIBZ],[Defined if libcurl supports libz])
44   AH_TEMPLATE([LIBCURL_FEATURE_ASYNCHDNS],[Defined if libcurl supports AsynchDNS])
45
46   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTP],[Defined if libcurl supports HTTP])
47   AH_TEMPLATE([LIBCURL_PROTOCOL_HTTPS],[Defined if libcurl supports HTTPS])
48   AH_TEMPLATE([LIBCURL_PROTOCOL_FTP],[Defined if libcurl supports FTP])
49   AH_TEMPLATE([LIBCURL_PROTOCOL_FTPS],[Defined if libcurl supports FTPS])
50   AH_TEMPLATE([LIBCURL_PROTOCOL_FILE],[Defined if libcurl supports FILE])
51   AH_TEMPLATE([LIBCURL_PROTOCOL_TELNET],[Defined if libcurl supports TELNET])
52   AH_TEMPLATE([LIBCURL_PROTOCOL_LDAP],[Defined if libcurl supports LDAP])
53   AH_TEMPLATE([LIBCURL_PROTOCOL_DICT],[Defined if libcurl supports DICT])
54
55   AC_ARG_WITH(libcurl,
56      AC_HELP_STRING([--with-libcurl=DIR],[look for the curl library in DIR]),
57      [_libcurl_with=$withval],[_libcurl_with=ifelse([$1],,[yes],[$1])])
58
59   if test "$_libcurl_with" != "no" ; then
60
61      AC_PROG_AWK
62
63      _libcurl_version_parse="eval $AWK '{split(\$NF,A,\".\"); X=256*256*A[[1]]+256*A[[2]]+A[[3]]; print X;}'"
64
65      _libcurl_try_link=yes
66
67      if test -d "$_libcurl_with" ; then
68         LIBCURL_CPPFLAGS="-I$withval/include"
69         _libcurl_ldflags="-L$withval/lib"
70         AC_PATH_PROG([_libcurl_config],["$withval/bin/curl-config"])
71      else
72         AC_PATH_PROG([_libcurl_config],[curl-config])
73      fi
74
75      if test x$_libcurl_config != "x" ; then
76         AC_CACHE_CHECK([for the version of libcurl],
77            [libcurl_cv_lib_curl_version],
78            [libcurl_cv_lib_curl_version=`$_libcurl_config --version | $AWK '{print $[]2}'`])
79
80         _libcurl_version=`echo $libcurl_cv_lib_curl_version | $_libcurl_version_parse`
81         _libcurl_wanted=`echo ifelse([$2],,[0],[$2]) | $_libcurl_version_parse`
82
83         if test $_libcurl_wanted -gt 0 ; then
84            AC_CACHE_CHECK([for libcurl >= version $2],
85               [libcurl_cv_lib_version_ok],
86               [
87               if test $_libcurl_version -ge $_libcurl_wanted ; then
88                  libcurl_cv_lib_version_ok=yes
89               else
90                  libcurl_cv_lib_version_ok=no
91               fi
92               ])
93         fi
94
95         if test $_libcurl_wanted -eq 0 || test x$libcurl_cv_lib_version_ok = xyes ; then
96            if test x"$LIBCURL_CPPFLAGS" = "x" ; then
97               LIBCURL_CPPFLAGS=`$_libcurl_config --cflags`
98            fi
99            if test x"$LIBCURL" = "x" ; then
100               LIBCURL=`$_libcurl_config --libs`
101
102               # This is so silly, but Apple actually has a bug in their
103               # curl-config script.  Fixed in Tiger, but there are still
104               # lots of Panther installs around.
105               case "${host}" in
106                  powerpc-apple-darwin7*)
107                     LIBCURL=`echo $LIBCURL | sed -e 's|-arch i386||g'`
108                  ;;
109               esac
110            fi
111
112            # All curl-config scripts support --feature
113            _libcurl_features=`$_libcurl_config --feature`
114
115            # Is it modern enough to have --protocols? (7.12.4)
116            if test $_libcurl_version -ge 461828 ; then
117               _libcurl_protocols=`$_libcurl_config --protocols`
118            fi
119         else
120            _libcurl_try_link=no
121         fi
122
123         unset _libcurl_wanted
124      fi
125
126      if test $_libcurl_try_link = yes ; then
127
128         # we didn't find curl-config, so let's see if the user-supplied
129         # link line (or failing that, "-lcurl") is enough.
130         LIBCURL=${LIBCURL-"$_libcurl_ldflags -lcurl"}
131
132         AC_CACHE_CHECK([whether libcurl is usable],
133            [libcurl_cv_lib_curl_usable],
134            [
135            _libcurl_save_cppflags=$CPPFLAGS
136            CPPFLAGS="$LIBCURL_CPPFLAGS $CPPFLAGS"
137            _libcurl_save_libs=$LIBS
138            LIBS="$LIBCURL $LIBS"
139
140            AC_LINK_IFELSE(AC_LANG_PROGRAM([#include <curl/curl.h>],[
141 /* Try and use a few common options to force a failure if we are
142    missing symbols or can't link. */
143 int x;
144 curl_easy_setopt(NULL,CURLOPT_URL,NULL);
145 curl_version_info(CURLVERSION_NOW);
146 x=CURL_ERROR_SIZE;
147 x=CURLOPT_WRITEFUNCTION;
148 x=CURLOPT_FILE;
149 x=CURLOPT_ERRORBUFFER;
150 x=CURLOPT_STDERR;
151 x=CURLOPT_VERBOSE;
152 ]),libcurl_cv_lib_curl_usable=yes,libcurl_cv_lib_curl_usable=no)
153
154            CPPFLAGS=$_libcurl_save_cppflags
155            LIBS=$_libcurl_save_libs
156            unset _libcurl_save_cppflags
157            unset _libcurl_save_libs
158            ])
159
160         if test $libcurl_cv_lib_curl_usable = yes ; then
161
162            # Does curl_free() exist in this version of libcurl?
163            # If not, fake it with free()
164
165            _libcurl_save_cppflags=$CPPFLAGS
166            CPPFLAGS="$CPPFLAGS $LIBCURL_CPPFLAGS"
167            _libcurl_save_libs=$LIBS
168            LIBS="$LIBS $LIBCURL"
169
170            AC_CHECK_FUNC(curl_free,,
171               AC_DEFINE(curl_free,free,
172                 [Define curl_free() as free() if our version of curl lacks curl_free.]))
173
174            CPPFLAGS=$_libcurl_save_cppflags
175            LIBS=$_libcurl_save_libs
176            unset _libcurl_save_cppflags
177            unset _libcurl_save_libs
178
179            AC_DEFINE(HAVE_LIBCURL,1,
180              [Define to 1 if you have a functional curl library.])
181            AC_SUBST(LIBCURL_CPPFLAGS)
182            AC_SUBST(LIBCURL)
183
184            for _libcurl_feature in $_libcurl_features ; do
185               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_feature_$_libcurl_feature),[1])
186               eval AS_TR_SH(libcurl_feature_$_libcurl_feature)=yes
187            done
188
189            if test "x$_libcurl_protocols" = "x" ; then
190
191               # We don't have --protocols, so just assume that all
192               # protocols are available
193               _libcurl_protocols="HTTP FTP FILE TELNET LDAP DICT"
194
195               if test x$libcurl_feature_SSL = xyes ; then
196                  _libcurl_protocols="$_libcurl_protocols HTTPS"
197
198                  # FTPS wasn't standards-compliant until version
199                  # 7.11.0
200                  if test $_libcurl_version -ge 461568; then
201                     _libcurl_protocols="$_libcurl_protocols FTPS"
202                  fi
203               fi
204            fi
205
206            for _libcurl_protocol in $_libcurl_protocols ; do
207               AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_protocol_$_libcurl_protocol),[1])
208               eval AS_TR_SH(libcurl_protocol_$_libcurl_protocol)=yes
209            done
210         fi
211      fi
212
213      unset _libcurl_try_link
214      unset _libcurl_version_parse
215      unset _libcurl_config
216      unset _libcurl_feature
217      unset _libcurl_features
218      unset _libcurl_protocol
219      unset _libcurl_protocols
220      unset _libcurl_version
221      unset _libcurl_ldflags
222   fi
223
224   if test x$_libcurl_with = xno || test x$libcurl_cv_lib_curl_usable != xyes ; then
225      # This is the IF-NO path
226      ifelse([$4],,:,[$4])
227   else
228      # This is the IF-YES path
229      ifelse([$3],,:,[$3])
230   fi
231
232   unset _libcurl_with
233 ])dnl