some more internall structure changes
[gnupg.git] / mpi / alpha / mpih-mul2.S
1 /* Alpha 21064 addmul_1 -- Multiply a limb vector with a limb and add
2  *                         the result to a second limb vector.
3  *
4  * Copyright (C) 1992, 1994, 1995, 1998 Free Software Foundation, Inc.
5  *
6  * This file is part of GNUPG.
7  *
8  * GNUPG is free software; you can redistribute it and/or modify
9  * it under the terms of the GNU General Public License as published by
10  * the Free Software Foundation; either version 2 of the License, or
11  * (at your option) any later version.
12  *
13  * GNUPG is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16  * GNU General Public License for more details.
17  *
18  * You should have received a copy of the GNU General Public License
19  * along with this program; if not, write to the Free Software
20  * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
21  */
22
23
24 /*******************
25  * mpi_limb_t
26  * mpihelp_addmul_1( mpi_ptr_t res_ptr,      (r16)
27  *                   mpi_ptr_t s1_ptr,       (r17)
28  *                   mpi_size_t s1_size,     (r18)
29  *                   mpi_limb_t s2_limb)     (r19)
30  *
31  * This code runs at 42 cycles/limb on EV4 and 18 cycles/limb on EV5.
32  */
33
34
35         .set    noreorder
36         .set    noat
37 .text
38         .align  3
39         .globl  mpihelp_addmul_1
40         .ent    mpihelp_addmul_1 2
41 mpihelp_addmul_1:
42         .frame  $30,0,$26
43
44         ldq     $2,0($17)       # $2 = s1_limb
45         addq    $17,8,$17       # s1_ptr++
46         subq    $18,1,$18       # size--
47         mulq    $2,$19,$3       # $3 = prod_low
48         ldq     $5,0($16)       # $5 = *res_ptr
49         umulh   $2,$19,$0       # $0 = prod_high
50         beq     $18,.Lend1      # jump if size was == 1
51         ldq     $2,0($17)       # $2 = s1_limb
52         addq    $17,8,$17       # s1_ptr++
53         subq    $18,1,$18       # size--
54         addq    $5,$3,$3
55         cmpult  $3,$5,$4
56         stq     $3,0($16)
57         addq    $16,8,$16       # res_ptr++
58         beq     $18,.Lend2      # jump if size was == 2
59
60         .align  3
61 .Loop:  mulq    $2,$19,$3       # $3 = prod_low
62         ldq     $5,0($16)       # $5 = *res_ptr
63         addq    $4,$0,$0        # cy_limb = cy_limb + 'cy'
64         subq    $18,1,$18       # size--
65         umulh   $2,$19,$4       # $4 = cy_limb
66         ldq     $2,0($17)       # $2 = s1_limb
67         addq    $17,8,$17       # s1_ptr++
68         addq    $3,$0,$3        # $3 = cy_limb + prod_low
69         cmpult  $3,$0,$0        # $0 = carry from (cy_limb + prod_low)
70         addq    $5,$3,$3
71         cmpult  $3,$5,$5
72         stq     $3,0($16)
73         addq    $16,8,$16       # res_ptr++
74         addq    $5,$0,$0        # combine carries
75         bne     $18,.Loop
76
77 .Lend2: mulq    $2,$19,$3       # $3 = prod_low
78         ldq     $5,0($16)       # $5 = *res_ptr
79         addq    $4,$0,$0        # cy_limb = cy_limb + 'cy'
80         umulh   $2,$19,$4       # $4 = cy_limb
81         addq    $3,$0,$3        # $3 = cy_limb + prod_low
82         cmpult  $3,$0,$0        # $0 = carry from (cy_limb + prod_low)
83         addq    $5,$3,$3
84         cmpult  $3,$5,$5
85         stq     $3,0($16)
86         addq    $5,$0,$0        # combine carries
87         addq    $4,$0,$0        # cy_limb = prod_high + cy
88         ret     $31,($26),1
89 .Lend1: addq    $5,$3,$3
90         cmpult  $3,$5,$5
91         stq     $3,0($16)
92         addq    $0,$5,$0
93         ret     $31,($26),1
94
95         .end    mpihelp_addmul_1
96