some more internall structure changes
[gnupg.git] / mpi / alpha / mpih-mul3.S
1 /* Alpha 21064  submul_1 -- Multiply a limb vector with a limb and
2  *                          subtract the result from a second limb vector.
3  * Copyright (C) 1992, 1994, 1995, 1998 Free Software Foundation, Inc.
4  *
5  * This file is part of GNUPG.
6  *
7  * GNUPG is free software; you can redistribute it and/or modify
8  * it under the terms of the GNU General Public License as published by
9  * the Free Software Foundation; either version 2 of the License, or
10  * (at your option) any later version.
11  *
12  * GNUPG is distributed in the hope that it will be useful,
13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15  * GNU General Public License for more details.
16  *
17  * You should have received a copy of the GNU General Public License
18  * along with this program; if not, write to the Free Software
19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20  */
21
22
23 /*******************
24  * mpi_limb_t
25  * mpihelp_submul_1( mpi_ptr_t res_ptr,      (r16   )
26  *                   mpi_ptr_t s1_ptr,       (r17   )
27  *                   mpi_size_t s1_size,     (r18   )
28  *                   mpi_limb_t s2_limb)     (r19   )
29  *
30  * This code runs at 42 cycles/limb on EV4 and 18 cycles/limb on EV5.
31  */
32
33         .set    noreorder
34         .set    noat
35 .text
36         .align  3
37         .globl  mpihelp_submul_1
38         .ent    mpihelp_submul_1 2
39 mpihelp_submul_1:
40         .frame  $30,0,$26
41
42         ldq     $2,0($17)       # $2 = s1_limb
43         addq    $17,8,$17       # s1_ptr++
44         subq    $18,1,$18       # size--
45         mulq    $2,$19,$3       # $3 = prod_low
46         ldq     $5,0($16)       # $5 = *res_ptr
47         umulh   $2,$19,$0       # $0 = prod_high
48         beq     $18,.Lend1      # jump if size was == 1
49         ldq     $2,0($17)       # $2 = s1_limb
50         addq    $17,8,$17       # s1_ptr++
51         subq    $18,1,$18       # size--
52         subq    $5,$3,$3
53         cmpult  $5,$3,$4
54         stq     $3,0($16)
55         addq    $16,8,$16       # res_ptr++
56         beq     $18,.Lend2      # jump if size was == 2
57
58         .align  3
59 .Loop:  mulq    $2,$19,$3       # $3 = prod_low
60         ldq     $5,0($16)       # $5 = *res_ptr
61         addq    $4,$0,$0        # cy_limb = cy_limb + 'cy'
62         subq    $18,1,$18       # size--
63         umulh   $2,$19,$4       # $4 = cy_limb
64         ldq     $2,0($17)       # $2 = s1_limb
65         addq    $17,8,$17       # s1_ptr++
66         addq    $3,$0,$3        # $3 = cy_limb + prod_low
67         cmpult  $3,$0,$0        # $0 = carry from (cy_limb + prod_low)
68         subq    $5,$3,$3
69         cmpult  $5,$3,$5
70         stq     $3,0($16)
71         addq    $16,8,$16       # res_ptr++
72         addq    $5,$0,$0        # combine carries
73         bne     $18,.Loop
74
75 .Lend2: mulq    $2,$19,$3       # $3 = prod_low
76         ldq     $5,0($16)       # $5 = *res_ptr
77         addq    $4,$0,$0        # cy_limb = cy_limb + 'cy'
78         umulh   $2,$19,$4       # $4 = cy_limb
79         addq    $3,$0,$3        # $3 = cy_limb + prod_low
80         cmpult  $3,$0,$0        # $0 = carry from (cy_limb + prod_low)
81         subq    $5,$3,$3
82         cmpult  $5,$3,$5
83         stq     $3,0($16)
84         addq    $5,$0,$0        # combine carries
85         addq    $4,$0,$0        # cy_limb = prod_high + cy
86         ret     $31,($26),1
87 .Lend1: subq    $5,$3,$3
88         cmpult  $5,$3,$5
89         stq     $3,0($16)
90         addq    $0,$5,$0
91         ret     $31,($26),1
92
93         .end    mpihelp_submul_1
94