Switched to GPLv3.
[gnupg.git] / mpi / hppa1.1 / mpih-mul1.S
1 /* hppa1.1  mul_1 -- Multiply a limb vector with a limb and store
2  *                   the result in a second limb vector.
3  *
4  *      Copyright (C) 1992, 1993, 1994, 1998, 
5  *                    2001 Free Software Foundation, Inc.
6  *
7  * This file is part of GnuPG.
8  *
9  * GnuPG is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU General Public License as published by
11  * the Free Software Foundation; either version 3 of the License, or
12  * (at your option) any later version.
13  *
14  * GnuPG is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU General Public License for more details.
18  *
19  * You should have received a copy of the GNU General Public License
20  * along with this program; if not, see <http://www.gnu.org/licenses/>.
21  *
22  * Note: This code is heavily based on the GNU MP Library.
23  *       Actually it's the same code with only minor changes in the
24  *       way the data is stored; this is to support the abstraction
25  *       of an optional secure memory allocation which may be used
26  *       to avoid revealing of sensitive data due to paging etc.
27  *       The GNU MP Library itself is published under the LGPL;
28  *       however I decided to publish this code under the plain GPL.
29  */
30
31
32 /*******************
33  * mpi_limb_t
34  * mpihelp_mul_1( mpi_ptr_t res_ptr,    (r26)
35  *                mpi_ptr_t s1_ptr,     (r25)
36  *                mpi_size_t s1_size,   (r24)
37  *                mpi_limb_t s2_limb)   (r23)
38  *
39  *
40  *
41  * This runs at 9 cycles/limb on a PA7000.  With the used instructions, it can
42  * not become faster due to data cache contention after a store.  On the
43  * PA7100 it runs at 7 cycles/limb, and that can not be improved either, since
44  * only the xmpyu does not need the integer pipeline, so the only dual-issue
45  * we will get are addc+xmpyu.  Unrolling would not help either CPU.
46  *
47  * We could use fldds to read two limbs at a time from the S1 array, and that
48  * could bring down the times to 8.5 and 6.5 cycles/limb for the PA7000 and
49  * PA7100, respectively.  We don't do that since it does not seem worth the
50  * (alignment) troubles...
51  *
52  * At least the PA7100 is rumored to be able to deal with cache-misses
53  * without stalling instruction issue.  If this is true, and the cache is
54  * actually also lockup-free, we should use a deeper software pipeline, and
55  * load from S1 very early!  (The loads and stores to -12(sp) will surely be
56  * in the cache.)
57  */
58
59         .code
60         .export         mpihelp_mul_1
61         .label          mpihelp_mul_1
62         .proc
63         .callinfo       frame=64,no_calls
64         .entry
65
66         ldo             64(%r30),%r30
67         fldws,ma        4(%r25),%fr5
68         stw             %r23,-16(%r30)          ; move s2_limb ...
69         addib,=         -1,%r24,L$just_one_limb
70          fldws          -16(%r30),%fr4          ; ... into fr4
71         add             %r0,%r0,%r0             ; clear carry
72         xmpyu           %fr4,%fr5,%fr6
73         fldws,ma        4(%r25),%fr7
74         fstds           %fr6,-16(%r30)
75         xmpyu           %fr4,%fr7,%fr8
76         ldw             -12(%r30),%r19          ; least significant limb in product
77         ldw             -16(%r30),%r28
78
79         fstds           %fr8,-16(%r30)
80         addib,=         -1,%r24,L$end
81          ldw            -12(%r30),%r1
82
83 ; Main loop
84         .label  L$loop
85         fldws,ma        4(%r25),%fr5
86         stws,ma         %r19,4(%r26)
87         addc            %r28,%r1,%r19
88         xmpyu           %fr4,%fr5,%fr6
89         ldw             -16(%r30),%r28
90         fstds           %fr6,-16(%r30)
91         addib,<>        -1,%r24,L$loop
92          ldw            -12(%r30),%r1
93
94         .label  L$end
95         stws,ma         %r19,4(%r26)
96         addc            %r28,%r1,%r19
97         ldw             -16(%r30),%r28
98         stws,ma         %r19,4(%r26)
99         addc            %r0,%r28,%r28
100         bv              0(%r2)
101          ldo            -64(%r30),%r30
102
103         .label  L$just_one_limb
104         xmpyu           %fr4,%fr5,%fr6
105         fstds           %fr6,-16(%r30)
106         ldw             -16(%r30),%r28
107         ldo             -64(%r30),%r30
108         bv              0(%r2)
109          fstws          %fr6R,0(%r26)
110
111         .exit
112         .procend
113
114