* gpgkeys_hkp.c (send_key, get_key, get_name, search_key, main): Add
[gnupg.git] / mpi / hppa1.1 / mpih-mul2.S
1 /* hppa1.1   addmul_1 -- Multiply a limb vector with a limb and add
2  *                       the result to a second limb vector.
3  *
4  *      Copyright (C) 1992, 1993, 1994, 1998,
5  *                    2001 Free Software Foundation, Inc.
6  *
7  * This file is part of GnuPG.
8  *
9  * GnuPG is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU General Public License as published by
11  * the Free Software Foundation; either version 3 of the License, or
12  * (at your option) any later version.
13  *
14  * GnuPG is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU General Public License for more details.
18  *
19  * You should have received a copy of the GNU General Public License
20  * along with this program; if not, see <http://www.gnu.org/licenses/>.
21  *
22  * Note: This code is heavily based on the GNU MP Library.
23  *       Actually it's the same code with only minor changes in the
24  *       way the data is stored; this is to support the abstraction
25  *       of an optional secure memory allocation which may be used
26  *       to avoid revealing of sensitive data due to paging etc.
27  *       The GNU MP Library itself is published under the LGPL;
28  *       however I decided to publish this code under the plain GPL.
29  */
30
31
32 /*******************
33  * mpi_limb_t
34  * mpihelp_addmul_1( mpi_ptr_t res_ptr,      (r26)
35  *                   mpi_ptr_t s1_ptr,       (r25)
36  *                   mpi_size_t s1_size,     (r24)
37  *                   mpi_limb_t s2_limb)     (r23)
38  *
39  * This runs at 11 cycles/limb on a PA7000.  With the used instructions, it
40  * can not become faster due to data cache contention after a store.  On the
41  * PA7100 it runs at 10 cycles/limb, and that can not be improved either,
42  * since only the xmpyu does not need the integer pipeline, so the only
43  * dual-issue we will get are addc+xmpyu.  Unrolling could gain a cycle/limb
44  * on the PA7100.
45  *
46  * There are some ideas described in mul1.S that applies to this code too.
47  */
48
49         .code
50         .export         mpihelp_addmul_1
51         .label          mpihelp_addmul_1
52         .proc
53         .callinfo       frame=64,no_calls
54         .entry
55
56         ldo             64(%r30),%r30
57         fldws,ma        4(%r25),%fr5
58         stw             %r23,-16(%r30)          ; move s2_limb ...
59         addib,=         -1,%r24,L$just_one_limb
60          fldws          -16(%r30),%fr4          ; ... into fr4
61         add             %r0,%r0,%r0             ; clear carry
62         xmpyu           %fr4,%fr5,%fr6
63         fldws,ma        4(%r25),%fr7
64         fstds           %fr6,-16(%r30)
65         xmpyu           %fr4,%fr7,%fr8
66         ldw             -12(%r30),%r19          ; least significant limb in product
67         ldw             -16(%r30),%r28
68
69         fstds           %fr8,-16(%r30)
70         addib,=         -1,%r24,L$end
71          ldw            -12(%r30),%r1
72
73 ; Main loop
74         .label  L$loop
75         ldws            0(%r26),%r29
76         fldws,ma        4(%r25),%fr5
77         add             %r29,%r19,%r19
78         stws,ma         %r19,4(%r26)
79         addc            %r28,%r1,%r19
80         xmpyu           %fr4,%fr5,%fr6
81         ldw             -16(%r30),%r28
82         fstds           %fr6,-16(%r30)
83         addc            %r0,%r28,%r28
84         addib,<>        -1,%r24,L$loop
85          ldw            -12(%r30),%r1
86
87         .label  L$end
88         ldw             0(%r26),%r29
89         add             %r29,%r19,%r19
90         stws,ma         %r19,4(%r26)
91         addc            %r28,%r1,%r19
92         ldw             -16(%r30),%r28
93         ldws            0(%r26),%r29
94         addc            %r0,%r28,%r28
95         add             %r29,%r19,%r19
96         stws,ma         %r19,4(%r26)
97         addc            %r0,%r28,%r28
98         bv              0(%r2)
99          ldo            -64(%r30),%r30
100
101         .label L$just_one_limb
102         xmpyu           %fr4,%fr5,%fr6
103         ldw             0(%r26),%r29
104         fstds           %fr6,-16(%r30)
105         ldw             -12(%r30),%r1
106         ldw             -16(%r30),%r28
107         add             %r29,%r1,%r19
108         stw             %r19,0(%r26)
109         addc            %r0,%r28,%r28
110         bv              0(%r2)
111          ldo            -64(%r30),%r30
112
113         .exit
114         .procend
115
116