added assembler stuff for hppa
[gnupg.git] / mpi / hppa1.1 / mpih-mul3.S
1 /* hppa1.1   submul_1 -- Multiply a limb vector with a limb and add
2  *                       the result to a second limb vector.
3  *      Copyright (C) 1992, 1993, 1994 Free Software Foundation, Inc.
4  *      Copyright (c) 1997 by Werner Koch (dd9jn)
5  *
6  * This file is part of G10.
7  *
8  * G10 is free software; you can redistribute it and/or modify
9  * it under the terms of the GNU General Public License as published by
10  * the Free Software Foundation; either version 2 of the License, or
11  * (at your option) any later version.
12  *
13  * G10 is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16  * GNU General Public License for more details.
17  *
18  * You should have received a copy of the GNU General Public License
19  * along with this program; if not, write to the Free Software
20  * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
21  *
22  * Note: This code is heavily based on the GNU MP Library.
23  *       Actually it's the same code with only minor changes in the
24  *       way the data is stored; this is to support the abstraction
25  *       of an optional secure memory allocation which may be used
26  *       to avoid revealing of sensitive data due to paging etc.
27  *       The GNU MP Library itself is published under the LGPL;
28  *       however I decided to publish this code under the plain GPL.
29  */
30
31
32 /*******************
33  * mpi_limb_t
34  * mpihelp_submul_1( mpi_ptr_t res_ptr,      (r26)
35  *                   mpi_ptr_t s1_ptr,       (r25)
36  *                   mpi_size_t s1_size,     (r24)
37  *                   mpi_limb_t s2_limb)     (r23)
38  *
39  *
40  * This runs at 12 cycles/limb on a PA7000.  With the used instructions, it
41  * can not become faster due to data cache contention after a store.  On the
42  * PA7100 it runs at 11 cycles/limb, and that can not be improved either,
43  * since only the xmpyu does not need the integer pipeline, so the only
44  * dual-issue we will get are addc+xmpyu.  Unrolling could gain a cycle/limb
45  * on the PA7100.
46  *
47  * There are some ideas described in mul1.S that applies to this code too.
48  *
49  * It seems possible to make this run as fast as addmul_1, if we use
50  *       sub,>>= %r29,%r19,%r22
51  *       addi    1,%r28,%r28
52  * but that requires reworking the hairy software pipeline...
53  */
54
55
56         .code
57         .export         mpihelp_submul_1
58 mpihelp_submul_1
59         .proc
60         .callinfo       frame=64,no_calls
61         .entry
62
63         ldo             64(%r30),%r30
64         fldws,ma        4(%r25),%fr5
65         stw             %r23,-16(%r30)          ; move s2_limb ...
66         addib,=         -1,%r24,L$just_one_limb
67          fldws          -16(%r30),%fr4          ; ... into fr4
68         add             %r0,%r0,%r0             ; clear carry
69         xmpyu           %fr4,%fr5,%fr6
70         fldws,ma        4(%r25),%fr7
71         fstds           %fr6,-16(%r30)
72         xmpyu           %fr4,%fr7,%fr8
73         ldw             -12(%r30),%r19          ; least significant limb in product
74         ldw             -16(%r30),%r28
75
76         fstds           %fr8,-16(%r30)
77         addib,=         -1,%r24,L$end
78          ldw            -12(%r30),%r1
79
80 ; Main loop
81 L$loop  ldws            0(%r26),%r29
82         fldws,ma        4(%r25),%fr5
83         sub             %r29,%r19,%r22
84         add             %r22,%r19,%r0
85         stws,ma         %r22,4(%r26)
86         addc            %r28,%r1,%r19
87         xmpyu           %fr4,%fr5,%fr6
88         ldw             -16(%r30),%r28
89         fstds           %fr6,-16(%r30)
90         addc            %r0,%r28,%r28
91         addib,<>        -1,%r24,L$loop
92          ldw            -12(%r30),%r1
93
94 L$end   ldw             0(%r26),%r29
95         sub             %r29,%r19,%r22
96         add             %r22,%r19,%r0
97         stws,ma         %r22,4(%r26)
98         addc            %r28,%r1,%r19
99         ldw             -16(%r30),%r28
100         ldws            0(%r26),%r29
101         addc            %r0,%r28,%r28
102         sub             %r29,%r19,%r22
103         add             %r22,%r19,%r0
104         stws,ma         %r22,4(%r26)
105         addc            %r0,%r28,%r28
106         bv              0(%r2)
107          ldo            -64(%r30),%r30
108
109 L$just_one_limb
110         xmpyu           %fr4,%fr5,%fr6
111         ldw             0(%r26),%r29
112         fstds           %fr6,-16(%r30)
113         ldw             -12(%r30),%r1
114         ldw             -16(%r30),%r28
115         sub             %r29,%r1,%r22
116         add             %r22,%r1,%r0
117         stw             %r22,0(%r26)
118         addc            %r0,%r28,%r28
119         bv              0(%r2)
120          ldo            -64(%r30),%r30
121
122         .exit
123         .procend
124