Switched to GPLv3.
[gnupg.git] / mpi / i386 / mpih-rshift.S
1 /* i80386   rshift
2  *
3  *      Copyright (C) 1992, 1994, 1998, 
4  *                    2001, 2002 Free Software Foundation, Inc.
5  *
6  * This file is part of GnuPG.
7  *
8  * GnuPG is free software; you can redistribute it and/or modify
9  * it under the terms of the GNU General Public License as published by
10  * the Free Software Foundation; either version 3 of the License, or
11  * (at your option) any later version.
12  *
13  * GnuPG is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16  * GNU General Public License for more details.
17  *
18  * You should have received a copy of the GNU General Public License
19  * along with this program; if not, see <http://www.gnu.org/licenses/>.
20  *
21  * Note: This code is heavily based on the GNU MP Library.
22  *       Actually it's the same code with only minor changes in the
23  *       way the data is stored; this is to support the abstraction
24  *       of an optional secure memory allocation which may be used
25  *       to avoid revealing of sensitive data due to paging etc.
26  *       The GNU MP Library itself is published under the LGPL;
27  *       however I decided to publish this code under the plain GPL.
28  */
29
30
31 #include "sysdep.h"
32 #include "asm-syntax.h"
33
34
35 /*******************
36  * mpi_limb_t
37  * mpihelp_rshift( mpi_ptr_t wp,        (sp + 4)
38  *                 mpi_ptr_t up,        (sp + 8)
39  *                 mpi_size_t usize,    (sp + 12)
40  *                 unsigned cnt)        (sp + 16)
41  */
42
43 .text
44         ALIGN (3)
45         .globl C_SYMBOL_NAME(mpihelp_rshift)
46 C_SYMBOL_NAME(mpihelp_rshift:)
47         pushl   %edi
48         pushl   %esi
49         pushl   %ebx
50
51         movl    16(%esp),%edi           /* wp */
52         movl    20(%esp),%esi           /* up */
53         movl    24(%esp),%edx           /* usize */
54         movl    28(%esp),%ecx           /* cnt */
55
56         leal    -4(%edi,%edx,4),%edi
57         leal    (%esi,%edx,4),%esi
58         negl    %edx
59
60         movl    (%esi,%edx,4),%ebx      /* read least significant limb */
61         xorl    %eax,%eax
62         shrdl   %ebx,%eax               /* compute carry limb */
63         incl    %edx
64         jz      Lend2
65         pushl   %eax                    /* push carry limb onto stack */
66         testb   $1,%dl
67         jnz     L2                      /* enter loop in the middle */
68         movl    %ebx,%eax
69
70         ALIGN (3)
71 Loop2:  movl     (%esi,%edx,4),%ebx      /* load next higher limb */
72         shrdl   %ebx,%eax               /* compute result limb */
73         movl    %eax,(%edi,%edx,4)      /* store it */
74         incl    %edx
75 L2:     movl    (%esi,%edx,4),%eax
76         shrdl   %eax,%ebx
77         movl    %ebx,(%edi,%edx,4)
78         incl    %edx
79         jnz     Loop2
80
81         shrl    %cl,%eax                /* compute most significant limb */
82         movl    %eax,(%edi)             /* store it */
83
84         popl    %eax                    /* pop carry limb */
85
86         popl    %ebx
87         popl    %esi
88         popl    %edi
89         ret
90
91 Lend2:  shrl    %cl,%ebx                /* compute most significant limb */
92         movl    %ebx,(%edi)             /* store it */
93
94         popl    %ebx
95         popl    %esi
96         popl    %edi
97         ret
98