Switched to GPLv3.
[gnupg.git] / mpi / m68k / mc68020 / mpih-mul2.S
1 /* mc68020 __mpn_addmul_1 -- Multiply a limb vector with a limb and add
2  *                           the result to a second limb vector.
3  *
4  *      Copyright (C) 1992, 1994, 1996, 1998, 
5  *                    2001 Free Software Foundation, Inc.
6  *       
7  * This file is part of GnuPG.
8  *
9  * GnuPG is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU General Public License as published by
11  * the Free Software Foundation; either version 3 of the License, or
12  * (at your option) any later version.
13  *
14  * GnuPG is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU General Public License for more details.
18  *
19  * You should have received a copy of the GNU General Public License
20  * along with this program; if not, see <http://www.gnu.org/licenses/>.
21  *
22  * Note: This code is heavily based on the GNU MP Library.
23  *       Actually it's the same code with only minor changes in the
24  *       way the data is stored; this is to support the abstraction
25  *       of an optional secure memory allocation which may be used
26  *       to avoid revealing of sensitive data due to paging etc.
27  *       The GNU MP Library itself is published under the LGPL;
28  *       however I decided to publish this code under the plain GPL.
29  */
30
31
32 #include "sysdep.h"
33 #include "asm-syntax.h"
34
35 /*******************
36  * mpi_limb_t
37  * mpihelp_addmul_1( mpi_ptr_t res_ptr,      (sp + 4)
38  *                   mpi_ptr_t s1_ptr,       (sp + 8)
39  *                   mpi_size_t s1_size,     (sp + 12)
40  *                   mpi_limb_t s2_limb)     (sp + 16)
41  */
42
43
44         TEXT
45         ALIGN
46         GLOBL   C_SYMBOL_NAME(mpihelp_addmul_1)
47
48 C_SYMBOL_NAME(mpihelp_addmul_1:)
49 PROLOG(mpihelp_addmul_1)
50
51 #define res_ptr a0
52 #define s1_ptr a1
53 #define s1_size d2
54 #define s2_limb d4
55
56 /* Save used registers on the stack.  */
57         moveml  R(d2)-R(d5),MEM_PREDEC(sp)
58
59 /* Copy the arguments to registers.  Better use movem?  */
60         movel   MEM_DISP(sp,20),R(res_ptr)
61         movel   MEM_DISP(sp,24),R(s1_ptr)
62         movel   MEM_DISP(sp,28),R(s1_size)
63         movel   MEM_DISP(sp,32),R(s2_limb)
64
65         eorw    #1,R(s1_size)
66         clrl    R(d1)
67         clrl    R(d5)
68         lsrl    #1,R(s1_size)
69         bcc     L(L1)
70         subql   #1,R(s1_size)
71         subl    R(d0),R(d0)             /* (d0,cy) <= (0,0) */
72
73 L(Loop:)
74         movel   MEM_POSTINC(s1_ptr),R(d3)
75         mulul   R(s2_limb),R(d1):R(d3)
76         addxl   R(d0),R(d3)
77         addxl   R(d5),R(d1)
78         addl    R(d3),MEM_POSTINC(res_ptr)
79 L(L1:)  movel   MEM_POSTINC(s1_ptr),R(d3)
80         mulul   R(s2_limb),R(d0):R(d3)
81         addxl   R(d1),R(d3)
82         addxl   R(d5),R(d0)
83         addl    R(d3),MEM_POSTINC(res_ptr)
84
85         dbf     R(s1_size),L(Loop)
86         addxl   R(d5),R(d0)
87         subl    #0x10000,R(s1_size)
88         bcc     L(Loop)
89
90 /* Restore used registers from stack frame.  */
91         moveml  MEM_POSTINC(sp),R(d2)-R(d5)
92
93         rts
94 EPILOG(mpihelp_addmul_1)
95