Switched to GPLv3.
[gnupg.git] / mpi / m68k / mc68020 / mpih-mul3.S
1 /* mc68020 __mpn_submul_1 -- Multiply a limb vector with a limb and subtract
2  *                           the result from a second limb vector.
3  *
4  *      Copyright (C) 1992, 1994, 1996, 1998, 
5  *                    2001 Free Software Foundation, Inc.
6  *       
7  * This file is part of GnuPG.
8  *
9  * GnuPG is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU General Public License as published by
11  * the Free Software Foundation; either version 3 of the License, or
12  * (at your option) any later version.
13  *
14  * GnuPG is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU General Public License for more details.
18  *
19  * You should have received a copy of the GNU General Public License
20  * along with this program; if not, see <http://www.gnu.org/licenses/>.
21  *
22  * Note: This code is heavily based on the GNU MP Library.
23  *       Actually it's the same code with only minor changes in the
24  *       way the data is stored; this is to support the abstraction
25  *       of an optional secure memory allocation which may be used
26  *       to avoid revealing of sensitive data due to paging etc.
27  *       The GNU MP Library itself is published under the LGPL;
28  *       however I decided to publish this code under the plain GPL.
29  */
30
31
32
33
34 #include "sysdep.h"
35 #include "asm-syntax.h"
36
37 /*******************
38  * mpi_limb_t
39  * mpihelp_submul_1( mpi_ptr_t res_ptr,      (sp + 4)
40  *                   mpi_ptr_t s1_ptr,       (sp + 8)
41  *                   mpi_size_t s1_size,     (sp + 12)
42  *                   mpi_limb_t s2_limb)     (sp + 16)
43  */
44
45
46         TEXT
47         ALIGN
48         GLOBL   C_SYMBOL_NAME(mpihelp_submul_1)
49
50 C_SYMBOL_NAME(mpihelp_submul_1:)
51 PROLOG(mpihelp_submul_1)
52
53 #define res_ptr a0
54 #define s1_ptr a1
55 #define s1_size d2
56 #define s2_limb d4
57
58 /* Save used registers on the stack.  */
59         moveml  R(d2)-R(d5),MEM_PREDEC(sp)
60
61 /* Copy the arguments to registers.  Better use movem?  */
62         movel   MEM_DISP(sp,20),R(res_ptr)
63         movel   MEM_DISP(sp,24),R(s1_ptr)
64         movel   MEM_DISP(sp,28),R(s1_size)
65         movel   MEM_DISP(sp,32),R(s2_limb)
66
67         eorw    #1,R(s1_size)
68         clrl    R(d1)
69         clrl    R(d5)
70         lsrl    #1,R(s1_size)
71         bcc     L(L1)
72         subql   #1,R(s1_size)
73         subl    R(d0),R(d0)     /* (d0,cy) <= (0,0) */
74
75 L(Loop:)
76         movel   MEM_POSTINC(s1_ptr),R(d3)
77         mulul   R(s2_limb),R(d1):R(d3)
78         addxl   R(d0),R(d3)
79         addxl   R(d5),R(d1)
80         subl    R(d3),MEM_POSTINC(res_ptr)
81 L(L1:)  movel   MEM_POSTINC(s1_ptr),R(d3)
82         mulul   R(s2_limb),R(d0):R(d3)
83         addxl   R(d1),R(d3)
84         addxl   R(d5),R(d0)
85         subl    R(d3),MEM_POSTINC(res_ptr)
86
87         dbf     R(s1_size),L(Loop)
88         addxl   R(d5),R(d0)
89         subl    #0x10000,R(s1_size)
90         bcc     L(Loop)
91
92 /* Restore used registers from stack frame.  */
93         moveml  MEM_POSTINC(sp),R(d2)-R(d5)
94
95         rts
96 EPILOG(mpihelp_submul_1)
97
98