mpi/m68k/mpih-add1.S

   1 /* mc68020 __mpn_add_n -- Add two limb vectors of the same length > 0 and store
   2  *                        sum in a third limb vector.
   3  *
   4  *      Copyright (C) 1992, 1994,1996, 1998,
   5  *                    2001 Free Software Foundation, Inc.
   6  *
   7  * This file is part of GnuPG.
   8  *
   9  * GnuPG is free software; you can redistribute it and/or modify
  10  * it under the terms of the GNU General Public License as published by
  11  * the Free Software Foundation; either version 3 of the License, or
  12  * (at your option) any later version.
  13  *
  14  * GnuPG is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, see <http://www.gnu.org/licenses/>.
  21  *
  22  * Note: This code is heavily based on the GNU MP Library.
  23  *       Actually it's the same code with only minor changes in the
  24  *       way the data is stored; this is to support the abstraction
  25  *       of an optional secure memory allocation which may be used
  26  *       to avoid revealing of sensitive data due to paging etc.
  27  *       The GNU MP Library itself is published under the LGPL;
  28  *       however I decided to publish this code under the plain GPL.
  29  */
  30
  31
  32 #include "sysdep.h"
  33 #include "asm-syntax.h"
  34
  35
  36 /*******************
  37  *  mpi_limb_t
  38  *  mpihelp_add_n( mpi_ptr_t res_ptr,   (sp + 4)
  39  *                 mpi_ptr_t s1_ptr,    (sp + 8)
  40  *                 mpi_ptr_t s2_ptr,    (sp + 16)
  41  *                 mpi_size_t size)     (sp + 12)
  42  */
  43
  44
  45         TEXT
  46         ALIGN
  47         GLOBL   C_SYMBOL_NAME(mpihelp_add_n)
  48
  49 C_SYMBOL_NAME(mpihelp_add_n:)
  50 PROLOG(mpihelp_add_n)
  51         /* Save used registers on the stack.  */
  52         movel   R(d2),MEM_PREDEC(sp)
  53         movel   R(a2),MEM_PREDEC(sp)
  54
  55         /* Copy the arguments to registers.  Better use movem?  */
  56         movel   MEM_DISP(sp,12),R(a2)
  57         movel   MEM_DISP(sp,16),R(a0)
  58         movel   MEM_DISP(sp,20),R(a1)
  59         movel   MEM_DISP(sp,24),R(d2)
  60
  61         eorw    #1,R(d2)
  62         lsrl    #1,R(d2)
  63         bcc     L(L1)
  64         subql   #1,R(d2)        /* clears cy as side effect */
  65
  66 L(Loop:)
  67         movel   MEM_POSTINC(a0),R(d0)
  68         movel   MEM_POSTINC(a1),R(d1)
  69         addxl   R(d1),R(d0)
  70         movel   R(d0),MEM_POSTINC(a2)
  71 L(L1:)  movel   MEM_POSTINC(a0),R(d0)
  72         movel   MEM_POSTINC(a1),R(d1)
  73         addxl   R(d1),R(d0)
  74         movel   R(d0),MEM_POSTINC(a2)
  75
  76         dbf     R(d2),L(Loop)           /* loop until 16 lsb of %4 == -1 */
  77         subxl   R(d0),R(d0)     /* d0 <= -cy; save cy as 0 or -1 in d0 */
  78         subl    #0x10000,R(d2)
  79         bcs     L(L2)
  80         addl    R(d0),R(d0)     /* restore cy */
  81         bra     L(Loop)
  82
  83 L(L2:)
  84         negl    R(d0)
  85
  86         /* Restore used registers from stack frame.  */
  87         movel   MEM_POSTINC(sp),R(a2)
  88         movel   MEM_POSTINC(sp),R(d2)
  89
  90         rts
  91 EPILOG(mpihelp_add_n)
  92
  93