Switched to GPLv3.
[gnupg.git] / mpi / m68k / mpih-sub1.S
1 /* mc68020 __mpn_sub_n -- Subtract two limb vectors of the same length > 0 and
2  *                        store difference in a third limb vector.
3  *
4  *      Copyright (C) 1992, 1994, 1996, 1998, 
5  *                    2001 Free Software Foundation, Inc.
6  *       
7  * This file is part of GnuPG.
8  *
9  * GnuPG is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU General Public License as published by
11  * the Free Software Foundation; either version 3 of the License, or
12  * (at your option) any later version.
13  *
14  * GnuPG is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU General Public License for more details.
18  *
19  * You should have received a copy of the GNU General Public License
20  * along with this program; if not, see <http://www.gnu.org/licenses/>.
21  *
22  * Note: This code is heavily based on the GNU MP Library.
23  *       Actually it's the same code with only minor changes in the
24  *       way the data is stored; this is to support the abstraction
25  *       of an optional secure memory allocation which may be used
26  *       to avoid revealing of sensitive data due to paging etc.
27  *       The GNU MP Library itself is published under the LGPL;
28  *       however I decided to publish this code under the plain GPL.
29  */
30
31 #include "sysdep.h"
32 #include "asm-syntax.h"
33
34
35 /*******************
36  *  mpi_limb_t
37  *  mpihelp_sub_n( mpi_ptr_t res_ptr,   (sp + 4)
38  *                 mpi_ptr_t s1_ptr,    (sp + 8)
39  *                 mpi_ptr_t s2_ptr,    (sp + 16)
40  *                 mpi_size_t size)     (sp + 12)
41  */
42
43
44         TEXT
45         ALIGN
46         GLOBL   C_SYMBOL_NAME(mpihelp_sub_n)
47
48 C_SYMBOL_NAME(mpihelp_sub_n:)
49 PROLOG(mpihelp_sub_n)
50 /* Save used registers on the stack.  */
51         movel   R(d2),MEM_PREDEC(sp)
52         movel   R(a2),MEM_PREDEC(sp)
53
54 /* Copy the arguments to registers.  Better use movem?  */
55         movel   MEM_DISP(sp,12),R(a2)
56         movel   MEM_DISP(sp,16),R(a0)
57         movel   MEM_DISP(sp,20),R(a1)
58         movel   MEM_DISP(sp,24),R(d2)
59
60         eorw    #1,R(d2)
61         lsrl    #1,R(d2)
62         bcc     L(L1)
63         subql   #1,R(d2)        /* clears cy as side effect */
64
65 L(Loop:)
66         movel   MEM_POSTINC(a0),R(d0)
67         movel   MEM_POSTINC(a1),R(d1)
68         subxl   R(d1),R(d0)
69         movel   R(d0),MEM_POSTINC(a2)
70 L(L1:)  movel   MEM_POSTINC(a0),R(d0)
71         movel   MEM_POSTINC(a1),R(d1)
72         subxl   R(d1),R(d0)
73         movel   R(d0),MEM_POSTINC(a2)
74
75         dbf     R(d2),L(Loop)           /* loop until 16 lsb of %4 == -1 */
76         subxl   R(d0),R(d0)     /* d0 <= -cy; save cy as 0 or -1 in d0 */
77         subl    #0x10000,R(d2)
78         bcs     L(L2)
79         addl    R(d0),R(d0)     /* restore cy */
80         bra     L(Loop)
81
82 L(L2:)
83         negl    R(d0)
84
85 /* Restore used registers from stack frame.  */
86         movel   MEM_POSTINC(sp),R(a2)
87         movel   MEM_POSTINC(sp),R(d2)
88
89         rts
90 EPILOG(mpihelp_sub_n)
91
92