Switched to GPLv3.
[gnupg.git] / mpi / mips3 / mpih-lshift.S
1 /* mips3    lshift
2  *
3  *      Copyright (C) 1995, 1998, 2000,
4  *                    2001 Free Software Foundation, Inc.
5  *
6  * This file is part of GnuPG.
7  *
8  * GnuPG is free software; you can redistribute it and/or modify
9  * it under the terms of the GNU General Public License as published by
10  * the Free Software Foundation; either version 3 of the License, or
11  * (at your option) any later version.
12  *
13  * GnuPG is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16  * GNU General Public License for more details.
17  *
18  * You should have received a copy of the GNU General Public License
19  * along with this program; if not, see <http://www.gnu.org/licenses/>.
20  */
21
22 /*******************
23  * mpi_limb_t
24  * mpihelp_lshift( mpi_ptr_t wp,        ($4)
25  *                 mpi_ptr_t up,        ($5)
26  *                 mpi_size_t usize,    ($6)
27  *                 unsigned cnt)        ($7)
28  */
29
30         .text
31         .align  2
32         .globl  mpihelp_lshift
33         .ent    mpihelp_lshift
34 mpihelp_lshift:
35         .set    noreorder
36         .set    nomacro
37
38         dsll    $2,$6,3
39         daddu   $5,$5,$2        # make r5 point at end of src
40         ld      $10,-8($5)      # load first limb
41         dsubu   $13,$0,$7
42         daddu   $4,$4,$2        # make r4 point at end of res
43         daddiu  $6,$6,-1
44         and     $9,$6,4-1       # number of limbs in first loop
45         beq     $9,$0,.L0       # if multiple of 4 limbs, skip first loop
46          dsrl   $2,$10,$13      # compute function result
47
48         dsubu   $6,$6,$9
49
50 .Loop0: ld      $3,-16($5)
51         daddiu  $4,$4,-8
52         daddiu  $5,$5,-8
53         daddiu  $9,$9,-1
54         dsll    $11,$10,$7
55         dsrl    $12,$3,$13
56         move    $10,$3
57         or      $8,$11,$12
58         bne     $9,$0,.Loop0
59          sd     $8,0($4)
60
61 .L0:    beq     $6,$0,.Lend
62          nop
63
64 .Loop:  ld      $3,-16($5)
65         daddiu  $4,$4,-32
66         daddiu  $6,$6,-4
67         dsll    $11,$10,$7
68         dsrl    $12,$3,$13
69
70         ld      $10,-24($5)
71         dsll    $14,$3,$7
72         or      $8,$11,$12
73         sd      $8,24($4)
74         dsrl    $9,$10,$13
75
76         ld      $3,-32($5)
77         dsll    $11,$10,$7
78         or      $8,$14,$9
79         sd      $8,16($4)
80         dsrl    $12,$3,$13
81
82         ld      $10,-40($5)
83         dsll    $14,$3,$7
84         or      $8,$11,$12
85         sd      $8,8($4)
86         dsrl    $9,$10,$13
87
88         daddiu  $5,$5,-32
89         or      $8,$14,$9
90         bgtz    $6,.Loop
91          sd     $8,0($4)
92
93 .Lend:  dsll    $8,$10,$7
94         j       $31
95         sd      $8,-8($4)
96         .end    mpihelp_lshift