Switched to GPLv3.
[gnupg.git] / mpi / power / mpih-mul1.S
1 /* IBM POWER  mul_1 -- Multiply a limb vector with a limb and store
2  *                     the result in a second limb vector.
3  *
4  *      Copyright (C) 1992, 1994, 1999 Free Software Foundation, Inc.
5  *
6  * This file is part of GnuPG.
7  *
8  * GnuPG is free software; you can redistribute it and/or modify
9  * it under the terms of the GNU General Public License as published by
10  * the Free Software Foundation; either version 3 of the License, or
11  * (at your option) any later version.
12  *
13  * GnuPG is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16  * GNU General Public License for more details.
17  *
18  * You should have received a copy of the GNU General Public License
19  * along with this program; if not, see <http://www.gnu.org/licenses/>.
20  */
21
22 #include "sysdep.h"
23 #include "asm-syntax.h"
24
25 /*
26 # INPUT PARAMETERS
27 # res_ptr       r3
28 # s1_ptr        r4
29 # size          r5
30 # s2_limb       r6
31
32 # The RS/6000 has no unsigned 32x32->64 bit multiplication instruction.  To
33 # obtain that operation, we have to use the 32x32->64 signed multiplication
34 # instruction, and add the appropriate compensation to the high limb of the
35 # result.  We add the multiplicand if the multiplier has its most significant
36 # bit set, and we add the multiplier if the multiplicand has its most
37 # significant bit set.  We need to preserve the carry flag between each
38 # iteration, so we have to compute the compensation carefully (the natural,
39 # srai+and doesn't work).  Since the POWER architecture has a branch unit
40 # we can branch in zero cycles, so that's how we perform the additions.
41  */
42
43         .toc
44         .csect .mpihelp_mul_1[PR]
45         .align 2
46         .globl mpihelp_mul_1
47         .globl .mpihelp_mul_1
48         .csect mpihelp_mul_1[DS]
49 mpihelp_mul_1:
50         .long .mpihelp_mul_1[PR], TOC[tc0], 0
51         .csect .mpihelp_mul_1[PR]
52 .mpihelp_mul_1:
53
54         cal     3,-4(3)
55         l       0,0(4)
56         cmpi    0,6,0
57         mtctr   5
58         mul     9,0,6
59         srai    7,0,31
60         and     7,7,6
61         mfmq    8
62         ai      0,0,0           # reset carry
63         cax     9,9,7
64         blt     Lneg
65 Lpos:   bdz     Lend
66 Lploop: lu      0,4(4)
67         stu     8,4(3)
68         cmpi    0,0,0
69         mul     10,0,6
70         mfmq    0
71         ae      8,0,9
72         bge     Lp0
73         cax     10,10,6         # adjust high limb for negative limb from s1
74 Lp0:    bdz     Lend0
75         lu      0,4(4)
76         stu     8,4(3)
77         cmpi    0,0,0
78         mul     9,0,6
79         mfmq    0
80         ae      8,0,10
81         bge     Lp1
82         cax     9,9,6           # adjust high limb for negative limb from s1
83 Lp1:    bdn     Lploop
84         b       Lend
85
86 Lneg:   cax     9,9,0
87         bdz     Lend
88 Lnloop: lu      0,4(4)
89         stu     8,4(3)
90         cmpi    0,0,0
91         mul     10,0,6
92         cax     10,10,0         # adjust high limb for negative s2_limb
93         mfmq    0
94         ae      8,0,9
95         bge     Ln0
96         cax     10,10,6         # adjust high limb for negative limb from s1
97 Ln0:    bdz     Lend0
98         lu      0,4(4)
99         stu     8,4(3)
100         cmpi    0,0,0
101         mul     9,0,6
102         cax     9,9,0           # adjust high limb for negative s2_limb
103         mfmq    0
104         ae      8,0,10
105         bge     Ln1
106         cax     9,9,6           # adjust high limb for negative limb from s1
107 Ln1:    bdn     Lnloop
108         b       Lend
109
110 Lend0:  cal     9,0(10)
111 Lend:   st      8,4(3)
112         aze     3,9
113         br
114