Switched to GPLv3.
[gnupg.git] / mpi / power / mpih-mul2.S
1 /* IBM POWER addmul_1 -- Multiply a limb vector with a limb and add
2  *                       the result to a second limb vector.
3  *
4  *      Copyright (C) 1992, 1994, 1999 Free Software Foundation, Inc.
5  *
6  * This file is part of GnuPG.
7  *
8  * GnuPG is free software; you can redistribute it and/or modify
9  * it under the terms of the GNU General Public License as published by
10  * the Free Software Foundation; either version 3 of the License, or
11  * (at your option) any later version.
12  *
13  * GnuPG is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16  * GNU General Public License for more details.
17  *
18  * You should have received a copy of the GNU General Public License
19  * along with this program; if not, see <http://www.gnu.org/licenses/>.
20  */
21
22 #include "sysdep.h"
23 #include "asm-syntax.h"
24
25
26
27 /*
28 # INPUT PARAMETERS
29 # res_ptr       r3
30 # s1_ptr        r4
31 # size          r5
32 # s2_limb       r6
33
34 # The RS/6000 has no unsigned 32x32->64 bit multiplication instruction.  To
35 # obtain that operation, we have to use the 32x32->64 signed multiplication
36 # instruction, and add the appropriate compensation to the high limb of the
37 # result.  We add the multiplicand if the multiplier has its most significant
38 # bit set, and we add the multiplier if the multiplicand has its most
39 # significant bit set.  We need to preserve the carry flag between each
40 # iteration, so we have to compute the compensation carefully (the natural,
41 # srai+and doesn't work).  Since the POWER architecture has a branch unit
42 # we can branch in zero cycles, so that's how we perform the additions.
43  */
44
45         .toc
46         .csect .mpihelp_addmul_1[PR]
47         .align 2
48         .globl mpihelp_addmul_1
49         .globl .mpihelp_addmul_1
50         .csect mpihelp_addmul_1[DS]
51 mpihelp_addmul_1:
52         .long .mpihelp_addmul_1[PR], TOC[tc0], 0
53         .csect .mpihelp_addmul_1[PR]
54 .mpihelp_addmul_1:
55
56         cal     3,-4(3)
57         l       0,0(4)
58         cmpi    0,6,0
59         mtctr   5
60         mul     9,0,6
61         srai    7,0,31
62         and     7,7,6
63         mfmq    8
64         cax     9,9,7
65         l       7,4(3)
66         a       8,8,7           # add res_limb
67         blt     Lneg
68 Lpos:   bdz     Lend
69
70 Lploop: lu      0,4(4)
71         stu     8,4(3)
72         cmpi    0,0,0
73         mul     10,0,6
74         mfmq    0
75         ae      8,0,9           # low limb + old_cy_limb + old cy
76         l       7,4(3)
77         aze     10,10           # propagate cy to new cy_limb
78         a       8,8,7           # add res_limb
79         bge     Lp0
80         cax     10,10,6         # adjust high limb for negative limb from s1
81 Lp0:    bdz     Lend0
82         lu      0,4(4)
83         stu     8,4(3)
84         cmpi    0,0,0
85         mul     9,0,6
86         mfmq    0
87         ae      8,0,10
88         l       7,4(3)
89         aze     9,9
90         a       8,8,7
91         bge     Lp1
92         cax     9,9,6           # adjust high limb for negative limb from s1
93 Lp1:    bdn     Lploop
94
95         b       Lend
96
97 Lneg:   cax     9,9,0
98         bdz     Lend
99 Lnloop: lu      0,4(4)
100         stu     8,4(3)
101         cmpi    0,0,0
102         mul     10,0,6
103         mfmq    7
104         ae      8,7,9
105         l       7,4(3)
106         ae      10,10,0         # propagate cy to new cy_limb
107         a       8,8,7           # add res_limb
108         bge     Ln0
109         cax     10,10,6         # adjust high limb for negative limb from s1
110 Ln0:    bdz     Lend0
111         lu      0,4(4)
112         stu     8,4(3)
113         cmpi    0,0,0
114         mul     9,0,6
115         mfmq    7
116         ae      8,7,10
117         l       7,4(3)
118         ae      9,9,0           # propagate cy to new cy_limb
119         a       8,8,7           # add res_limb
120         bge     Ln1
121         cax     9,9,6           # adjust high limb for negative limb from s1
122 Ln1:    bdn     Lnloop
123         b       Lend
124
125 Lend0:  cal     9,0(10)
126 Lend:   st      8,4(3)
127         aze     3,9
128         br
129