d9f594f8667cf80ea6b00f05904d3cbf8cb35c4f
[gnupg.git] / scripts / gitlog-to-changelog
1 eval '(exit $?0)' && eval 'exec perl -wS "$0" ${1+"$@"}'
2   & eval 'exec perl -wS "$0" $argv:q'
3     if 0;
4 # Convert git log output to ChangeLog format.
5
6 my $VERSION = '2011-11-02 07:53'; # UTC
7 # The definition above must lie within the first 8 lines in order
8 # for the Emacs time-stamp write hook (at end) to update it.
9 # If you change this file with Emacs, please let the write hook
10 # do its job.  Otherwise, update this string manually.
11
12 # Copyright (C) 2008-2011 Free Software Foundation, Inc.
13
14 # This program is free software: you can redistribute it and/or modify
15 # it under the terms of the GNU General Public License as published by
16 # the Free Software Foundation, either version 3 of the License, or
17 # (at your option) any later version.
18
19 # This program is distributed in the hope that it will be useful,
20 # but WITHOUT ANY WARRANTY; without even the implied warranty of
21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
22 # GNU General Public License for more details.
23
24 # You should have received a copy of the GNU General Public License
25 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
26
27 # Written by Jim Meyering
28
29 use strict;
30 use warnings;
31 use Getopt::Long;
32 use POSIX qw(strftime);
33
34 (my $ME = $0) =~ s|.*/||;
35
36 # use File::Coda; # http://meyering.net/code/Coda/
37 END {
38   defined fileno STDOUT or return;
39   close STDOUT and return;
40   warn "$ME: failed to close standard output: $!\n";
41   $? ||= 1;
42 }
43
44 sub usage ($)
45 {
46   my ($exit_code) = @_;
47   my $STREAM = ($exit_code == 0 ? *STDOUT : *STDERR);
48   if ($exit_code != 0)
49     {
50       print $STREAM "Try `$ME --help' for more information.\n";
51     }
52   else
53     {
54       print $STREAM <<EOF;
55 Usage: $ME [OPTIONS] [ARGS]
56
57 Convert git log output to ChangeLog format.  If present, any ARGS
58 are passed to "git log".  To avoid ARGS being parsed as options to
59 $ME, they may be preceded by '--'.
60
61 OPTIONS:
62
63    --amend=FILE FILE maps from an SHA1 to perl code (i.e., s/old/new/) that
64                   makes a change to SHA1's commit log text or metadata.
65    --append-dot append a dot to the first line of each commit message if
66                   there is no other punctuation or blank at the end.
67    --tear-off   tear off all commit log lines after a '--' line.
68    --since=DATE convert only the logs since DATE;
69                   the default is to convert all log entries.
70    --format=FMT set format string for commit subject and body;
71                   see 'man git-log' for the list of format metacharacters;
72                   the default is '%s%n%b%n'
73
74    --help       display this help and exit
75    --version    output version information and exit
76
77 EXAMPLE:
78
79   $ME --since=2008-01-01 > ChangeLog
80   $ME -- -n 5 foo > last-5-commits-to-branch-foo
81
82 In a FILE specified via --amend, comment lines (starting with "#") are ignored.
83 FILE must consist of <SHA,CODE+> pairs where SHA is a 40-byte SHA1 (alone on
84 a line) referring to a commit in the current project, and CODE refers to one
85 or more consecutive lines of Perl code.  Pairs must be separated by one or
86 more blank line.
87
88 Here is sample input for use with --amend=FILE, from coreutils:
89
90 3a169f4c5d9159283548178668d2fae6fced3030
91 # fix typo in title:
92 s/all tile types/all file types/
93
94 1379ed974f1fa39b12e2ffab18b3f7a607082202
95 # Due to a bug in vc-dwim, I mis-attributed a patch by Paul to myself.
96 # Change the author to be Paul.  Note the escaped "@":
97 s,Jim .*>,Paul Eggert <eggert\@cs.ucla.edu>,
98
99 EOF
100     }
101   exit $exit_code;
102 }
103
104 # If the string $S is a well-behaved file name, simply return it.
105 # If it contains white space, quotes, etc., quote it, and return the new string.
106 sub shell_quote($)
107 {
108   my ($s) = @_;
109   if ($s =~ m![^\w+/.,-]!)
110     {
111       # Convert each single quote to '\''
112       $s =~ s/\'/\'\\\'\'/g;
113       # Then single quote the string.
114       $s = "'$s'";
115     }
116   return $s;
117 }
118
119 sub quoted_cmd(@)
120 {
121   return join (' ', map {shell_quote $_} @_);
122 }
123
124 # Parse file F.
125 # Comment lines (starting with "#") are ignored.
126 # F must consist of <SHA,CODE+> pairs where SHA is a 40-byte SHA1
127 # (alone on a line) referring to a commit in the current project, and
128 # CODE refers to one or more consecutive lines of Perl code.
129 # Pairs must be separated by one or more blank line.
130 sub parse_amend_file($)
131 {
132   my ($f) = @_;
133
134   open F, '<', $f
135     or die "$ME: $f: failed to open for reading: $!\n";
136
137   my $fail;
138   my $h = {};
139   my $in_code = 0;
140   my $sha;
141   while (defined (my $line = <F>))
142     {
143       $line =~ /^\#/
144         and next;
145       chomp $line;
146       $line eq ''
147         and $in_code = 0, next;
148
149       if (!$in_code)
150         {
151           $line =~ /^([0-9a-fA-F]{40})$/
152             or (warn "$ME: $f:$.: invalid line; expected an SHA1\n"),
153               $fail = 1, next;
154           $sha = lc $1;
155           $in_code = 1;
156           exists $h->{$sha}
157             and (warn "$ME: $f:$.: duplicate SHA1\n"),
158               $fail = 1, next;
159         }
160       else
161         {
162           $h->{$sha} ||= '';
163           $h->{$sha} .= "$line\n";
164         }
165     }
166   close F;
167
168   $fail
169     and exit 1;
170
171   return $h;
172 }
173
174 {
175   my $since_date;
176   my $format_string = '%s%n%b%n';
177   my $amend_file;
178   my $append_dot = 0;
179   my $tear_off = 0;
180   GetOptions
181     (
182      help => sub { usage 0 },
183      version => sub { print "$ME version $VERSION\n"; exit },
184      'since=s' => \$since_date,
185      'format=s' => \$format_string,
186      'amend=s' => \$amend_file,
187      'append-dot' => \$append_dot,
188      'tear-off' => \$tear_off,
189     ) or usage 1;
190
191
192   defined $since_date
193     and unshift @ARGV, "--since=$since_date";
194
195   # This is a hash that maps an SHA1 to perl code (i.e., s/old/new/)
196   # that makes a correction in the log or attribution of that commit.
197   my $amend_code = defined $amend_file ? parse_amend_file $amend_file : {};
198
199   my @cmd = (qw (git log --log-size),
200              '--pretty=format:%H:%ct  %an  <%ae>%n%n'.$format_string, @ARGV);
201   open PIPE, '-|', @cmd
202     or die ("$ME: failed to run `". quoted_cmd (@cmd) ."': $!\n"
203             . "(Is your Git too old?  Version 1.5.1 or later is required.)\n");
204
205   my $prev_date_line = '';
206   my @prev_coauthors = ();
207   while (1)
208     {
209       defined (my $in = <PIPE>)
210         or last;
211       $in =~ /^log size (\d+)$/
212         or die "$ME:$.: Invalid line (expected log size):\n$in";
213       my $log_nbytes = $1;
214
215       my $log;
216       my $n_read = read PIPE, $log, $log_nbytes;
217       $n_read == $log_nbytes
218         or die "$ME:$.: unexpected EOF\n";
219
220       # Extract leading hash.
221       my ($sha, $rest) = split ':', $log, 2;
222       defined $sha
223         or die "$ME:$.: malformed log entry\n";
224       $sha =~ /^[0-9a-fA-F]{40}$/
225         or die "$ME:$.: invalid SHA1: $sha\n";
226
227       # If this commit's log requires any transformation, do it now.
228       my $code = $amend_code->{$sha};
229       if (defined $code)
230         {
231           eval 'use Safe';
232           my $s = new Safe;
233           # Put the unpreprocessed entry into "$_".
234           $_ = $rest;
235
236           # Let $code operate on it, safely.
237           my $r = $s->reval("$code")
238             or die "$ME:$.:$sha: failed to eval \"$code\":\n$@\n";
239
240           # Note that we've used this entry.
241           delete $amend_code->{$sha};
242
243           # Update $rest upon success.
244           $rest = $_;
245         }
246
247       my @line = split "\n", $rest;
248       my $author_line = shift @line;
249       defined $author_line
250         or die "$ME:$.: unexpected EOF\n";
251       $author_line =~ /^(\d+)  (.*>)$/
252         or die "$ME:$.: Invalid line "
253           . "(expected date/author/email):\n$author_line\n";
254
255       my $date_line = sprintf "%s  $2\n", strftime ("%F", localtime ($1));
256
257       # Format 'Co-authored-by: A U Thor <email@example.com>' lines in
258       # standard multi-author ChangeLog format.
259       my @coauthors = grep /^Co-authored-by:.*$/, @line;
260       for (@coauthors)
261         {
262           s/^Co-authored-by:\s*/\t    /;
263           s/\s*</  </;
264
265           /<.*?@.*\..*>/
266             or warn "$ME: warning: missing email address for "
267               . substr ($_, 5) . "\n";
268         }
269
270       # If this header would be the same as the previous date/name/email/
271       # coauthors header, then arrange not to print it.
272       if ($date_line ne $prev_date_line or "@coauthors" ne "@prev_coauthors")
273         {
274           $prev_date_line eq ''
275             or print "\n";
276           print $date_line;
277           @coauthors
278             and print join ("\n", @coauthors), "\n";
279         }
280       $prev_date_line = $date_line;
281       @prev_coauthors = @coauthors;
282
283       # Omit "Co-authored-by..." and "Signed-off-by..." lines.
284       @line = grep !/^Signed-off-by: .*>$/, @line;
285       @line = grep !/^Co-authored-by: /, @line;
286
287       # Remove everything after a line with 2 dashes at the beginning.
288       if ($tear_off)
289         {
290            my @tmpline;
291            foreach (@line)
292              {
293                last if /^--\s*$/;
294                push @tmpline,$_;
295              }
296            @line = @tmpline;
297         }
298
299       # Remove leading and trailing blank lines.
300       if (@line)
301         {
302           while ($line[0] =~ /^\s*$/) { shift @line; }
303           while ($line[$#line] =~ /^\s*$/) { pop @line; }
304         }
305
306       # If there were any lines
307       if (@line == 0)
308         {
309           warn "$ME: warning: empty commit message:\n  $date_line\n";
310         }
311       else
312         {
313           if ($append_dot)
314             {
315               # If the first line of the message has enough room, then
316               if (length $line[0] < 72)
317                 {
318                   # append a dot if there is no other punctuation or blank
319                   # at the end.
320                   $line[0] =~ /[[:punct:]\s]$/
321                     or $line[0] .= '.';
322                 }
323             }
324
325           # Prefix each non-empty line with a TAB.
326           @line = map { length $_ ? "\t$_" : '' } @line;
327
328           print "\n", join ("\n", @line), "\n";
329         }
330
331       defined ($in = <PIPE>)
332         or last;
333       $in ne "\n"
334         and die "$ME:$.: unexpected line:\n$in";
335     }
336
337   close PIPE
338     or die "$ME: error closing pipe from " . quoted_cmd (@cmd) . "\n";
339   # FIXME-someday: include $PROCESS_STATUS in the diagnostic
340
341   # Complain about any unused entry in the --amend=F specified file.
342   my $fail = 0;
343   foreach my $sha (keys %$amend_code)
344     {
345       warn "$ME:$amend_file: unused entry: $sha\n";
346       $fail = 1;
347     }
348
349   exit $fail;
350 }
351
352 # Local Variables:
353 # mode: perl
354 # indent-tabs-mode: nil
355 # eval: (add-hook 'write-file-hooks 'time-stamp)
356 # time-stamp-start: "my $VERSION = '"
357 # time-stamp-format: "%:y-%02m-%02d %02H:%02M"
358 # time-stamp-time-zone: "UTC"
359 # time-stamp-end: "'; # UTC"
360 # End: