Switched to GPLv3.
[gnupg.git] / scripts / w32installer.nsi
1 ; w32installer.nsi                                  -*- coding: latin-1; -*-
2 ;                   W32 Installer script
3 ; Copyright (C) 2005 Free Software Foundation, Inc.
4 ;
5 ; This file is free software; as a special exception the author gives
6 ; unlimited permission to copy and/or distribute it, with or without
7 ; modifications, as long as this notice is preserved.
8 ;
9 ; This program is distributed in the hope that it will be useful, but
10 ; WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
11 ; implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
12
13 ;----------------------------------------------------------------------
14 ; This is an installer script used to create a W32 installer "exe" file
15 ; using NSIS.  It is usually used by the mk-w32-dist script.
16 ;----------------------------------------------------------------------
17
18 ; We use the modern UI.
19 !include "MUI.nsh"
20 !include "StrFunc.nsh"
21 !include "Sections.nsh"
22
23 ; -------------
24 ; General stuff
25 ; -------------
26 Name "GNU Privacy Guard"
27
28 !ifdef WITH_WINPT
29 OutFile "gnupg-w32-${VERSION}.exe"
30 !else
31 OutFile "gnupg-w32cli-${VERSION}.exe"
32 !endif
33
34 InstallDir "$PROGRAMFILES\GNU\GnuPG"
35
36 InstallDirRegKey HKLM "Software\GNU\GnuPG" "Install Directory"
37
38 SetCompressor lzma
39
40 VIProductVersion "${PROD_VERSION}"
41 VIAddVersionKey "ProductName" "GNU Privacy Guard (${VERSION})"
42 VIAddVersionKey "Comments" \
43    "GnuPG is Free Software; you can redistribute it and/or modify  \
44     it under the terms of the GNU General Public License. You should  \
45     have received a copy of the GNU General Public License along with  \
46     this software; if not, see <http://www.gnu.org/licenses/>."
47 VIAddVersionKey "CompanyName" "Free Software Foundation"
48 VIAddVersionKey "LegalTrademarks" ""
49 VIAddVersionKey "LegalCopyright" \
50     "Copyright (C) 2007 Free Software Foundation, Inc."
51 VIAddVersionKey "FileDescription" \
52     "GnuPG: Encryption and digital signature tool"
53 VIAddVersionKey "FileVersion" "${PROD_VERSION}"
54
55 ; ----------------------
56 ; Variable declarations
57 ; ----------------------
58
59 Var MYTMP
60 Var STARTMENU_FOLDER
61
62 ; ------------------
63 ; Interface Settings
64 ; ------------------
65
66 ;;;!define MUI_ABORTWARNING
67 !define MUI_FINISHPAGE_NOAUTOCLOSE
68 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
69
70 ; Remember the installer language
71 !define MUI_LANGDLL_REGISTRY_ROOT "HKCU" 
72 !define MUI_LANGDLL_REGISTRY_KEY "Software\GNU\GnuPG" 
73 !define MUI_LANGDLL_REGISTRY_VALUENAME "Installer Language"
74
75 ; -----
76 ; Pages      
77 ; -----
78
79 !define MUI_WELCOMEPAGE_TEXT "$(T_About)"
80
81 !insertmacro MUI_PAGE_WELCOME
82
83
84 !define MUI_PAGE_HEADER_SUBTEXT "$(T_GPLHeader)"
85
86 !define MUI_LICENSEPAGE_TEXT_BOTTOM "$(T_GPLShort)"
87
88 !define MUI_LICENSEPAGE_BUTTON "$(^NextBtn)"
89
90 !insertmacro MUI_PAGE_LICENSE "COPYING.txt"
91
92 !define MUI_PAGE_CUSTOMFUNCTION_SHOW PrintNonAdminWarning
93 !insertmacro MUI_PAGE_COMPONENTS
94
95 Page custom CustomPageOptions
96
97 !insertmacro MUI_PAGE_DIRECTORY
98
99 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKCU" 
100 !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\GNU\GnuPG" 
101 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
102   
103 !insertmacro MUI_PAGE_STARTMENU Application $STARTMENU_FOLDER
104
105 !insertmacro MUI_PAGE_INSTFILES
106
107 !define MUI_FINISHPAGE_SHOWREADME "README-W32.txt"
108 !define MUI_FINISHPAGE_SHOWREADME_TEXT "$(T_ShowReadme)"
109 !define MUI_FINISHPAGE_LINK "$(T_FiniLink)"
110 !define MUI_FINISHPAGE_LINK_LOCATION "http://www.gnupg.org/"
111 !insertmacro MUI_PAGE_FINISH
112
113   
114 !insertmacro MUI_UNPAGE_CONFIRM
115 !insertmacro MUI_UNPAGE_INSTFILES
116
117
118 ; -----------------
119 ; i18n Declarations
120 ; -----------------
121
122 !insertmacro MUI_LANGUAGE "English"
123 !insertmacro MUI_LANGUAGE "German"
124
125 ; ------------------
126 ; Installer Sections
127 ; ------------------
128
129 !insertmacro MUI_RESERVEFILE_LANGDLL
130 !insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
131 ReserveFile "opt.ini" 
132 ReserveFile "COPYING.txt"
133 ReserveFile "README-W32.txt"
134 #ReserveFile "${NSISDIR}/Plugins/System.dll"
135 ReserveFile "${NSISDIR}/Plugins/UserInfo.dll"
136
137
138 ${StrStr} # Supportable for Install Sections and Functions
139 ${StrTok} # Supportable for Install Sections and Functions
140
141
142
143 ;InstType "full"
144 ;InstType "minimal"
145
146
147 ;----------------------
148 Section "Base" SecBase
149 ;  SectionIn 1 2 RO
150   SectionIn RO
151
152   SetOutPath "$INSTDIR"
153
154   File "gpg.exe"
155   File "gpgkeys_finger.exe"
156   File "gpgkeys_hkp.exe"
157   File "gpgkeys_curl.exe"
158   File "gpgkeys_ldap.exe"
159
160   SetOutPath "$INSTDIR\Doc"
161
162   File "README.txt"
163   File "README-W32.txt"
164   File "COPYING.txt"
165
166   Call InstallIconv
167
168   WriteRegStr HKLM "Software\GNU\GnuPG" "Install Directory" $INSTDIR
169
170 SectionEnd ; Section Base
171
172 ;----------------------
173 Section "NLS" SecNLS
174 ;  SectionIn 1
175
176   SetOutPath "$INSTDIR\gnupg.nls"
177
178   File "*.mo"
179
180 SectionEnd ; Section NLS
181
182 ;------------------------
183 Section "Tools" SecTools
184 ;  SectionIn 1
185
186   SetOutPath "$INSTDIR"
187   File "gpgsplit.exe"
188   File "gpgv.exe"
189
190 SectionEnd ; Section Tools
191
192 ;------------------
193 !ifdef WITH_WINPT
194 Section "WinPT" SecWinPT
195 ;  SectionIn 1
196
197   SetOutPath "$INSTDIR"
198
199   File "WinPT.exe"
200   File "PTD.dll"
201   File "keyserver.conf"
202
203   SetOutPath "$INSTDIR\Doc"
204
205   File "README.winpt.txt"
206
207   WriteRegStr HKCU "Software\GNU\GnuPG" "gpgProgram" "$INSTDIR\gpg.exe"
208
209 SectionEnd ; Section WinPT
210 !endif
211
212
213 ;----------------------
214 Section "Documentation" SecDoc
215 ;  SectionIn 1
216
217   SetOutPath "$INSTDIR\Doc"
218
219   File "gnupg.man"
220   File "gpg.man"
221   File "gpgv.man"
222   File "NEWS.txt"
223   File "FAQ.txt"
224
225 !ifdef WITH_WINPT
226   File "NEWS.winpt.txt"
227 !endif ; WITH_WINPT
228
229 !ifdef WITH_PATCHES
230   SetOutPath "$INSTDIR\Src"
231   File '*.diff'
232 !endif
233
234 SectionEnd ; Section Documentation
235
236
237 ;------------------
238 !ifdef WITH_SOURCE
239 Section /o "Source" SecSource
240
241   SetOutPath "$INSTDIR\Src"
242
243   ; Note that we include the uncompressed tarballs because this allows
244   ; far better compression results for the distribution.  We might
245   ; want to compress it again after installation.
246
247   File "gnupg-${VERSION}.tar"
248
249   File "libiconv-${LIBICONV_VERSION}.tar"
250
251 !ifdef WITH_WINPT
252   File "winpt-${WINPT_VERSION}.tar"
253 !endif ; WITH_WINPT
254
255 SectionEnd ; Section Source
256 !endif
257
258
259 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
260 ;;
261 ;; The last section is a hidden one; used to finish up things.
262 ;;
263 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
264 Section "-Finish"
265
266   ;;--------------------------
267   ;;  Create the uninstaller
268   ;;--------------------------
269   WriteUninstaller "$INSTDIR\uninst-gnupg.exe"
270
271   StrCpy $MYTMP "Software\Microsoft\Windows\CurrentVersion\Uninstall\GnuPG"
272   WriteRegExpandStr HKLM $MYTMP "UninstallString" '"$INSTDIR\uninst-gnupg.exe"'
273   WriteRegExpandStr HKLM $MYTMP "InstallLocation" "$INSTDIR"
274   WriteRegStr       HKLM $MYTMP "DisplayName"     "GNU Privacy Guard"
275   WriteRegStr       HKLM $MYTMP "DisplayIcon"     "$INSTDIR\gpg.exe,0"
276   WriteRegStr       HKLM $MYTMP "DisplayVersion"  "${VERSION}"
277   WriteRegStr       HKLM $MYTMP "Publisher"       "Free Software Foundation"
278   WriteRegStr       HKLM $MYTMP "URLInfoAbout"    "http://www.gnupg.org/"
279   WriteRegDWORD     HKLM $MYTMP "NoModify"        "1"
280   WriteRegDWORD     HKLM $MYTMP "NoRepair"        "1"
281
282
283   ;;---------------------
284   ;; Create Menu entries
285   ;;---------------------
286   !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
287     
288   CreateDirectory "$SMPROGRAMS\$STARTMENU_FOLDER"
289
290   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GnuPG README.lnk" \
291                  "$INSTDIR\Doc\README.txt"
292   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GnuPG README.Windows.lnk" \
293                  "$INSTDIR\Doc\README-W32.txt"
294   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GnuPG NEWS.lnk" \
295                  "$INSTDIR\Doc\NEWS.txt"
296
297   SectionGetFlags ${SecDoc} $R0 
298   IntOp $R0 $R0 & ${SF_SELECTED} 
299   IntCmp $R0 ${SF_SELECTED} 0 +2 
300   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GnuPG Manual Page.lnk" \
301                  "$INSTDIR\Doc\gpg.man"
302
303
304 !ifdef WITH_WINPT
305   SectionGetFlags ${SecWinPT} $R0 
306   IntOp $R0 $R0 & ${SF_SELECTED} 
307   IntCmp $R0 ${SF_SELECTED} 0 no_winpt_menu 
308   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\winpt.lnk" \
309                  "$INSTDIR\winpt.exe"
310   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\WinPT README.lnk" \
311                  "$INSTDIR\Doc\README.winpt.txt"
312
313   SectionGetFlags ${SecDoc} $R0 
314   IntOp $R0 $R0 & ${SF_SELECTED} 
315   IntCmp $R0 ${SF_SELECTED} 0 +2 
316   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\WinPT NEWS.lnk" \
317                  "$INSTDIR\Doc\NEWS.winpt.txt"
318
319  no_winpt_menu:
320 !endif
321
322   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\uninst-gnupg.lnk" \
323                  "$INSTDIR\uninst-gnupg.exe"
324
325
326   !insertmacro MUI_STARTMENU_WRITE_END
327
328
329   ;;-----------------
330   ;; Set the language
331   ;;-----------------
332   SectionGetFlags ${SecNLS} $R0 
333   IntOp $R0 $R0 & ${SF_SELECTED} 
334   IntCmp $R0 ${SF_SELECTED} 0 lang_none
335   
336   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "opt.ini" "Field 1" "ListItems"
337   DetailPrint "Available languages: $R0"
338   !insertmacro MUI_INSTALLOPTIONS_READ $R1 "opt.ini" "Field 1" "State"
339   DetailPrint "Selected language: $R1"
340
341   StrCmp $R1 "" lang_none +1
342   ${StrStr} $R2 $R0 $R1 
343   StrCmp $R2 "" lang_none +1
344   ${StrTok} $R3 $R2 " " "0" "1"
345   goto lang_set_finish
346  lang_none:
347   DetailPrint "No language selected - using default"
348   StrCpy $R3 ""
349  lang_set_finish:
350   DetailPrint "Setting language to: $R3"
351   WriteRegStr HKCU "Software\GNU\GnuPG" "Lang" $R3
352   ;;
353
354
355 SectionEnd ; "-Finish"
356
357
358
359 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
360 ;;
361 ;; Create the section for the uninstaller
362 ;;
363 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
364 Section "Uninstall"
365
366   ;;------------------------
367   ;; Delete files
368   ;;------------------------
369   Delete "$INSTDIR\gpg.exe"
370   Delete "$INSTDIR\gpgkeys_finger.exe"
371   Delete "$INSTDIR\gpgkeys_hkp.exe"
372   Delete "$INSTDIR\gpgkeys_curl.exe"
373   Delete "$INSTDIR\gpgkeys_ldap.exe"
374
375   Delete "$INSTDIR\Doc\README.txt"
376   Delete "$INSTDIR\Doc\README-W32.txt"
377   Delete "$INSTDIR\Doc\COPYING.txt"
378   Delete "$INSTDIR\Doc\COPYING.LIB.txt"
379   Delete "$INSTDIR\Doc\README.iconv.txt"
380
381   Delete "$INSTDIR\iconv.dll"
382
383   Delete "$INSTDIR\gnupg.nls\*.mo"
384
385   Delete "$INSTDIR\gpgsplit.exe"
386   Delete "$INSTDIR\gpgv.exe"
387
388 !ifdef WITH_WINPT
389   Delete "$INSTDIR\WinPT.exe"
390   Delete "$INSTDIR\PTD.dll"
391   Delete "$INSTDIR\Doc\README.winpt.txt"
392   Delete "$INSTDIR\Doc\NEWS.winpt.txt"
393   Delete "$INSTDIR\Doc\keyserver.conf"
394 !endif
395
396   Delete "$INSTDIR\Doc\gnupg.man"
397   Delete "$INSTDIR\Doc\gpg.man"
398   Delete "$INSTDIR\Doc\gpgv.man"
399   Delete "$INSTDIR\Doc\NEWS.txt"
400   Delete "$INSTDIR\Doc\FAQ.txt"
401
402   Delete "$INSTDIR\Src\gnupg-${VERSION}.tar"
403   Delete "$INSTDIR\Src\libiconv-${LIBICONV_VERSION}.tar"
404   Delete "$INSTDIR\Src\winpt-${WINPT_VERSION}.tar"
405   Delete "$INSTDIR\Src\*.diff"
406
407   Delete "$INSTDIR\uninst-gnupg.exe"
408
409   ;;------------------------
410   ;; Delete directories
411   ;;------------------------
412   RMDir "$INSTDIR\Doc"
413   RMDir "$INSTDIR\Src"
414   RMDir "$INSTDIR\gnupg.nls"
415   RMDir "$INSTDIR"
416
417
418   ;;---------------------------------------------------
419   ;; Delete the menu entries and any empty parent menus
420   ;;---------------------------------------------------
421   !insertmacro MUI_STARTMENU_GETFOLDER Application $MYTMP
422   Delete "$SMPROGRAMS\$MYTMP\*.lnk"
423   StrCpy $MYTMP "$SMPROGRAMS\$MYTMP"
424   startMenuDeleteLoop:
425     ClearErrors
426     RMDir $MYTMP
427     GetFullPathName $MYTMP "$MYTMP\.."
428     IfErrors startMenuDeleteLoopDone
429     StrCmp $MYTMP $SMPROGRAMS startMenuDeleteLoopDone startMenuDeleteLoop
430   startMenuDeleteLoopDone:
431
432
433   ;;-----------------------
434   ;;  Cleanup the registry
435   ;;-----------------------
436   DeleteRegValue HKCU "Software\GNU\GnuPG" "Start Menu Folder"
437   DeleteRegValue HKLM "Software\GNU\GnuPG" "Install Directory"
438   DeleteRegKey /ifempty HKLM "Software\GNU\GnuPG"
439   DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GnuPG"
440
441 SectionEnd ; Uninstall
442
443
444 ; ---------
445 ; Functions
446 ; ---------
447
448 Function .onInit
449   # We can't use System.dll anymore becuase it has bee removed from
450   # Debian due to an inability to build using FS.  We should use the
451   # use our own DLL as we do with gpg4win.
452   #System::Call 'kernel32::CreateMutexA(i 0, i 0, t "GnuPGInst") i .r1 ?e'
453   #Pop $R0
454   #StrCmp $R0 0 +3
455   # MessageBox MB_OK "An instance of the installer is already running."
456   # Abort
457
458   ;;!define MUI_LANGDLL_ALWAYSSHOW
459   !insertmacro MUI_LANGDLL_DISPLAY
460
461   !insertmacro MUI_INSTALLOPTIONS_EXTRACT "opt.ini"
462
463 FunctionEnd 
464
465
466 Function un.onInit 
467
468   !insertmacro MUI_UNGETLANGUAGE
469   
470 FunctionEnd
471
472
473 ;; Check whether the current user is in the Administrator group or
474 ;; an OS version without the need for an Administrator is in use.
475 ;; Print a warning if this is not the case.
476 Function PrintNonAdminWarning
477   ClearErrors
478   UserInfo::GetName
479   IfErrors leave
480   Pop $0
481   UserInfo::GetAccountType
482   Pop $1
483   StrCmp $1 "Admin" leave +1
484   MessageBox MB_OK "$(T_AdminNeeded)"
485
486  leave:
487 FunctionEnd
488
489
490 Function CustomPageOptions  
491   SectionGetFlags ${SecNLS} $R0 
492   IntOp $R0 $R0 & ${SF_SELECTED} 
493   IntCmp $R0 ${SF_SELECTED} show 
494  
495   Abort 
496  
497  show: 
498   !insertmacro MUI_HEADER_TEXT "$(T_InstallOptions)" "$(T_SelectLanguage)"
499   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "opt.ini" "Field 1" "ListItems"
500   ReadRegStr $R1 HKCU "Software\GNU\GnuPG" "Lang" 
501   StrCmp $R1 "" use_default +1
502   ${StrStr} $R2 $R0 "$R1 - " 
503   StrCmp $R2 "" +1 set_lang
504  use_default:
505   StrCpy $R2 "$(T_langid) - $(T_langname)"
506  set_lang:
507   ${StrTok} $R3 $R2 "|" "0" "1"
508   !insertmacro MUI_INSTALLOPTIONS_WRITE "opt.ini" "Field 1" "State" $R3
509
510   !insertmacro MUI_INSTALLOPTIONS_DISPLAY "opt.ini"
511
512 FunctionEnd
513
514
515 ; Install iconv.dll if it has not been installed on the system.
516 Function InstallIconv
517
518   ; First delete a iconv DLL already installed in the target directory.
519   ; This is required to detect a meanwhile globally installed dll.
520   Delete "$INSTDIR\iconv.dll"
521   ClearErrors
522   GetDllVersion "iconv.dll" $R0 $R1
523   IfErrors 0 +3
524     DetailPrint "iconv.dll is not installed."
525     goto InstallIconv
526
527   IntOp $R2 $R0 / 0x00010000
528   IntOp $R3 $R0 & 0x0000FFFF
529   IntOp $R4 $R1 / 0x00010000
530   IntOp $R5 $R1 & 0x0000FFFF
531   StrCpy $0 "$R2.$R3.$R4.$R5"
532
533   DetailPrint "iconv.dll version is $0"
534
535   IntCmp $R2 1 0 IconvTooOld
536   IntCmp $R3 9 0 IconvTooOld
537   return
538
539  IconvTooOld:
540     DetailPrint "The installed iconv.dll is too old."
541
542  InstallIconv:
543   SetOutPath "$INSTDIR"
544   File "iconv.dll"
545
546   SetOutPath "$INSTDIR\doc"
547   File "COPYING.LIB.txt"
548   File "README.iconv.txt"
549
550 FunctionEnd
551
552
553 ; ------------
554 ; Descriptions
555 ; ------------
556
557 ; The list of language IDs and corresponding Latin-1 names.  Note that
558 ; this mapping needs to match the one in the mk-w32-dist script, so
559 ; that they are usable to get a default value for then ListItems of
560 ; opt.ini.
561 LangString T_langid   ${LANG_ENGLISH} "en"
562 LangString T_langname ${LANG_ENGLISH} "English"
563 LangString T_langid   ${LANG_GERMAN}  "de"
564 LangString T_langname ${LANG_GERMAN}  "Deutsch"
565
566 ; The About string as displayed on the first page.
567 LangString T_About ${LANG_ENGLISH} \
568   "GnuPG is GNU's tool for secure communication and data storage. \
569   It can be used to encrypt data and to create digital signatures. \
570   It includes an advanced key management facility and is compliant \
571   with the proposed OpenPGP Internet standard as described in RFC2440. \
572   \r\n\r\n$_CLICK \
573   \r\n\r\n\r\n\r\n\r\nThis is GnuPG version ${VERSION}\r\n\
574   built on $%BUILDINFO%\r\n\
575   file version ${PROD_VERSION}"
576 LangString T_About ${LANG_GERMAN} \
577   "GnuPG is das Werkzeug aus dem GNU Projekt zur sicheren Kommunikation \
578    sowie zum sicheren Speichern von Daten. \
579    \r\n\r\n$_CLICK \
580    \r\n\r\n\r\n\r\n\r\nDies ist GnuPG Version ${VERSION}\r\n\
581    erstellt am $%BUILDINFO%\r\n\
582    Dateiversion ${PROD_VERSION}"
583
584 ; Startup page
585 LangString T_GPLHeader ${LANG_ENGLISH} \
586   "This software is licensed under the terms of the GNU General Public \
587    License (GPL) which guarantees your freedom to share and change Free \
588    Software."
589 LangString T_GPLHeader ${LANG_GERMAN}} \
590   "Diese Software ist unter der GNU General Public License \
591    (GPL) lizensiert; dies gibt Ihnen die Freiheit, sie \
592    zu ändern und weiterzugeben."
593
594 LangString T_GPLShort ${LANG_ENGLISH} \
595   "In short: You are allowed to run this software for any purpose. \
596    You may distribute it as long as you give the recipients the same \
597    rights you have received."
598 LangString T_GPLShort ${LANG_GERMAN} \
599   "In aller Kürze: Sie haben das Recht, die Software zu jedem Zweck \
600    einzusetzen.  Sie können die Software weitergeben, sofern Sie dem \
601    Empfänger dieselben Rechte einräumen, die auch Sie erhalten haben."
602
603
604 ; Finish page
605 LangString T_FiniLink ${LANG_ENGLISH} \
606   "Visit the GnuPG website for latest news and support"
607 LangString T_FiniLink ${LANG_GERMAN}} \
608   "Zur GnuPG Website mit Neuigkeiten und Hilfsangeboten"
609
610 ; From Function PrintNonAdminWarning
611 LangString T_AdminNeeded ${LANG_ENGLISH} \
612    "Warning: Administrator permissions required for a successful installation"
613 LangString T_AdminNeeded ${LANG_GERMAN} \
614    "Warnung: Administrator Reche werden für eine erfolgreiche \
615     Installation benötigt."
616
617
618 ; Installation options like language used for GnuPG
619 LangString T_InstallOptions ${LANG_ENGLISH} "Install Options"
620 LangString T_InstallOptions ${LANG_GERMAN}  "Installationsoptionen"
621
622 LangString T_SelectLanguage ${LANG_ENGLISH} "GnuPG Language Selection"
623 LangString T_SelectLanguage ${LANG_German}  "Auswahl der Sprache für GnuPG"
624
625 ; This text is used on the finish page.
626 LangString T_ShowReadme ${LANG_ENGLISH} "Show the README file"
627 LangString T_ShowReadme ${LANG_GERMAN} "Die README Datei anzeigen"
628
629 ; Section names
630 LangString DESC_SecBase ${LANG_ENGLISH} \
631       "The basic files used for the standard OpenPGP protocol"
632 LangString DESC_SecBase ${LANG_GERMAN} \
633       "Die Basis Dateien zur Benutzung des OpenPGP Protokolls"
634
635 Langstring DESC_SecNLS ${LANG_ENGLISH} \
636       "Support for languages other than English"
637 LangString DESC_SecNLS ${LANG_GERMAN} \
638       "Unterstützung für weitere Sprachen neben Englisch"
639
640 LangString DESC_SecTools ${LANG_ENGLISH} \
641       "Extra tools like gpgv and gpgsplit"
642 LangString DESC_SecTools ${LANG_GERMAN} \
643       "Weitere Tools wie gpgv und gpgsplit"
644
645 !ifdef WITH_WINPT
646 LangString DESC_SecWinPT ${LANG_ENGLISH} \
647       "The Windows Privacy Tray (WinPT)"
648 LangString DESC_SecWinPT ${LANG_GERMAN} \
649       "Der Windows Privacy Tray (WinPT)"
650 !endif
651
652 LangString DESC_SecDoc ${LANG_ENGLISH} \
653       "Manual pages and a FAQ"
654 LangString DESC_SecDoc ${LANG_GERMAN} \
655       "Handbuchseiten und eine FAQ"
656
657 LangString DESC_SecSource ${LANG_ENGLISH} \
658       "Quelltextdateien"
659 LangString DESC_SecSource ${LANG_GERMAN} \
660       "Source files"
661
662
663
664 ;-------------------------------------
665 ; Associate section names with strings
666 ;--------------------------------------
667 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
668   !insertmacro MUI_DESCRIPTION_TEXT ${SecBase} $(DESC_SecBase)
669   !insertmacro MUI_DESCRIPTION_TEXT ${SecNLS} $(DESC_SecNLS)
670   !insertmacro MUI_DESCRIPTION_TEXT ${SecTools} $(DESC_SecTools)
671 !ifdef WITH_WINPT
672   !insertmacro MUI_DESCRIPTION_TEXT ${SecWinPT} $(DESC_SecWinPT)
673 !endif
674   !insertmacro MUI_DESCRIPTION_TEXT ${SecDoc} $(DESC_SecDoc)
675 !insertmacro MUI_FUNCTION_DESCRIPTION_END
676