Don't link gpgv with libreadline
[gnupg.git] / scripts / w32installer.nsi
1 ; w32installer.nsi                                  -*- coding: latin-1; -*-
2 ;                   W32 Installer script
3 ; Copyright (C) 2005 Free Software Foundation, Inc.
4 ;
5 ; This file is free software; as a special exception the author gives
6 ; unlimited permission to copy and/or distribute it, with or without
7 ; modifications, as long as this notice is preserved.
8 ;
9 ; This program is distributed in the hope that it will be useful, but
10 ; WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
11 ; implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
12
13 ;----------------------------------------------------------------------
14 ; This is an installer script used to create a W32 installer "exe" file
15 ; using NSIS.  It is usually used by the mk-w32-dist script.
16 ;----------------------------------------------------------------------
17
18 ; We use the modern UI.
19 !include "MUI.nsh"
20 !include "StrFunc.nsh"
21 !include "Sections.nsh"
22
23 ; -------------
24 ; General stuff
25 ; -------------
26 Name "GNU Privacy Guard"
27
28 !ifdef WITH_WINPT
29 OutFile "gnupg-w32-${VERSION}.exe"
30 !else
31 OutFile "gnupg-w32cli-${VERSION}.exe"
32 !endif
33
34 InstallDir "$PROGRAMFILES\GNU\GnuPG"
35
36 InstallDirRegKey HKLM "Software\GNU\GnuPG" "Install Directory"
37
38 SetCompressor lzma
39
40 VIProductVersion "${PROD_VERSION}"
41 VIAddVersionKey "ProductName" "GNU Privacy Guard (${VERSION})"
42 VIAddVersionKey "Comments" \
43    "GnuPG is Free Software; you can redistribute it and/or modify  \
44     it under the terms of the GNU General Public License. You should  \
45     have received a copy of the GNU General Public License along with  \
46     this software; if not, see <http://www.gnu.org/licenses/>."
47 VIAddVersionKey "CompanyName" "Free Software Foundation"
48 VIAddVersionKey "LegalTrademarks" ""
49 VIAddVersionKey "LegalCopyright" \
50     "Copyright (C) 2007 Free Software Foundation, Inc."
51 VIAddVersionKey "FileDescription" \
52     "GnuPG: Encryption and digital signature tool"
53 VIAddVersionKey "FileVersion" "${PROD_VERSION}"
54
55 ; ----------------------
56 ; Variable declarations
57 ; ----------------------
58
59 Var MYTMP
60 Var STARTMENU_FOLDER
61
62 ; ------------------
63 ; Interface Settings
64 ; ------------------
65
66 ;;;!define MUI_ABORTWARNING
67 !define MUI_FINISHPAGE_NOAUTOCLOSE
68 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
69
70 ; Remember the installer language
71 !define MUI_LANGDLL_REGISTRY_ROOT "HKCU" 
72 !define MUI_LANGDLL_REGISTRY_KEY "Software\GNU\GnuPG" 
73 !define MUI_LANGDLL_REGISTRY_VALUENAME "Installer Language"
74
75 ; -----
76 ; Pages      
77 ; -----
78
79 !define MUI_WELCOMEPAGE_TEXT "$(T_About)"
80
81 !insertmacro MUI_PAGE_WELCOME
82
83
84 !define MUI_PAGE_HEADER_SUBTEXT "$(T_GPLHeader)"
85
86 !define MUI_LICENSEPAGE_TEXT_BOTTOM "$(T_GPLShort)"
87
88 !define MUI_LICENSEPAGE_BUTTON "$(^NextBtn)"
89
90 !insertmacro MUI_PAGE_LICENSE "COPYING.txt"
91
92 !define MUI_PAGE_CUSTOMFUNCTION_SHOW PrintNonAdminWarning
93 !insertmacro MUI_PAGE_COMPONENTS
94
95 Page custom CustomPageOptions
96
97 !insertmacro MUI_PAGE_DIRECTORY
98
99 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKCU" 
100 !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\GNU\GnuPG" 
101 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
102   
103 !insertmacro MUI_PAGE_STARTMENU Application $STARTMENU_FOLDER
104
105 !insertmacro MUI_PAGE_INSTFILES
106
107 !define MUI_FINISHPAGE_SHOWREADME "README-W32.txt"
108 !define MUI_FINISHPAGE_SHOWREADME_TEXT "$(T_ShowReadme)"
109 !define MUI_FINISHPAGE_LINK "$(T_FiniLink)"
110 !define MUI_FINISHPAGE_LINK_LOCATION "http://www.gnupg.org/"
111 !insertmacro MUI_PAGE_FINISH
112
113   
114 !insertmacro MUI_UNPAGE_CONFIRM
115 !insertmacro MUI_UNPAGE_INSTFILES
116
117
118 ; -----------------
119 ; i18n Declarations
120 ; -----------------
121
122 !insertmacro MUI_LANGUAGE "English"
123 !insertmacro MUI_LANGUAGE "German"
124
125 ; ------------------
126 ; Installer Sections
127 ; ------------------
128
129 !insertmacro MUI_RESERVEFILE_LANGDLL
130 !insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
131 ReserveFile "opt.ini" 
132 ReserveFile "COPYING.txt"
133 ReserveFile "README-W32.txt"
134 #ReserveFile "${NSISDIR}/Plugins/System.dll"
135 ReserveFile "${NSISDIR}/Plugins/UserInfo.dll"
136
137
138 ${StrStr} # Supportable for Install Sections and Functions
139 ${StrTok} # Supportable for Install Sections and Functions
140
141
142
143 ;InstType "full"
144 ;InstType "minimal"
145
146
147 ;----------------------
148 Section "Base" SecBase
149 ;  SectionIn 1 2 RO
150   SectionIn RO
151
152   SetOutPath "$INSTDIR"
153
154   File "gpg.exe"
155   File "gpgkeys_finger.exe"
156   File "gpgkeys_hkp.exe"
157   File "gpgkeys_curl.exe"
158   File "gpgkeys_ldap.exe"
159
160   SetOutPath "$INSTDIR\Doc"
161
162   File "README.txt"
163   File "README-W32.txt"
164   File "COPYING.txt"
165
166   Call InstallIconv
167
168   WriteRegStr HKLM "Software\GNU\GnuPG" "Install Directory" $INSTDIR
169
170 SectionEnd ; Section Base
171
172 ;----------------------
173 Section "NLS" SecNLS
174 ;  SectionIn 1
175
176   SetOutPath "$INSTDIR\gnupg.nls"
177
178   File "*.mo"
179
180 SectionEnd ; Section NLS
181
182 ;------------------------
183 Section "Tools" SecTools
184 ;  SectionIn 1
185
186   SetOutPath "$INSTDIR"
187   File "gpgsplit.exe"
188   File "gpgv.exe"
189
190 SectionEnd ; Section Tools
191
192 ;------------------
193 !ifdef WITH_WINPT
194 Section "WinPT" SecWinPT
195 ;  SectionIn 1
196
197   SetOutPath "$INSTDIR"
198
199   File "WinPT.exe"
200   File "PTD.dll"
201   File "keyserver.conf"
202
203   SetOutPath "$INSTDIR\Doc"
204
205   File "README.winpt.txt"
206
207   WriteRegStr HKCU "Software\GNU\GnuPG" "gpgProgram" "$INSTDIR\gpg.exe"
208
209 SectionEnd ; Section WinPT
210 !endif
211
212
213 ;----------------------
214 Section "Documentation" SecDoc
215 ;  SectionIn 1
216
217   SetOutPath "$INSTDIR\Doc"
218
219   File "gnupg.man"
220   File "gpg.man"
221   File "gpgv.man"
222   File "NEWS.txt"
223   File "FAQ.txt"
224
225 !ifdef WITH_WINPT
226   File "NEWS.winpt.txt"
227 !endif ; WITH_WINPT
228
229 !ifdef WITH_PATCHES
230   SetOutPath "$INSTDIR\Src"
231   File '*.diff'
232   File '*.tar.gz'
233 !endif
234
235 SectionEnd ; Section Documentation
236
237
238 ;------------------
239 !ifdef WITH_SOURCE
240 Section /o "Source" SecSource
241
242   SetOutPath "$INSTDIR\Src"
243
244   ; Note that we include the uncompressed tarballs because this allows
245   ; far better compression results for the distribution.  We might
246   ; want to compress it again after installation.
247
248   File "gnupg-${VERSION}.tar"
249
250   File "libiconv-${LIBICONV_VERSION}.tar"
251
252 !ifdef WITH_WINPT
253   File "winpt-${WINPT_VERSION}.tar"
254 !endif ; WITH_WINPT
255
256 SectionEnd ; Section Source
257 !endif
258
259
260 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
261 ;;
262 ;; The last section is a hidden one; used to finish up things.
263 ;;
264 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
265 Section "-Finish"
266
267   ;;--------------------------
268   ;;  Create the uninstaller
269   ;;--------------------------
270   WriteUninstaller "$INSTDIR\uninst-gnupg.exe"
271
272   StrCpy $MYTMP "Software\Microsoft\Windows\CurrentVersion\Uninstall\GnuPG"
273   WriteRegExpandStr HKLM $MYTMP "UninstallString" '"$INSTDIR\uninst-gnupg.exe"'
274   WriteRegExpandStr HKLM $MYTMP "InstallLocation" "$INSTDIR"
275   WriteRegStr       HKLM $MYTMP "DisplayName"     "GNU Privacy Guard"
276   WriteRegStr       HKLM $MYTMP "DisplayIcon"     "$INSTDIR\gpg.exe,0"
277   WriteRegStr       HKLM $MYTMP "DisplayVersion"  "${VERSION}"
278   WriteRegStr       HKLM $MYTMP "Publisher"       "Free Software Foundation"
279   WriteRegStr       HKLM $MYTMP "URLInfoAbout"    "http://www.gnupg.org/"
280   WriteRegDWORD     HKLM $MYTMP "NoModify"        "1"
281   WriteRegDWORD     HKLM $MYTMP "NoRepair"        "1"
282
283
284   ;;---------------------
285   ;; Create Menu entries
286   ;;---------------------
287   !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
288     
289   CreateDirectory "$SMPROGRAMS\$STARTMENU_FOLDER"
290
291   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GnuPG README.lnk" \
292                  "$INSTDIR\Doc\README.txt"
293   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GnuPG README.Windows.lnk" \
294                  "$INSTDIR\Doc\README-W32.txt"
295   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GnuPG NEWS.lnk" \
296                  "$INSTDIR\Doc\NEWS.txt"
297
298   SectionGetFlags ${SecDoc} $R0 
299   IntOp $R0 $R0 & ${SF_SELECTED} 
300   IntCmp $R0 ${SF_SELECTED} 0 +2 
301   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GnuPG Manual Page.lnk" \
302                  "$INSTDIR\Doc\gpg.man"
303
304
305 !ifdef WITH_WINPT
306   SectionGetFlags ${SecWinPT} $R0 
307   IntOp $R0 $R0 & ${SF_SELECTED} 
308   IntCmp $R0 ${SF_SELECTED} 0 no_winpt_menu 
309   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\winpt.lnk" \
310                  "$INSTDIR\winpt.exe"
311   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\WinPT README.lnk" \
312                  "$INSTDIR\Doc\README.winpt.txt"
313
314   SectionGetFlags ${SecDoc} $R0 
315   IntOp $R0 $R0 & ${SF_SELECTED} 
316   IntCmp $R0 ${SF_SELECTED} 0 +2 
317   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\WinPT NEWS.lnk" \
318                  "$INSTDIR\Doc\NEWS.winpt.txt"
319
320  no_winpt_menu:
321 !endif
322
323   CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\uninst-gnupg.lnk" \
324                  "$INSTDIR\uninst-gnupg.exe"
325
326
327   !insertmacro MUI_STARTMENU_WRITE_END
328
329
330   ;;-----------------
331   ;; Set the language
332   ;;-----------------
333   SectionGetFlags ${SecNLS} $R0 
334   IntOp $R0 $R0 & ${SF_SELECTED} 
335   IntCmp $R0 ${SF_SELECTED} 0 lang_none
336   
337   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "opt.ini" "Field 1" "ListItems"
338   DetailPrint "Available languages: $R0"
339   !insertmacro MUI_INSTALLOPTIONS_READ $R1 "opt.ini" "Field 1" "State"
340   DetailPrint "Selected language: $R1"
341
342   StrCmp $R1 "" lang_none +1
343   ${StrStr} $R2 $R0 $R1 
344   StrCmp $R2 "" lang_none +1
345   ${StrTok} $R3 $R2 " " "0" "1"
346   goto lang_set_finish
347  lang_none:
348   DetailPrint "No language selected - using default"
349   StrCpy $R3 ""
350  lang_set_finish:
351   DetailPrint "Setting language to: $R3"
352   WriteRegStr HKCU "Software\GNU\GnuPG" "Lang" $R3
353   ;;
354
355   # Set the Outpath pack so that the README file can be displayed.
356   SetOutPath "$INSTDIR\Doc"
357
358 SectionEnd ; "-Finish"
359
360
361
362 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
363 ;;
364 ;; Create the section for the uninstaller
365 ;;
366 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
367 Section "Uninstall"
368
369   ;;------------------------
370   ;; Delete files
371   ;;------------------------
372   Delete "$INSTDIR\gpg.exe"
373   Delete "$INSTDIR\gpgkeys_finger.exe"
374   Delete "$INSTDIR\gpgkeys_hkp.exe"
375   Delete "$INSTDIR\gpgkeys_curl.exe"
376   Delete "$INSTDIR\gpgkeys_ldap.exe"
377
378   Delete "$INSTDIR\Doc\README.txt"
379   Delete "$INSTDIR\Doc\README-W32.txt"
380   Delete "$INSTDIR\Doc\COPYING.txt"
381   Delete "$INSTDIR\Doc\COPYING.LIB.txt"
382   Delete "$INSTDIR\Doc\README.iconv.txt"
383
384   Delete "$INSTDIR\iconv.dll"
385
386   Delete "$INSTDIR\gnupg.nls\*.mo"
387
388   Delete "$INSTDIR\gpgsplit.exe"
389   Delete "$INSTDIR\gpgv.exe"
390
391 !ifdef WITH_WINPT
392   Delete "$INSTDIR\WinPT.exe"
393   Delete "$INSTDIR\PTD.dll"
394   Delete "$INSTDIR\Doc\README.winpt.txt"
395   Delete "$INSTDIR\Doc\NEWS.winpt.txt"
396   Delete "$INSTDIR\Doc\keyserver.conf"
397 !endif
398
399   Delete "$INSTDIR\Doc\gnupg.man"
400   Delete "$INSTDIR\Doc\gpg.man"
401   Delete "$INSTDIR\Doc\gpgv.man"
402   Delete "$INSTDIR\Doc\NEWS.txt"
403   Delete "$INSTDIR\Doc\FAQ.txt"
404
405   Delete "$INSTDIR\Src\gnupg-${VERSION}.tar"
406   Delete "$INSTDIR\Src\libiconv-${LIBICONV_VERSION}.tar"
407   Delete "$INSTDIR\Src\winpt-${WINPT_VERSION}.tar"
408   Delete "$INSTDIR\Src\*.diff"
409
410   Delete "$INSTDIR\uninst-gnupg.exe"
411
412   ;;------------------------
413   ;; Delete directories
414   ;;------------------------
415   RMDir "$INSTDIR\Doc"
416   RMDir "$INSTDIR\Src"
417   RMDir "$INSTDIR\gnupg.nls"
418   RMDir "$INSTDIR"
419
420
421   ;;---------------------------------------------------
422   ;; Delete the menu entries and any empty parent menus
423   ;;---------------------------------------------------
424   !insertmacro MUI_STARTMENU_GETFOLDER Application $MYTMP
425   Delete "$SMPROGRAMS\$MYTMP\*.lnk"
426   StrCpy $MYTMP "$SMPROGRAMS\$MYTMP"
427   startMenuDeleteLoop:
428     ClearErrors
429     RMDir $MYTMP
430     GetFullPathName $MYTMP "$MYTMP\.."
431     IfErrors startMenuDeleteLoopDone
432     StrCmp $MYTMP $SMPROGRAMS startMenuDeleteLoopDone startMenuDeleteLoop
433   startMenuDeleteLoopDone:
434
435
436   ;;-----------------------
437   ;;  Cleanup the registry
438   ;;-----------------------
439   DeleteRegValue HKCU "Software\GNU\GnuPG" "Start Menu Folder"
440   DeleteRegValue HKLM "Software\GNU\GnuPG" "Install Directory"
441   DeleteRegKey /ifempty HKLM "Software\GNU\GnuPG"
442   DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GnuPG"
443
444 SectionEnd ; Uninstall
445
446
447 ; ---------
448 ; Functions
449 ; ---------
450
451 Function .onInit
452   # We can't use System.dll anymore becuase it has bee removed from
453   # Debian due to an inability to build using FS.  We should use the
454   # use our own DLL as we do with gpg4win.
455   #System::Call 'kernel32::CreateMutexA(i 0, i 0, t "GnuPGInst") i .r1 ?e'
456   #Pop $R0
457   #StrCmp $R0 0 +3
458   # MessageBox MB_OK "An instance of the installer is already running."
459   # Abort
460
461   ;;!define MUI_LANGDLL_ALWAYSSHOW
462   !insertmacro MUI_LANGDLL_DISPLAY
463
464   !insertmacro MUI_INSTALLOPTIONS_EXTRACT "opt.ini"
465
466 FunctionEnd 
467
468
469 Function un.onInit 
470
471   !insertmacro MUI_UNGETLANGUAGE
472   
473 FunctionEnd
474
475
476 ;; Check whether the current user is in the Administrator group or
477 ;; an OS version without the need for an Administrator is in use.
478 ;; Print a warning if this is not the case.
479 Function PrintNonAdminWarning
480   ClearErrors
481   UserInfo::GetName
482   IfErrors leave
483   Pop $0
484   UserInfo::GetAccountType
485   Pop $1
486   StrCmp $1 "Admin" leave +1
487   MessageBox MB_OK "$(T_AdminNeeded)"
488
489  leave:
490 FunctionEnd
491
492
493 Function CustomPageOptions  
494   SectionGetFlags ${SecNLS} $R0 
495   IntOp $R0 $R0 & ${SF_SELECTED} 
496   IntCmp $R0 ${SF_SELECTED} show 
497  
498   Abort 
499  
500  show: 
501   !insertmacro MUI_HEADER_TEXT "$(T_InstallOptions)" "$(T_SelectLanguage)"
502   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "opt.ini" "Field 1" "ListItems"
503   ReadRegStr $R1 HKCU "Software\GNU\GnuPG" "Lang" 
504   StrCmp $R1 "" use_default +1
505   ${StrStr} $R2 $R0 "$R1 - " 
506   StrCmp $R2 "" +1 set_lang
507  use_default:
508   StrCpy $R2 "$(T_langid) - $(T_langname)"
509  set_lang:
510   ${StrTok} $R3 $R2 "|" "0" "1"
511   !insertmacro MUI_INSTALLOPTIONS_WRITE "opt.ini" "Field 1" "State" $R3
512
513   !insertmacro MUI_INSTALLOPTIONS_DISPLAY "opt.ini"
514
515 FunctionEnd
516
517
518 ; Install iconv.dll if it has not been installed on the system.
519 Function InstallIconv
520
521   ; First delete a iconv DLL already installed in the target directory.
522   ; This is required to detect a meanwhile globally installed dll.
523   Delete "$INSTDIR\iconv.dll"
524   ClearErrors
525   GetDllVersion "iconv.dll" $R0 $R1
526   IfErrors 0 +3
527     DetailPrint "iconv.dll is not installed."
528     goto InstallIconv
529
530   IntOp $R2 $R0 / 0x00010000
531   IntOp $R3 $R0 & 0x0000FFFF
532   IntOp $R4 $R1 / 0x00010000
533   IntOp $R5 $R1 & 0x0000FFFF
534   StrCpy $0 "$R2.$R3.$R4.$R5"
535
536   DetailPrint "iconv.dll version is $0"
537
538   IntCmp $R2 1 0 IconvTooOld
539   IntCmp $R3 9 0 IconvTooOld
540   return
541
542  IconvTooOld:
543     DetailPrint "The installed iconv.dll is too old."
544
545  InstallIconv:
546   SetOutPath "$INSTDIR"
547   File "iconv.dll"
548
549   SetOutPath "$INSTDIR\doc"
550   File "COPYING.LIB.txt"
551   File "README.iconv.txt"
552
553 FunctionEnd
554
555
556 ; ------------
557 ; Descriptions
558 ; ------------
559
560 ; The list of language IDs and corresponding Latin-1 names.  Note that
561 ; this mapping needs to match the one in the mk-w32-dist script, so
562 ; that they are usable to get a default value for then ListItems of
563 ; opt.ini.
564 LangString T_langid   ${LANG_ENGLISH} "en"
565 LangString T_langname ${LANG_ENGLISH} "English"
566 LangString T_langid   ${LANG_GERMAN}  "de"
567 LangString T_langname ${LANG_GERMAN}  "Deutsch"
568
569 ; The About string as displayed on the first page.
570 LangString T_About ${LANG_ENGLISH} \
571   "GnuPG is GNU's tool for secure communication and data storage. \
572   It can be used to encrypt data and to create digital signatures. \
573   It includes an advanced key management facility and is compliant \
574   with the proposed OpenPGP Internet standard as described in RFC4880. \
575   \r\n\r\n$_CLICK \
576   \r\n\r\n\r\n\r\n\r\nThis is GnuPG version ${VERSION}\r\n\
577   built on $%BUILDINFO%\r\n\
578   file version ${PROD_VERSION}"
579 LangString T_About ${LANG_GERMAN} \
580   "GnuPG is das Werkzeug aus dem GNU Projekt zur sicheren Kommunikation \
581    sowie zum sicheren Speichern von Daten. \
582    \r\n\r\n$_CLICK \
583    \r\n\r\n\r\n\r\n\r\nDies ist GnuPG Version ${VERSION}\r\n\
584    erstellt am $%BUILDINFO%\r\n\
585    Dateiversion ${PROD_VERSION}"
586
587 ; Startup page
588 LangString T_GPLHeader ${LANG_ENGLISH} \
589   "This software is licensed under the terms of the GNU General Public \
590    License (GPL) which guarantees your freedom to share and change Free \
591    Software."
592 LangString T_GPLHeader ${LANG_GERMAN}} \
593   "Diese Software ist unter der GNU General Public License \
594    (GPL) lizensiert; dies gibt Ihnen die Freiheit, sie \
595    zu ändern und weiterzugeben."
596
597 LangString T_GPLShort ${LANG_ENGLISH} \
598   "In short: You are allowed to run this software for any purpose. \
599    You may distribute it as long as you give the recipients the same \
600    rights you have received."
601 LangString T_GPLShort ${LANG_GERMAN} \
602   "In aller Kürze: Sie haben das Recht, die Software zu jedem Zweck \
603    einzusetzen.  Sie können die Software weitergeben, sofern Sie dem \
604    Empfänger dieselben Rechte einräumen, die auch Sie erhalten haben."
605
606
607 ; Finish page
608 LangString T_FiniLink ${LANG_ENGLISH} \
609   "Visit the GnuPG website for latest news and support"
610 LangString T_FiniLink ${LANG_GERMAN}} \
611   "Zur GnuPG Website mit Neuigkeiten und Hilfsangeboten"
612
613 ; From Function PrintNonAdminWarning
614 LangString T_AdminNeeded ${LANG_ENGLISH} \
615    "Warning: Administrator permissions required for a successful installation"
616 LangString T_AdminNeeded ${LANG_GERMAN} \
617    "Warnung: Administrator Reche werden für eine erfolgreiche \
618     Installation benötigt."
619
620
621 ; Installation options like language used for GnuPG
622 LangString T_InstallOptions ${LANG_ENGLISH} "Install Options"
623 LangString T_InstallOptions ${LANG_GERMAN}  "Installationsoptionen"
624
625 LangString T_SelectLanguage ${LANG_ENGLISH} "GnuPG Language Selection"
626 LangString T_SelectLanguage ${LANG_German}  "Auswahl der Sprache für GnuPG"
627
628 ; This text is used on the finish page.
629 LangString T_ShowReadme ${LANG_ENGLISH} "Show the README file"
630 LangString T_ShowReadme ${LANG_GERMAN} "Die README Datei anzeigen"
631
632 ; Section names
633 LangString DESC_SecBase ${LANG_ENGLISH} \
634       "The basic files used for the standard OpenPGP protocol"
635 LangString DESC_SecBase ${LANG_GERMAN} \
636       "Die Basis Dateien zur Benutzung des OpenPGP Protokolls"
637
638 Langstring DESC_SecNLS ${LANG_ENGLISH} \
639       "Support for languages other than English"
640 LangString DESC_SecNLS ${LANG_GERMAN} \
641       "Unterstützung für weitere Sprachen neben Englisch"
642
643 LangString DESC_SecTools ${LANG_ENGLISH} \
644       "Extra tools like gpgv and gpgsplit"
645 LangString DESC_SecTools ${LANG_GERMAN} \
646       "Weitere Tools wie gpgv und gpgsplit"
647
648 !ifdef WITH_WINPT
649 LangString DESC_SecWinPT ${LANG_ENGLISH} \
650       "The Windows Privacy Tray (WinPT)"
651 LangString DESC_SecWinPT ${LANG_GERMAN} \
652       "Der Windows Privacy Tray (WinPT)"
653 !endif
654
655 LangString DESC_SecDoc ${LANG_ENGLISH} \
656       "Manual pages and a FAQ"
657 LangString DESC_SecDoc ${LANG_GERMAN} \
658       "Handbuchseiten und eine FAQ"
659
660 LangString DESC_SecSource ${LANG_ENGLISH} \
661       "Quelltextdateien"
662 LangString DESC_SecSource ${LANG_GERMAN} \
663       "Source files"
664
665
666
667 ;-------------------------------------
668 ; Associate section names with strings
669 ;--------------------------------------
670 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
671   !insertmacro MUI_DESCRIPTION_TEXT ${SecBase} $(DESC_SecBase)
672   !insertmacro MUI_DESCRIPTION_TEXT ${SecNLS} $(DESC_SecNLS)
673   !insertmacro MUI_DESCRIPTION_TEXT ${SecTools} $(DESC_SecTools)
674 !ifdef WITH_WINPT
675   !insertmacro MUI_DESCRIPTION_TEXT ${SecWinPT} $(DESC_SecWinPT)
676 !endif
677   !insertmacro MUI_DESCRIPTION_TEXT ${SecDoc} $(DESC_SecDoc)
678 !insertmacro MUI_FUNCTION_DESCRIPTION_END
679