tests: Add "disable-scdaemon" in gpg-agent.conf.
[gnupg.git] / tests / gpgme / gpgme-defs.scm
1 #!/usr/bin/env gpgscm
2
3 ;; Copyright (C) 2016 g10 Code GmbH
4 ;;
5 ;; This file is part of GnuPG.
6 ;;
7 ;; GnuPG is free software; you can redistribute it and/or modify
8 ;; it under the terms of the GNU General Public License as published by
9 ;; the Free Software Foundation; either version 3 of the License, or
10 ;; (at your option) any later version.
11 ;;
12 ;; GnuPG is distributed in the hope that it will be useful,
13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 ;; GNU General Public License for more details.
16 ;;
17 ;; You should have received a copy of the GNU General Public License
18 ;; along with this program; if not, see <http://www.gnu.org/licenses/>.
19
20 (load (in-srcdir "tests" "openpgp" "defs.scm"))
21
22 (define gpgme-srcdir (getenv "XTEST_GPGME_SRCDIR"))
23
24 (define (in-gpgme-srcdir . names)
25   (canonical-path (apply path-join (cons gpgme-srcdir names))))
26
27 (define gpgme-builddir (getenv "XTEST_GPGME_BUILDDIR"))
28
29 (define (have-gpgme?)
30   (cond
31    ((string=? "" gpgme-srcdir)
32     (info
33      "SKIP: Environment variable 'XTEST_GPGME_SRCDIR' not set.  Please"
34      "point it to a recent GPGME source tree to run the GPGME test suite.")
35     #f)
36    ((string=? "" gpgme-builddir)
37     (info
38      "SKIP: Environment variable 'XTEST_GPGME_BUILDDIR' not set.  Please"
39      "point it to a recent GPGME build tree to run the GPGME test suite.")
40     #f)
41    (else
42     #t)))
43
44 ;; Make sure that GPGME picks up our gpgconf.  This makes GPGME use
45 ;; and thus executes the tests with GnuPG components from the build
46 ;; tree.
47 (setenv "PATH" (string-append (path-join (getenv "GNUPG_BUILDDIR") "tools")
48                               (string *pathsep*) (getenv "PATH")) #t)
49
50 ;; The tests expect the pinentry to return the passphrase "abc".
51 (setenv "PINENTRY_USER_DATA" "abc" #t)
52
53 (define (create-gpgmehome . path)
54   ;; Support for various environments.
55   (define mode
56     (cond
57      ((equal? path '("lang" "python" "tests"))
58       (set! path '("tests" "gpg")) ;; Mostly uses files from tests/gpg.
59       'python)
60      (else
61       'gpg)))
62
63   (create-file
64    "gpg.conf"
65    "no-force-v3-sigs"
66    (string-append "agent-program " (tool 'gpg-agent) "|--debug-quick-random\n"))
67   (create-file
68    "gpg-agent.conf"
69    (string-append "pinentry-program " (tool 'pinentry))
70    "disable-scdaemon")
71
72   (start-agent)
73
74   (log "Storing private keys")
75   (for-each
76    (lambda (name)
77      (file-copy (apply in-gpgme-srcdir `(,@path ,name))
78                 (path-join "private-keys-v1.d"
79                            (string-append name ".key"))))
80    '("13CD0F3BDF24BE53FE192D62F18737256FF6E4FD"
81      "76F7E2B35832976B50A27A282D9B87E44577EB66"
82      "A0747D5F9425E6664F4FFBEED20FBCA79FDED2BD"
83      "13CBE3758AFE42B5E5E2AE4CED27AFA455E3F87F"
84      "7A030357C0F253A5BBCD282FFC4E521B37558F5C"))
85
86   (log "Importing public demo and test keys")
87   (for-each
88    (lambda (file)
89      (call-check `(,@GPG --yes --import ,(apply in-gpgme-srcdir
90                                                 `(,@path ,file)))))
91    (list "pubdemo.asc" "secdemo.asc"))
92
93   (when (equal? mode 'python)
94         (log "Importing extra keys for Python tests")
95         (for-each
96          (lambda (file)
97            (call-check `(,@GPG --yes --import
98                                ,(apply in-gpgme-srcdir
99                                        `("lang" "python" "tests" ,file)))))
100          (list "encrypt-only.asc" "sign-only.asc"))
101
102         (log "Marking key as trusted")
103         (pipe:do
104          (pipe:echo "A0FF4590BB6122EDEF6E3C542D727CC768697734:6:\n")
105          (pipe:spawn `(,(tool 'gpg) --import-ownertrust))))
106
107   (stop-agent))
108
109 ;; Initialize the test environment, install appropriate configuration
110 ;; and start the agent, with the keys from the legacy test suite.
111 (define (setup-gpgme-environment . path)
112   (if (member "--unpack-tarball" *args*)
113       (begin
114         (call-check `(,(tool 'gpgtar) --extract --directory=. ,(cadr *args*)))
115         (start-agent))
116       (apply create-gpgme-gpghome path)))
117
118 (define python
119   (let loop ((pythons (list "python" "python2" "python3")))
120     (if (null? pythons)
121         #f
122         (catch (loop (cdr pythons))
123                (unless (file-exists? (path-join gpgme-builddir "lang" "python"
124                                                 (string-append (car pythons) "-gpg")))
125                        (throw "next please"))
126                (path-expand (car pythons) (string-split (getenv "PATH") *pathsep*))))))
127
128 (define (run-python-tests?)
129   (not (not python)))