Fixed a C-89 incompatibility.
authorWerner Koch <wk@gnupg.org>
Wed, 23 Apr 2008 17:23:04 +0000 (17:23 +0000)
committerWerner Koch <wk@gnupg.org>
Wed, 23 Apr 2008 17:23:04 +0000 (17:23 +0000)
Minor changes to make it build on Debian bo.
Thanks to Alain Guibert.

ChangeLog
configure.ac
m4/ChangeLog
m4/Makefile.am
m4/socklen.m4 [new file with mode: 0644]
m4/sys_socket_h.m4 [new file with mode: 0644]
sm/ChangeLog
sm/certchain.c

index 75f89cb..134e3ea 100644 (file)
--- a/ChangeLog
+++ b/ChangeLog
@@ -1,3 +1,7 @@
+2008-04-23  Werner Koch  <wk@g10code.com>
+
+       * configure.ac: Call gl_HEADER_SYS_SOCKET and gl_TYPE_SOCKLEN_T.
+
 2008-04-07  Werner Koch  <wk@g10code.com>
 
        * configure.ac (ADNSLIBS): Test for adns.
index 4ad65a6..ed7aa68 100644 (file)
@@ -992,6 +992,9 @@ AC_TYPE_MODE_T
 AC_TYPE_SIGNAL
 AC_DECL_SYS_SIGLIST
 
+gl_HEADER_SYS_SOCKET
+gl_TYPE_SOCKLEN_T
+
 AC_ARG_ENABLE(endian-check,
               AC_HELP_STRING([--disable-endian-check],
              [disable the endian check and trust the OS provided macros]),
index b58f231..ee88462 100644 (file)
@@ -1,3 +1,8 @@
+2008-04-23  Werner Koch  <wk@g10code.com>
+
+       * socklen.m4, sys_socket_h.m4: New.  Taken from libassuan.
+       * Makefile.am (EXTRA_DIST): Add them.
+
 2008-02-15  gettextize  <bug-gnu-gettext@gnu.org>
 
        * gettext.m4: Upgrade to gettext-0.17.
index 34b1743..d0d84e2 100644 (file)
@@ -10,5 +10,9 @@ EXTRA_DIST += autobuild.m4
 
 EXTRA_DIST += estream.m4
 
+EXTRA_DIST += sys_socket_h.m4 socklen.m4
+
+
+
 
 
diff --git a/m4/socklen.m4 b/m4/socklen.m4
new file mode 100644 (file)
index 0000000..5e3765a
--- /dev/null
@@ -0,0 +1,52 @@
+# socklen.m4 serial 4
+dnl Copyright (C) 2005, 2006 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl From Albert Chin, Windows fixes from Simon Josefsson.
+
+dnl Check for socklen_t: historically on BSD it is an int, and in
+dnl POSIX 1g it is a type of its own, but some platforms use different
+dnl types for the argument to getsockopt, getpeername, etc.  So we
+dnl have to test to find something that will work.
+
+dnl On mingw32, socklen_t is in ws2tcpip.h ('int'), so we try to find
+dnl it there first.  That file is included by gnulib's socket_.h, which
+dnl all users of this module should include.  Cygwin must not include
+dnl ws2tcpip.h.
+AC_DEFUN([gl_TYPE_SOCKLEN_T],
+  [AC_REQUIRE([gl_HEADER_SYS_SOCKET])dnl
+   AC_CHECK_TYPE([socklen_t], ,
+     [AC_MSG_CHECKING([for socklen_t equivalent])
+      AC_CACHE_VAL([gl_cv_gl_cv_socklen_t_equiv],
+       [# Systems have either "struct sockaddr *" or
+        # "void *" as the second argument to getpeername
+        gl_cv_socklen_t_equiv=
+        for arg2 in "struct sockaddr" void; do
+          for t in int size_t "unsigned int" "long int" "unsigned long int"; do
+            AC_TRY_COMPILE(
+              [#include <sys/types.h>
+               #include <sys/socket.h>
+
+               int getpeername (int, $arg2 *, $t *);],
+              [$t len;
+               getpeername (0, 0, &len);],
+              [gl_cv_socklen_t_equiv="$t"])
+            test "$gl_cv_socklen_t_equiv" != "" && break
+          done
+          test "$gl_cv_socklen_t_equiv" != "" && break
+        done
+      ])
+      if test "$gl_cv_socklen_t_equiv" = ""; then
+       AC_MSG_ERROR([Cannot find a type to use in place of socklen_t])
+      fi
+      AC_MSG_RESULT([$gl_cv_socklen_t_equiv])
+      AC_DEFINE_UNQUOTED([socklen_t], [$gl_cv_socklen_t_equiv],
+       [type to use in place of socklen_t if not defined])],
+     [#include <sys/types.h>
+      #if HAVE_SYS_SOCKET_H
+      # include <sys/socket.h>
+      #elif HAVE_WS2TCPIP_H
+      # include <ws2tcpip.h>
+      #endif])])
diff --git a/m4/sys_socket_h.m4 b/m4/sys_socket_h.m4
new file mode 100644 (file)
index 0000000..d3e45b4
--- /dev/null
@@ -0,0 +1,23 @@
+# sys_socket_h.m4 serial 2
+dnl Copyright (C) 2005, 2006 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl From Simon Josefsson.
+
+AC_DEFUN([gl_HEADER_SYS_SOCKET],
+[
+  AC_CHECK_HEADERS_ONCE([sys/socket.h])
+  if test $ac_cv_header_sys_socket_h = yes; then
+    SYS_SOCKET_H=''
+  else
+    dnl We cannot use AC_CHECK_HEADERS_ONCE here, because that would make
+    dnl the check for those headers unconditional; yet cygwin reports
+    dnl that the headers are present but cannot be compiled (since on
+    dnl cygwin, all socket information should come from sys/socket.h).
+    AC_CHECK_HEADERS([winsock2.h ws2tcpip.h])
+    SYS_SOCKET_H='sys/socket.h'
+  fi
+  AC_SUBST(SYS_SOCKET_H)
+])
index bff7f1b..7fad938 100644 (file)
@@ -1,3 +1,8 @@
+2008-04-23  Werner Koch  <wk@g10code.com>
+
+       * certchain.c (find_up): Make correct C89 code.  Declare variable
+       at the top of the block.  Reported by Alain Guibert.
+
 2008-04-09  Werner Koch  <wk@g10code.com>
 
        * verify.c (gpgsm_verify): Print the message hash values on error.
index 05a6ace..03b020e 100644 (file)
@@ -702,12 +702,14 @@ find_up (ctrl_t ctrl, KEYDB_HANDLE kh,
     rc = keydb_search_subject (kh, issuer);
   if (rc == -1 && !find_next)
     {
+      int old;
+
       /* Also try to get it from the Dirmngr cache.  The function
          merely puts it into the ephemeral database.  */
       find_up_dirmngr (ctrl, kh, NULL, issuer, 0);
 
       /* Not found, let us see whether we have one in the ephemeral key DB. */
-      int old = keydb_set_ephemeral (kh, 1);
+      old = keydb_set_ephemeral (kh, 1);
       if (!old)
         {
           keydb_search_reset (kh);