5aad9f40e8d6cd8b97ab820b319a1c308b153744
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
4 #               2009, 2010, 2011, 2012, 2013, 2014, 2015  g10 Code GmbH
5 #
6 # This file is part of GPGME.
7 #
8 # GPGME is free software; you can redistribute it and/or modify it
9 # under the terms of the GNU Lesser General Public License as
10 # published by the Free Software Foundation; either version 2.1 of the
11 # License, or (at your option) any later version.
12 #
13 # GPGME is distributed in the hope that it will be useful, but WITHOUT
14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
16 # Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, see <http://www.gnu.org/licenses/>.
20
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.59)
23 min_automake_version="1.14"
24
25 # To build a release you need to create a tag with the version number
26 # (git tag -s gpgme-n.m.k) and run "./autogen.sh --force".  Please
27 # bump the version number immediately after the release and do another
28 # commit and push so that the git magic is able to work.  See below
29 # for the LT versions.
30 m4_define(mym4_version_major, [1])
31 m4_define(mym4_version_minor, [6])
32 m4_define(mym4_version_micro, [1])
33
34 # Below is m4 magic to extract and compute the revision number, the
35 # decimalized short revision number, a beta version string, and a flag
36 # indicating a development version (mym4_isgit). Note that the m4
37 # processing is done by autoconf and not during the configure run.
38 m4_define(mym4_version,
39           [mym4_version_major.mym4_version_minor.mym4_version_micro])
40 m4_define([mym4_revision],
41           m4_esyscmd([git rev-parse --short HEAD | tr -d '\n\r']))
42 m4_define([mym4_revision_dec],
43           m4_esyscmd_s([echo $((0x$(echo ]mym4_revision[|head -c 4)))]))
44 m4_define([mym4_betastring],
45           m4_esyscmd_s([git describe --match 'gpgme-[0-9].*[0-9]' --long|\
46                         awk -F- '$3!=0{print"-beta"$3}']))
47 m4_define([mym4_isgit],m4_if(mym4_betastring,[],[no],[yes]))
48 m4_define([mym4_full_version],[mym4_version[]mym4_betastring])
49
50 AC_INIT([gpgme],[mym4_full_version],[http://bugs.gnupg.org])
51
52 # LT Version numbers, remember to change them just *before* a release.
53 #   (Code changed:                      REVISION++)
54 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
55 #   (Interfaces added:                  AGE++)
56 #   (Interfaces removed/changed:        AGE=0)
57 #
58 LIBGPGME_LT_CURRENT=25
59 # Subtract 2 from this value if you want to make the LFS transition an
60 # ABI break.  [Note to self: Remove this comment with the next regular break.]
61 LIBGPGME_LT_AGE=14
62 LIBGPGME_LT_REVISION=0
63
64 LIBGPGMEPP_LT_CURRENT=3
65 LIBGPGMEPP_LT_AGE=0
66 LIBGPGMEPP_LT_REVISION=0
67
68 # If the API is changed in an incompatible way: increment the next counter.
69 GPGME_CONFIG_API_VERSION=1
70 ##############################################
71
72 NEED_GPG_ERROR_VERSION=1.11
73 NEED_LIBASSUAN_API=2
74 NEED_LIBASSUAN_VERSION=2.0.2
75
76
77 PACKAGE=$PACKAGE_NAME
78 VERSION=$PACKAGE_VERSION
79
80 AC_CONFIG_AUX_DIR([build-aux])
81 AC_CONFIG_MACRO_DIR([m4])
82 AC_CONFIG_SRCDIR(src/gpgme.h.in)
83 AC_CONFIG_HEADER(config.h)
84 AM_INIT_AUTOMAKE([serial-tests dist-bzip2 no-dist-gzip])
85 AM_MAINTAINER_MODE
86 AC_CANONICAL_HOST
87 AM_SILENT_RULES
88 AC_ARG_VAR(SYSROOT,[locate config scripts also below that directory])
89
90 # Enable GNU extensions on systems that have them.
91 AC_GNU_SOURCE
92
93 AH_VERBATIM([_REENTRANT],
94 [/* To allow the use of GPGME in multithreaded programs we have to use
95   special features from the library.
96   IMPORTANT: gpgme is not yet fully reentrant and you should use it
97   only from one thread.  */
98 #ifndef _REENTRANT
99 # define _REENTRANT 1
100 #endif])
101
102 AC_PROG_CC
103 AC_PROG_CXX
104
105 # Note: A suitable gitlog-to-changelog script can be found in GnuPG master.
106 AC_CHECK_PROGS(GITLOG_TO_CHANGELOG, gitlog-to-changelog, [gitlog-to-changelog])
107
108 AC_SUBST(LIBGPGME_LT_CURRENT)
109 AC_SUBST(LIBGPGME_LT_AGE)
110 AC_SUBST(LIBGPGME_LT_REVISION)
111 AC_SUBST(LIBGPGMEPP_LT_CURRENT)
112 AC_SUBST(LIBGPGMEPP_LT_AGE)
113 AC_SUBST(LIBGPGMEPP_LT_REVISION)
114
115 AC_SUBST(PACKAGE)
116 AC_SUBST(VERSION)
117 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
118 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
119 VERSION_NUMBER=m4_esyscmd(printf "0x%02x%02x%02x" mym4_version_major \
120                           mym4_version_minor mym4_version_micro)
121 AC_SUBST(VERSION_NUMBER)
122
123 # Don't default to build static libs.
124 LT_PREREQ([2.2.6])
125 LT_INIT([win32-dll disable-static])
126 LT_LANG([Windows Resource])
127
128 # For now we hardcode the use of version scripts.  It would be better
129 # to write a test for this or even implement this within libtool.
130 have_ld_version_script=no
131 case "${host}" in
132     *-*-linux*)
133         have_ld_version_script=yes
134         ;;
135     *-*-gnu*)
136         have_ld_version_script=yes
137         ;;
138     *-apple-darwin*)
139         AC_DEFINE(_XOPEN_SOURCE, 500, Activate POSIX interface on MacOS X)
140         ;;
141 esac
142
143 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
144
145 GPG_DEFAULT=no
146 GPGSM_DEFAULT=no
147 GPGCONF_DEFAULT=no
148 G13_DEFAULT=no
149 component_system=None
150 have_dosish_system=no
151 have_android_system=no
152 have_w32_system=no
153 have_w64_system=no
154 build_w32_glib=no
155 build_w32_qt=no
156 available_languages="cpp cl"
157 default_languages="cpp cl"
158 case "${host}" in
159     x86_64-*mingw32*)
160         have_w64_system=yes
161         ;;
162     *-mingw32ce*)
163         have_w32ce_system=yes
164         ;;
165     *-linux-androideabi)
166         have_android_system=yes
167         ;;
168 esac
169 case "${host}" in
170     *-mingw32ce*|*-mingw32*)
171         have_dosish_system=yes
172         have_w32_system=yes
173         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
174         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
175         GPGCONF_DEFAULT='c:\\gnupg\\gpgconf.exe'
176         G13_DEFAULT='c:\\gnupg\\g13.exe'
177         #component_system='COM+'
178
179         AM_PATH_GLIB_2_0
180         AC_ARG_ENABLE(w32-glib,
181             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
182                            build_w32_glib=$enableval)
183
184         # Check disabled, because the qt-dev packages in gpg4win do
185         # not provide any support for cross compilation.
186         # PKG_CHECK_MODULES(QT4_CORE, QtCore)
187
188         # Use it like this:
189         # ./configure --enable-w32-qt QT4_CORE_CFLAGS="..." QT4_CORE_LIBS="..."
190         AC_SUBST(QT4_CORE_CFLAGS)
191         AC_SUBST(QT4_CORE_LIBS)
192         AC_ARG_ENABLE(w32-qt,
193             AC_HELP_STRING([--enable-w32-qt], [build GPGME Qt for W32]),
194                            build_w32_qt=$enableval)
195         ;;
196     *)
197         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
198         if test "$have_pthread" = yes; then
199           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
200         fi
201
202         # XXX: Probably use exec-prefix here?
203 #       GPG_DEFAULT='/usr/bin/gpg'
204 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
205 #       GPGCONF_DEFAULT='/usr/bin/gpgconf'
206 #       G13_DEFAULT='/usr/bin/g13'
207         ;;
208 esac
209
210 if test "$have_dosish_system" = yes; then
211    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
212              [Defined if we run on some of the PCDOS like systems
213               (DOS, Windoze. OS/2) with special properties like
214               no file modes])
215 fi
216 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
217
218 if test "$have_w32_system" = yes; then
219    AC_DEFINE(HAVE_W32_SYSTEM,1,
220              [Defined if we run on any kind of W32 API based system])
221 fi
222 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
223
224 if test "$have_w64_system" = yes; then
225    AC_DEFINE(HAVE_W64_SYSTEM,1,
226              [Defined if we run on a 64 bit W32 API based system])
227 fi
228 AM_CONDITIONAL(HAVE_W64_SYSTEM, test "$have_w64_system" = yes)
229
230 if test "$have_w32ce_system" = yes; then
231    AC_DEFINE(HAVE_W32CE_SYSTEM,1,
232              [Defined if we run on a W32 CE API based system])
233 fi
234 AM_CONDITIONAL(HAVE_W32CE_SYSTEM, test "$have_w32ce_system" = yes)
235
236 if test "$have_android_system" = yes; then
237    AC_DEFINE(HAVE_ANDROID_SYSTEM,1, [Defined if we build for an Android system])
238 fi
239 AM_CONDITIONAL(HAVE_ANDROID_SYSTEM, test "$have_android_system" = yes)
240
241 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
242 AM_CONDITIONAL(BUILD_W32_QT, test "$build_w32_qt" = yes)
243
244 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
245
246
247 AC_ARG_ENABLE([fixed-path],
248               AC_HELP_STRING([--enable-fixed-path=PATH],
249                              [locate binaries only via this PATH]),
250               [fixed_search_path="$enableval"],
251               [fixed_search_path=""])
252 if test x$fixed_search_path != x ; then
253   AC_DEFINE_UNQUOTED(FIXED_SEARCH_PATH, "$fixed_search_path",
254                     [Locate binaries only via this PATH])
255 fi
256
257 AC_ARG_ENABLE([languages],
258               AC_HELP_STRING([--enable-languages=languages],
259                              [enable only specific language bindings]),
260                              [enabled_languages=`echo $enableval | \
261                              tr ',:' '  ' | tr '[A-Z]' '[a-z]' | \
262                              sed 's/c++/cpp/'`],
263                              [enabled_languages="$default_languages"])
264 if test "x$enabled_languages" = "x" \
265    -o "$enabled_languages" = "no"; then
266    enabled_languages=
267 fi
268 for language in $enabled_languages; do
269     LIST_MEMBER($language, $available_languages)
270     if test "$found" = "0"; then
271        AC_MSG_ERROR([unsupported language binding specified])
272     fi
273 done
274 AC_SUBST(ENABLED_LANGUAGES, $enabled_languages)
275
276 #
277 # Provide information about the build.
278 #
279 BUILD_REVISION="mym4_revision"
280 AC_SUBST(BUILD_REVISION)
281 AC_DEFINE_UNQUOTED(BUILD_REVISION, "$BUILD_REVISION",
282                    [GIT commit id revision used to build this package])
283
284 changequote(,)dnl
285 BUILD_FILEVERSION=`echo "$PACKAGE_VERSION"|sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
286 changequote([,])dnl
287 BUILD_FILEVERSION="${BUILD_FILEVERSION}mym4_revision_dec"
288 AC_SUBST(BUILD_FILEVERSION)
289
290 AC_ARG_ENABLE([build-timestamp],
291   AC_HELP_STRING([--enable-build-timestamp],
292                  [set an explicit build timestamp for reproducibility.
293                   (default is the current time in ISO-8601 format)]),
294      [if test "$enableval" = "yes"; then
295         BUILD_TIMESTAMP=`date -u +%Y-%m-%dT%H:%M+0000 2>/dev/null || date`
296       else
297         BUILD_TIMESTAMP="$enableval"
298       fi],
299      [BUILD_TIMESTAMP="<none>"])
300 AC_SUBST(BUILD_TIMESTAMP)
301 AC_DEFINE_UNQUOTED(BUILD_TIMESTAMP, "$BUILD_TIMESTAMP",
302                    [The time this package was configured for a build])
303
304
305 #
306 # Options to disable some regression tests
307 #
308 run_gpgconf_test="yes"
309 AC_ARG_ENABLE(gpgconf-test,
310   AC_HELP_STRING([--disable-gpgconf-test], [disable GPGCONF regression test]),
311          run_gpgconf_test=$enableval)
312 AM_CONDITIONAL(RUN_GPGCONF_TESTS, test "$run_gpgconf_test" = "yes")
313
314 run_gpg_test="yes"
315 AC_ARG_ENABLE(gpg-test,
316   AC_HELP_STRING([--disable-gpg-test], [disable GPG regression test]),
317          run_gpg_test=$enableval)
318 AM_CONDITIONAL(RUN_GPG_TESTS, test "$run_gpg_test" = "yes")
319
320 run_gpgsm_test="yes"
321 AC_ARG_ENABLE(gpgsm-test,
322   AC_HELP_STRING([--disable-gpgsm-test], [disable GPGSM regression test]),
323          run_gpgsm_test=$enableval)
324 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$run_gpgsm_test" = "yes")
325
326 run_g13_test="yes"
327 AC_ARG_ENABLE(g13-test,
328   AC_HELP_STRING([--disable-g13-test], [disable G13 regression test]),
329          run_g13_test=$enableval)
330 AM_CONDITIONAL(RUN_G13_TESTS, test "$run_g13_test" = "yes")
331
332
333 # Checks for header files.
334 AC_CHECK_HEADERS_ONCE([locale.h sys/select.h sys/uio.h argp.h
335                        unistd.h sys/time.h sys/types.h sys/stat.h])
336
337
338 # Type checks.
339 AC_C_INLINE
340 AC_CHECK_SIZEOF(unsigned int)
341 AC_SYS_LARGEFILE
342 AC_TYPE_OFF_T
343 AC_TYPE_UINTPTR_T
344
345 # A simple compile time check in gpgme.h for GNU/Linux systems that
346 # prevents a file offset bits mismatch between gpgme and the application.
347 NEED__FILE_OFFSET_BITS=0
348 if test "$have_w32_system" != yes; then
349   case "$ac_cv_sys_file_offset_bits" in
350     "" | no | unknown) ;;
351     *)
352     NEED__FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits
353     ;;
354   esac
355 fi
356 AC_SUBST(NEED__FILE_OFFSET_BITS)
357
358 # Figure out platform dependent typedefs for gpgme.h
359 if test "$have_w32_system" = yes; then
360     INSERT__TYPEDEFS_FOR_GPGME_H="
361 #ifdef _WIN64
362 # include <stdint.h>
363   typedef int64_t gpgme_off_t;
364   typedef int64_t gpgme_ssize_t;
365 #else /* _WIN32 */
366   typedef long gpgme_off_t;
367   typedef long gpgme_ssize_t;
368 #endif /* _WIN32 */"
369     API__OFF_T="gpgme_off_t"
370     API__SSIZE_T="gpgme_ssize_t"
371 else
372     INSERT__TYPEDEFS_FOR_GPGME_H="
373 #include <sys/types.h>
374 typedef off_t   gpgme_off_t;
375 typedef ssize_t gpgme_ssize_t;"
376     API__OFF_T="off_t"
377     API__SSIZE_T="ssize_t"
378 fi
379 AC_SUBST(INSERT__TYPEDEFS_FOR_GPGME_H)
380 AM_SUBST_NOTMAKE(INSERT__TYPEDEFS_FOR_GPGME_H)
381 AC_SUBST(API__OFF_T)
382 AM_SUBST_NOTMAKE(API__OFF_T)
383 AC_SUBST(API__SSIZE_T)
384 AM_SUBST_NOTMAKE(API__SSIZE_T)
385
386 # Checks for compiler features.
387 if test "$GCC" = yes; then
388     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
389     if test "$have_w32_system" = yes; then
390        CFLAGS="$CFLAGS -mms-bitfields"
391     fi
392 fi
393
394 # Only used for debugging, so no serious test needed (for actual
395 # functionality you have to test libc as well, this only tests the
396 # compiler).
397 AC_CACHE_CHECK([for __thread],[gpgme_cv_tls_works],
398    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([__thread int foo;])],
399                      gpgme_cv_tls_works=yes,gpgme_cv_tls_works=no))
400 if test "$gpgme_cv_tls_works" = yes; then
401   AC_DEFINE(HAVE_TLS, [1], [Define if __thread is supported])
402 fi
403
404
405 # Checks for library functions.
406 AC_MSG_NOTICE([checking for libraries])
407
408 AC_FUNC_FSEEKO
409
410 AC_REPLACE_FUNCS(vasprintf)
411 if test "$ac_cv_func_vasprintf" != yes; then
412   GNUPG_CHECK_VA_COPY
413 fi
414
415 # Try to find a thread-safe version of ttyname().
416 gnupg_REPLACE_TTYNAME_R
417 if test "$ac_cv_func_ttyname_r" != yes; then
418   AC_MSG_WARN([
419 ***
420 *** ttyname() is not thread-safe and ttyname_r() does not exist
421 ***])
422 fi
423
424 # Try to find a thread-safe version of getenv().
425 have_thread_safe_getenv=no
426 jm_GLIBC21
427 if test $GLIBC21 = yes; then
428   have_thread_safe_getenv=yes
429 fi
430 if test $have_thread_safe_getenv = yes; then
431   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
432 fi
433 have_getenv_r=no
434 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
435 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
436   AC_MSG_WARN([
437 ***
438 *** getenv() is not thread-safe and getenv_r() does not exist
439 ***])
440 fi
441
442 # For converting time strings to seconds since Epoch, we need the timegm
443 # function.
444 AC_CHECK_FUNCS(timegm)
445 if test "$ac_cv_func_timegm" != yes; then
446   AC_MSG_WARN([
447 ***
448 *** timegm() not available - a non-thread-safe kludge will be used
449 *** and the TZ variable might be changed at runtime.
450 ***])
451 fi
452
453 AC_CHECK_FUNCS(setlocale)
454
455 # Checking for libgpg-error.
456 have_gpg_error=no
457 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
458                   have_gpg_error=yes, have_gpg_error=no)
459 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
460           [The default error source for GPGME.])
461
462 # And for libassuan.
463 have_libassuan=no
464 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
465                   have_libassuan=yes, have_libassuan=no)
466 if test "$have_libassuan" = "yes"; then
467   AC_DEFINE_UNQUOTED(GPGME_LIBASSUAN_VERSION, "$libassuan_version",
468                      [version of the libassuan library])
469 fi
470
471
472 #
473 # Other checks
474 #
475
476 # Check for funopen
477 AC_CHECK_FUNCS(funopen)
478 if test $ac_cv_func_funopen != yes; then
479     # No funopen but we can implement that in terms of fopencookie.
480     AC_CHECK_FUNCS(fopencookie)
481     if test $ac_cv_func_fopencookie = yes; then
482         AC_REPLACE_FUNCS(funopen)
483     else
484         AC_MSG_WARN([
485 ***
486 *** No implementation of fopencookie or funopen available
487 ***])
488     fi
489 fi
490
491 # Check for getgid etc
492 AC_CHECK_FUNCS(getgid getegid)
493
494
495 # Replacement functions.
496 AC_REPLACE_FUNCS(stpcpy)
497 AC_REPLACE_FUNCS(setenv)
498
499 # Assuan check for descriptor passing.
500 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
501                 [supports_descriptor_passing=yes],
502                 [supports_descriptor_passing=no
503                  AC_MSG_WARN([
504 ***
505 *** Data structure for sending ancillary data missing.
506 *** Descriptor passing won't work.
507 ***])],[
508 #include <stdlib.h>
509 #include <stddef.h>
510 #include <stdio.h>
511 #include <sys/types.h>
512 #include <sys/socket.h>
513 #include <sys/un.h>
514 #if HAVE_SYS_UIO_H
515 #include <sys/uio.h>
516 #endif
517 #include <unistd.h>
518        ])
519
520
521 dnl There seems to be a problem with Apple and decriptor passing.
522 dnl Until we found a solution we change the default to no.
523 dnl See bug 1483.
524 case "${host}" in
525     *-apple-darwin*)
526       use_descriptor_passing=no
527       ;;
528     *)
529       use_descriptor_passing=yes
530       ;;
531 esac
532 AC_ARG_ENABLE(fd-passing,
533   AC_HELP_STRING([--disable-fd-passing], [do not use FD passing]),
534   use_descriptor_passing=$enableval)
535
536 if test "$supports_descriptor_passing" != "yes"; then
537   use_descriptor_passing=no
538 fi
539
540 if test "$use_descriptor_passing" = "yes"; then
541 AC_DEFINE(USE_DESCRIPTOR_PASSING,1,
542           [Defined if descriptor passing is enabled and supported])
543 fi
544
545 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
546
547
548 uiserver=no
549 if test "$use_descriptor_passing" = "yes" && test "$have_libassuan" = "yes"; then
550   uiserver=yes
551 fi
552 if test "$uiserver" != "no"; then
553   AC_DEFINE(ENABLE_UISERVER, 1,
554             [Defined if we are building with uiserver support.])
555 fi
556 AM_CONDITIONAL(HAVE_UISERVER, test "$uiserver" != "no")
557
558
559 # Add a few constants to help porting to W32
560 AH_VERBATIM([SEPCONSTANTS],
561 [
562 /* Separators as used in $PATH and file name.  */
563 #ifdef HAVE_DOSISH_SYSTEM
564 #define PATHSEP_C ';'
565 #define DIRSEP_C '\\'
566 #define DIRSEP_S "\\"
567 #else
568 #define PATHSEP_C ':'
569 #define DIRSEP_C '/'
570 #define DIRSEP_S "/"
571 #endif
572 ])
573
574 AH_BOTTOM([
575 /* Definition of GCC specific attributes.  */
576 #if __GNUC__ > 2
577 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
578 #else
579 # define GPGME_GCC_A_PURE
580 #endif
581
582 /* Under WindowsCE we need gpg-error's strerror macro.  */
583 #define GPG_ERR_ENABLE_ERRNO_MACROS 1
584
585 #define CRIGHTBLURB "Copyright (C) 2000 Werner Koch\n" \
586                     "Copyright (C) 2001--2015 g10 Code GmbH\n"
587 ])
588
589
590 # Substitution used for gpgme-config
591 GPGME_CONFIG_LIBS="-lgpgme"
592 GPGME_CONFIG_CFLAGS=""
593 GPGME_CONFIG_HOST="$host"
594 AC_SUBST(GPGME_CONFIG_API_VERSION)
595 AC_SUBST(GPGME_CONFIG_LIBS)
596 AC_SUBST(GPGME_CONFIG_CFLAGS)
597 AC_SUBST(GPGME_CONFIG_HOST)
598
599 # Frob'da Variables
600 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
601            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
602 AC_SUBST(LTLIBOBJS)
603
604 # Some checks for gpgme-tool
605 # Done at top: AC_CHECK_HEADER([argp.h])
606 AC_CHECK_TYPES([error_t], [],
607    [AC_DEFINE([error_t], [int],
608    [Define to a type to use for `error_t' if it is not otherwise available.])],
609    [#include <errno.h>])
610
611
612 # A substitution to set generated files in a Emacs buffer to read-only.
613 AC_SUBST(emacs_local_vars_begin, [['Local][ ][Variables:']])
614 AC_SUBST(emacs_local_vars_read_only, ['buffer-read-only: t'])
615 AC_SUBST(emacs_local_vars_end, ['End:'])
616
617
618 # Last check.
619 die=no
620 if test "$have_gpg_error" = "no"; then
621    die=yes
622    AC_MSG_NOTICE([[
623 ***
624 *** You need libgpg-error to build this program.
625 **  This library is for example available at
626 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
627 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
628 ***]])
629 fi
630 if test "$have_libassuan" = "no"; then
631    die=yes
632    AC_MSG_NOTICE([[
633 ***
634 *** You need libassuan to build this program.
635 *** This library is for example available at
636 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
637 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
638 ***]])
639 fi
640
641 if test "$die" = "yes"; then
642     AC_MSG_ERROR([[
643 ***
644 *** Required libraries not found. Please consult the above messages
645 *** and install them before running configure again.
646 ***]])
647 fi
648
649
650 #
651 # Create config files
652
653 AC_CONFIG_FILES(Makefile src/Makefile
654                 tests/Makefile
655                 tests/gpg/Makefile
656                 tests/gpgsm/Makefile
657                 tests/opassuan/Makefile
658                 doc/Makefile
659                 src/versioninfo.rc
660                 src/gpgme.h)
661 AC_CONFIG_FILES(src/gpgme-config, chmod +x src/gpgme-config)
662 AC_CONFIG_FILES(lang/cpp/Makefile lang/cpp/src/Makefile)
663 AC_CONFIG_FILES(lang/cpp/src/GpgmeppConfig.cmake.in)
664 AC_CONFIG_FILES(lang/cpp/src/GpgmeppConfigVersion.cmake)
665 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
666 AC_OUTPUT
667
668 echo "
669         GPGME v${VERSION} has been configured as follows:
670
671         Revision:          mym4_revision  (mym4_revision_dec)
672         Platform:          $host
673
674         UI Server:         $uiserver
675         FD Passing:        $use_descriptor_passing
676         GPGME Pthread:     $have_pthread
677
678         Language bindings: $enabled_languages
679 "
680 if test "x${gpg_config_script_warn}" != x; then
681 cat <<G10EOF
682         Mismatches between the target platform and the to
683         be used libraries have been been detected for:
684          ${gpg_config_script_warn}
685         Please check above for warning messages.
686
687 G10EOF
688 fi