* Fixed a bug in that the fingerprints of subkeys are not available.
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005 g10 Code GmbH
4
5 # This file is part of GPGME.
6
7 # GPGME is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU Lesser General Public License as
9 # published by the Free Software Foundation; either version 2.1 of the
10 # License, or (at your option) any later version.
11
12 # GPGME is distributed in the hope that it will be useful, but WITHOUT
13 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
15 # Public License for more details.
16
17 # You should have received a copy of the GNU Lesser General Public
18 # License along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20  
21 # (Process this file with autoconf to produce a configure script.)
22
23 AC_PREREQ(2.59)
24 min_automake_version="1.9.3"
25
26 # Version number: Remember to change it immediately *after* a release.
27 #                 Make sure to run  "svn up" before a "make dist".
28 AC_INIT(gpgme, 1.2.0-cvs, [bug-gpgme@gnupg.org])
29 # LT Version numbers, remember to change them just *before* a release.
30 #   (Code changed:                      REVISION++)
31 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
32 #   (Interfaces added:                  AGE++)
33 #   (Interfaces removed/changed:        AGE=0)
34 #
35 LIBGPGME_LT_CURRENT=16
36 # Subtract 2 from this value if you want to make the LFS transition an
37 # ABI break.  [Note to self: Remove this comment with the next regular break.]
38 LIBGPGME_LT_AGE=5
39 LIBGPGME_LT_REVISION=0
40
41 # If the API is changed in an incompatible way: increment the next counter.
42 GPGME_CONFIG_API_VERSION=1
43
44 NEED_GPG_VERSION=1.2.2
45 NEED_GPGSM_VERSION=1.9.6
46 ##############################################
47
48
49 PACKAGE=$PACKAGE_NAME
50 VERSION=$PACKAGE_VERSION
51
52 AC_CONFIG_SRCDIR(gpgme/gpgme.h)
53 dnl FIXME: Enable this with autoconf 2.59.
54 dnl AC_CONFIG_MACRO_DIR(m4)
55 AM_CONFIG_HEADER(config.h)
56 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
57 AM_MAINTAINER_MODE
58 AC_CANONICAL_HOST
59
60 # Enable GNU extensions on systems that have them.
61 AC_GNU_SOURCE
62
63 AH_VERBATIM([_REENTRANT],
64 [/* To allow the use of GPGME in multithreaded programs we have to use
65   special features from the library.
66   IMPORTANT: gpgme is not yet fully reentrant and you should use it
67   only from one thread.  */
68 #ifndef _REENTRANT
69 # define _REENTRANT 1
70 #endif])
71
72 AC_PROG_CC
73
74 AC_SUBST(LIBGPGME_LT_CURRENT)
75 AC_SUBST(LIBGPGME_LT_AGE)
76 AC_SUBST(LIBGPGME_LT_REVISION)
77 AC_DEFINE_UNQUOTED(NEED_GPG_VERSION, "$NEED_GPG_VERSION",
78                                      [Min. needed GnuPG version.])
79 AC_DEFINE_UNQUOTED(NEED_GPGSM_VERSION, "$NEED_GPGSM_VERSION",
80                                        [Min. needed GPGSM version.])
81
82 AC_SUBST(PACKAGE)
83 AC_SUBST(VERSION)
84 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
85 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
86
87 # Don't default to build static libs.
88 AC_DISABLE_STATIC
89 AC_LIBTOOL_WIN32_DLL
90 AC_LIBTOOL_RC
91 AC_PROG_LIBTOOL
92
93 # For now we hardcode the use of version scripts.  It would be better
94 # to write a test for this or even implement this within libtool.
95 have_ld_version_script=no
96 case "${host}" in
97     *-*-linux*)
98         have_ld_version_script=yes
99         ;;
100     *-*-gnu*)
101         have_ld_version_script=yes
102         ;;
103 esac
104 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
105
106 GPG_DEFAULT=no
107 GPGSM_DEFAULT=no
108 component_system=None
109 have_dosish_system=no
110 have_w32_system=no
111 case "${host}" in
112     *-mingw32*)
113         # special stuff for Windoze NT
114         have_dosish_system=yes
115         have_w32_system=yes
116         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
117         # XXX Assuan is not supported in this configuration.
118         #GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
119         #component_system='COM+'
120         ;;
121     *)
122         AC_CHECK_PTH(1.2.0,,,no,have_pth=yes)
123         if test "$have_pth" = yes; then
124           AC_DEFINE(HAVE_PTH, ,[Define if we have Pth.])
125         fi
126         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
127         if test "$have_pthread" = yes; then
128           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
129         fi
130
131         # XXX: Probably use exec-prefix here?
132 #       GPG_DEFAULT='/usr/bin/gpg'
133 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
134         ;;
135 esac
136
137 if test "$have_dosish_system" = yes; then
138    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
139              [Defined if we run on some of the PCDOS like systems 
140               (DOS, Windoze. OS/2) with special properties like
141               no file modes])
142 fi
143 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
144
145 if test "$have_w32_system" = yes; then
146    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
147 fi
148 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
149
150 build_w32_glib=no
151 AM_PATH_GLIB_2_0
152 AC_ARG_ENABLE(w32-glib,
153             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
154             build_w32_glib=$withval)
155 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
156
157 AM_CONDITIONAL(HAVE_PTH, test "$have_pth" = "yes")
158 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
159
160
161 # Checks for header files.
162 AC_CHECK_HEADERS(sys/select.h)
163
164
165 # Type checks.
166 AC_CHECK_SIZEOF(unsigned int)
167 AC_SYS_LARGEFILE
168 AC_TYPE_OFF_T
169
170 # Checks for compiler features.
171 if test "$GCC" = yes; then
172     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
173     if test "$have_w32_system" = yes; then
174        CFLAGS="$CFLAGS -mms-bitfields"
175     fi
176 fi
177
178
179 # Checks for library functions.
180 AC_FUNC_FSEEKO
181
182 AC_CHECK_FUNCS(stpcpy)
183
184 AC_REPLACE_FUNCS(vasprintf)
185 if test "$ac_cv_func_vasprintf" != yes; then
186   GNUPG_CHECK_VA_COPY
187 fi
188
189 # Try to find a thread-safe version of ttyname().
190 AC_REPLACE_FUNCS(ttyname_r)
191 if test "$ac_cv_func_ttyname_r" != yes; then
192   AC_MSG_WARN([
193 ***
194 *** ttyname() is not thread-safe and ttyname_r() does not exist
195 ***])
196 fi
197
198 # Try to find a thread-safe version of getenv().
199 have_thread_safe_getenv=no
200 jm_GLIBC21
201 if test $GLIBC21 = yes; then
202   have_thread_safe_getenv=yes
203 fi
204 if test $have_thread_safe_getenv = yes; then
205   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
206 fi
207 have_getenv_r=no
208 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
209 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
210   AC_MSG_WARN([
211 ***
212 *** getenv() is not thread-safe and getenv_r() does not exist
213 ***])
214 fi
215
216 # For converting time strings to seconds since Epoch, we need the timegm
217 # function.
218 AC_CHECK_FUNCS(timegm)
219 if test "$ac_cv_func_timegm" != yes; then
220   AC_MSG_WARN([
221 ***
222 *** timegm() not available - a non-thread-safe kludge will be used
223 *** and the TZ variable might be changed at runtime.
224 ***])
225 fi
226
227 # Checking for libgpg-error.
228 AM_PATH_GPG_ERROR(0.5,, AC_MSG_ERROR([libgpg-error was not found]))
229 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
230           [The default error source for GPGME.])
231
232
233
234 # Checks for system services
235 NO_OVERRIDE=no
236 AC_ARG_WITH(gpg,
237             AC_HELP_STRING([--with-gpg=PATH], [use GnuPG binary at PATH]),
238             GPG=$withval, NO_OVERRIDE=yes)
239 if test "$NO_OVERRIDE" = "yes" || test "$GPG" = "yes"; then
240   GPG=
241   NO_OVERRIDE=yes
242   if test "$cross_compiling" != "yes"; then
243     AC_PATH_PROG(GPG, gpg)
244   fi
245   if test -z "$GPG"; then
246     GPG="$GPG_DEFAULT"
247   fi
248 fi
249 if test "$GPG" = no; then
250   if test "$NO_OVERRIDE" = "yes"; then
251     if test "$cross_compiling" != "yes"; then
252       AC_MSG_WARN([
253 ***
254 *** Could not find GnuPG, install GnuPG or use --with-gpg=PATH to enable it
255 ***])
256     else
257       AC_MSG_ERROR([
258 ***
259 *** Can not determine path to GnuPG when cross-compiling, use --with-gpg=PATH
260 ***])
261     fi
262   fi
263 else
264   AC_DEFINE_UNQUOTED(GPG_PATH, "$GPG", [Path to the GnuPG binary.])
265   AC_SUBST(GPG)
266 fi
267 dnl Check for GnuPG version requirement.
268 GPG_VERSION=unknown
269 ok=maybe
270 if test -z "$GPG" -o "x$GPG" = "xno"; then
271   ok=no
272 else
273   if test "$cross_compiling" = "yes"; then
274     AC_MSG_WARN([GnuPG version can not be checked when cross compiling])
275     ok=no
276   else
277     if test ! -x "$GPG"; then
278       AC_MSG_WARN([GnuPG not executable, version check disabled])
279       ok=no
280     fi
281   fi
282 fi
283 if test "$ok" = "maybe"; then
284   AC_MSG_CHECKING(for GnuPG >= $NEED_GPG_VERSION)
285   req_major=`echo $NEED_GPG_VERSION | \
286              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
287   req_minor=`echo $NEED_GPG_VERSION | \
288              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
289   req_micro=`echo $NEED_GPG_VERSION | \
290              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
291   gpg_version=`$GPG --version | grep ^gpg`
292   major=`echo $gpg_version | \
293          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
294   minor=`echo $gpg_version | \
295          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
296   micro=`echo $gpg_version | \
297          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
298   GPG_VERSION=`echo $gpg_version | sed 's/^gpg (GnuPG) //'`
299
300   if test "$major" -gt "$req_major"; then
301     ok=yes
302   else
303     if test "$major" -eq "$req_major"; then
304       if test "$minor" -gt "$req_minor"; then
305         ok=yes
306       else
307         if test "$minor" -eq "$req_minor"; then
308           if test "$micro" -ge "$req_micro"; then
309             ok=yes
310           fi
311         fi
312       fi
313     fi
314   fi
315   if test "$ok" = "yes"; then
316     AC_MSG_RESULT(yes)
317   else
318     AC_MSG_RESULT(no)
319     AC_MSG_WARN([GnuPG must be at least version $NEED_GPG_VERSION])
320   fi
321 fi
322 AM_CONDITIONAL(RUN_GPG_TESTS, test "$ok" = "yes")
323 AC_SUBST(GPG_PATH)
324
325 NO_OVERRIDE=no
326 AC_ARG_WITH(gpgsm,
327             AC_HELP_STRING([--with-gpgsm=PATH], [use GpgSM binary at PATH]),
328             GPGSM=$withval, NO_OVERRIDE=yes)
329 if test "$NO_OVERRIDE" = "yes" || test "$GPGSM" = "yes"; then
330   GPGSM=
331   NO_OVERRIDE=yes
332   if test "$cross_compiling" != "yes"; then
333     AC_PATH_PROG(GPGSM, gpgsm)
334   fi
335   if test -z "$GPGSM"; then
336     GPGSM="$GPGSM_DEFAULT"
337   fi
338 fi
339 if test "$GPGSM" = no; then
340   if test "$NO_OVERRIDE" = "yes"; then
341     if test "$cross_compiling" != "yes"; then
342       AC_MSG_WARN([
343 ***
344 *** Could not find GpgSM, install GpgSM or use --with-gpgsm=PATH to enable it
345 ***])
346     else
347       AC_MSG_ERROR([
348 ***
349 *** Can not determine path to GpgSM when cross-compiling, use --with-gpgsm=PATH
350 ***])
351     fi
352   fi
353 else
354   AC_DEFINE_UNQUOTED(GPGSM_PATH, "$GPGSM", [Path to the GPGSM binary.])
355   AC_DEFINE(ENABLE_GPGSM,1,[Whether GPGSM support is enabled])
356 fi
357 AM_CONDITIONAL(HAVE_GPGSM, test "$GPGSM" != "no")
358
359
360 dnl Check for GPGSM version requirement.
361 GPGSM_VERSION=unknown
362 ok=maybe
363 if test -z "$GPGSM" -o "x$GPGSM" = "xno"; then
364   ok=no
365 else
366   if test "$cross_compiling" = "yes"; then
367     AC_MSG_WARN([GPGSM version can not be checked when cross compiling])
368     ok=no
369   else
370     if test ! -x "$GPGSM"; then
371       AC_MSG_WARN([GPGSM not executable, version check disabled])
372       ok=no
373     fi
374   fi
375 fi
376 if test "$ok" = "maybe"; then
377   AC_MSG_CHECKING(for GPGSM >= $NEED_GPGSM_VERSION)
378   req_major=`echo $NEED_GPGSM_VERSION | \
379              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
380   req_minor=`echo $NEED_GPGSM_VERSION | \
381              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
382   req_micro=`echo $NEED_GPGSM_VERSION | \
383              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
384   gpgsm_version=`$GPGSM --version | grep ^gpgsm`
385   major=`echo $gpgsm_version | \
386          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
387   minor=`echo $gpgsm_version | \
388          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
389   micro=`echo $gpgsm_version | \
390          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
391   GPGSM_VERSION=`echo $gpgsm_version | sed 's/^gpgsm (GnuPG) //'`
392
393   if test "$major" -gt "$req_major"; then
394     ok=yes
395   else
396     if test "$major" -eq "$req_major"; then
397       if test "$minor" -gt "$req_minor"; then
398         ok=yes
399       else
400         if test "$minor" -eq "$req_minor"; then
401           if test "$micro" -ge "$req_micro"; then
402             ok=yes
403           fi
404         fi
405       fi
406     fi
407   fi
408   if test "$ok" = "yes"; then
409     AC_MSG_RESULT(yes)
410   else
411     AC_MSG_RESULT(no)
412     AC_MSG_WARN([GPGSM must be at least version $NEED_GPGSM_VERSION])
413   fi
414 fi
415 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$ok" = "yes")
416
417 # FIXME: Only build if supported.
418 AM_CONDITIONAL(BUILD_ASSUAN, test "$GPGSM" != "no")
419
420
421 # The assuan code uses funopen but it will also build without it.  So
422 # test for it.  Frankly, this is not required in gpgme, but thats the
423 # way we handle it in libassuan.
424 AC_CHECK_FUNCS(funopen)
425 if test $ac_cv_func_funopen != yes; then
426     # No funopen but we can implement that in terms of fopencookie.
427     AC_CHECK_FUNCS(fopencookie)
428     if test $ac_cv_func_fopencookie = yes; then
429         AC_LIBOBJ([funopen])
430     else
431         AC_MSG_WARN([
432 ***
433 *** No implementation of fopencookie or funopen available
434 ***])
435     fi
436 fi
437
438 # More assuan replacement functions.
439 AC_REPLACE_FUNCS(isascii)
440 AC_REPLACE_FUNCS(putc_unlocked)
441 AC_REPLACE_FUNCS(memrchr)
442
443 # More assuan checks.
444 AC_CHECK_HEADERS([sys/uio.h])
445
446 # End of assuan checks.
447
448 AM_CONDITIONAL(BUILD_COMPLUS, test "$component_system" = "COM+")
449
450 # Make the version number in gpgme/gpgme.h the same as the one here.
451 # (this is easier than to have a *.in file just for one substitution)
452 GNUPG_FIX_HDR_VERSION(gpgme/gpgme.h, GPGME_VERSION)
453
454 # Generate values for the DLL version info
455 changequote(,)dnl 
456 BUILD_REVISION="`echo '$Revision$' | sed 's/[^0-9]//g'`"
457 changequote([,])dnl
458 test -z "$BUILD_REVISION" && BUILD_REVISION="0"
459 if test "$have_w32_system" = yes; then
460     BUILD_TIMESTAMP=`date --iso-8601=minutes`
461     changequote(,)dnl 
462     BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
463     changequote([,])dnl
464     BUILD_FILEVERSION="${BUILD_FILEVERSION}${BUILD_REVISION}"
465 fi
466 AC_SUBST(BUILD_REVISION)
467 AC_SUBST(BUILD_TIMESTAMP)
468 AC_SUBST(BUILD_FILEVERSION)
469
470 # Add a few constants to help porting to W32
471 AH_VERBATIM([SEPCONSTANTS],
472 [
473 /* Separators as used in file names and $PATH. Please note that the
474    string version must not contain more than one character because
475    the using code assumes strlen()==1 */
476 #ifdef HAVE_DOSISH_SYSTEM
477 #define DIRSEP_C '\\\\'
478 #define EXTSEP_C '.'
479 #define DIRSEP_S "\\\\"
480 #define EXTSEP_S "."
481 #define PATHSEP_C ';'
482 #define PATHSEP_S ";"
483 #else
484 #define DIRSEP_C '/'
485 #define EXTSEP_C '.'
486 #define DIRSEP_S "/"
487 #define EXTSEP_S "."
488 #define PATHSEP_C ':'
489 #define PATHSEP_S ":"
490 #endif
491 ])
492
493
494 # Substitution used for gpgme-config 
495 GPGME_CONFIG_LIBS="-lgpgme"
496 GPGME_CONFIG_CFLAGS=""
497 AC_SUBST(GPGME_CONFIG_API_VERSION)
498 AC_SUBST(GPGME_CONFIG_LIBS)
499 AC_SUBST(GPGME_CONFIG_CFLAGS)
500
501 # Frob'da Variables
502 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
503            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
504 AC_SUBST(LTLIBOBJS)
505
506 #
507 # Create config files 
508
509 AC_CONFIG_FILES(Makefile assuan/Makefile gpgme/Makefile
510                 tests/Makefile tests/gpg/Makefile tests/gpgsm/Makefile
511                 doc/Makefile complus/Makefile
512                 gpgme/versioninfo.rc)
513 AC_CONFIG_FILES(gpgme/gpgme-config, chmod +x gpgme/gpgme-config)
514 AC_OUTPUT
515
516 echo "
517         GPGME v${VERSION} has been configured as follows:
518
519         GnuPG path:    $GPG
520         GnuPG version: $GPG_VERSION, min. $NEED_GPG_VERSION
521
522         GpgSM path:    $GPGSM
523         GpgSM version: $GPGSM_VERSION, min. $NEED_GPGSM_VERSION
524
525         GPGME Pthread: $have_pthread
526         GPGME Pth:     $have_pth
527 "