Add Albrecht Dre´┐Ż <albrecht.dress@arcor.de>, because he was helpful.
[gpgme.git] / configure.ac
1 # configure.in for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004 g10 Code GmbH
4
5 # This file is part of GPGME.
6
7 # GPGME is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # GPGME is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20  
21 # (Process this file with autoconf to produce a configure script.)
22
23 AC_PREREQ(2.57)
24 min_automake_version="1.7.6"
25
26 # Version number: Remember to change it immediately *after* a release.
27 AC_INIT(gpgme, 0.4.7-cvs, [bug-gpgme@gnupg.org])
28 # LT Version numbers, remember to change them just *before* a release.
29 #   (Code changed:                      REVISION++)
30 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
31 #   (Interfaces added:                  AGE++)
32 #   (Interfaces removed/changed:        AGE=0)
33 #
34 LIBGPGME_LT_CURRENT=13
35 # Subtract 2 from this value if you want to make the LFS transition an
36 # ABI break.  [Note to self: Remove this comment with the next regular break.]
37 LIBGPGME_LT_AGE=2
38 LIBGPGME_LT_REVISION=1
39 NEED_GPG_VERSION=1.2.2
40 NEED_GPGSM_VERSION=1.9.6
41 ##############################################
42 AC_PREREQ(2.52)
43 AC_REVISION($Revision$)
44
45 PACKAGE=$PACKAGE_NAME
46 VERSION=$PACKAGE_VERSION
47
48 AC_CONFIG_SRCDIR(gpgme/gpgme.h)
49 AM_CONFIG_HEADER(config.h)
50 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
51 AM_MAINTAINER_MODE
52 AC_CANONICAL_HOST
53
54 AH_VERBATIM([_GNU_SOURCE],
55 [/* Enable GNU extensions on systems that have them.  */
56 #ifndef _GNU_SOURCE
57 # define _GNU_SOURCE
58 #endif])
59
60 AH_VERBATIM([_REENTRANT],
61 [/* To allow the use of GPGME in multithreaded programs we have to use
62   special features from the library.
63   IMPORTANT: gpgme is not yet fully reentrant and you should use it
64   only from one thread.  */
65 #ifndef _REENTRANT
66 # define _REENTRANT 1
67 #endif])
68
69
70 AC_PROG_CC
71
72
73 AC_SUBST(LIBGPGME_LT_CURRENT)
74 AC_SUBST(LIBGPGME_LT_AGE)
75 AC_SUBST(LIBGPGME_LT_REVISION)
76 AC_DEFINE_UNQUOTED(NEED_GPG_VERSION, "$NEED_GPG_VERSION",
77                                      [Min. needed GnuPG version.])
78 AC_DEFINE_UNQUOTED(NEED_GPGSM_VERSION, "$NEED_GPGSM_VERSION",
79                                        [Min. needed GPGSM version.])
80
81 AC_SUBST(PACKAGE)
82 AC_SUBST(VERSION)
83 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
84 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
85
86 # Don't default to build static libs.
87 AC_DISABLE_STATIC
88 AC_PROG_LIBTOOL
89
90 # For now we hardcode the use of version scripts.  It would be better
91 # to write a test for this or even implement this within libtool.
92 have_ld_version_script=no
93 case "${host}" in
94     *-*-linux*)
95         have_ld_version_script=yes
96         ;;
97     *-*-gnu*)
98         have_ld_version_script=yes
99         ;;
100 esac
101 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
102
103 GPG_DEFAULT=no
104 GPGSM_DEFAULT=no
105 component_system=None
106 case "${host}" in
107     *-*-mingw32* | i?86-emx-os2 | i?86-*-os2*emx | i?86-*-msdosdjgpp* )
108         # special stuff for Windoze NT
109         # OS/2 with the EMX environment
110         # DOS with the DJGPP environment
111         AC_DEFINE(HAVE_DRIVE_LETTERS, ,
112                   [Defined if we run on some of the PCDOS like systems (DOS,
113                    Windoze, OS/2) with special properties like no file modes.])
114         AC_DEFINE(HAVE_DOSISH_SYSTEM, ,
115                   [Defined if the filesystem uses driver letters.])
116         have_dosish_system=yes
117         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
118         # XXX Assuan is not supported in this configuration.
119         #GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
120         #component_system='COM+'
121         ;;
122     *)
123         AC_CHECK_PTH(1.2.0,,,no,have_pth=yes)
124         if test "$have_pth" = yes; then
125           AC_DEFINE(HAVE_PTH, ,[Define if we have Pth.])
126           CFLAGS="$CFLAGS $PTH_CFLAGS"
127         fi
128         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
129         if test "$have_pthread" = yes; then
130           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
131         fi
132
133         # XXX: Probably use exec-prefix here?
134 #       GPG_DEFAULT='/usr/bin/gpg'
135 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
136         ;;
137 esac
138 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = "yes")
139 AM_CONDITIONAL(HAVE_PTH, test "$have_pth" = "yes")
140 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
141
142
143 # Checks for header files.
144 AC_CHECK_HEADERS(sys/select.h)
145
146
147 # Type checks.
148 AC_CHECK_SIZEOF(unsigned int)
149 AC_SYS_LARGEFILE
150 AC_TYPE_OFF_T
151
152 # Checks for compiler features.
153 if test "$GCC" = yes; then
154     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
155 fi
156
157
158 # Checks for library functions.
159 AC_FUNC_FSEEKO
160
161 AC_REPLACE_FUNCS(stpcpy)
162
163 AC_REPLACE_FUNCS(vasprintf)
164 if test "$ac_cv_func_vasprintf" != yes; then
165   GNUPG_CHECK_VA_COPY
166 fi
167
168 # Try to find a thread-safe version of getenv().
169 have_thread_safe_getenv=no
170 jm_GLIBC21
171 if test $GLIBC21 = yes; then
172   have_thread_safe_getenv=yes
173 fi
174 if test $have_thread_safe_getenv = yes; then
175   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
176 fi
177 have_getenv_r=no
178 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
179 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
180   AC_MSG_WARN([
181 ***
182 *** getenv() is not thread-safe and getenv_r() does not exist
183 ***])
184 fi
185
186 # For converting time strings to seconds since Epoch, we need the timegm
187 # function.
188 AC_CHECK_FUNCS(timegm)
189 if test "$ac_cv_func_timegm" != yes; then
190   AC_MSG_WARN([
191 ***
192 *** timegm() not available - a non-thread-safe kludge will be used
193 *** and the TZ variable might be changed at runtime.
194 ***])
195 fi
196
197 # Checking for libgpg-error.
198 AM_PATH_GPG_ERROR(0.5,, AC_MSG_ERROR([libgpg-error was not found]))
199 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
200           [The default error source for GPGME.])
201
202
203
204 # Checks for system services
205 NO_OVERRIDE=no
206 AC_ARG_WITH(gpg,
207             AC_HELP_STRING([--with-gpg=PATH], [use GnuPG binary at PATH]),
208             GPG=$withval, NO_OVERRIDE=yes)
209 if test "$NO_OVERRIDE" = "yes" || test "$GPG" = "yes"; then
210   GPG=
211   NO_OVERRIDE=yes
212   if test "$cross_compiling" != "yes"; then
213     AC_PATH_PROG(GPG, gpg)
214   fi
215   if test -z "$GPG"; then
216     GPG="$GPG_DEFAULT"
217   fi
218 fi
219 if test "$GPG" = no; then
220   if test "$NO_OVERRIDE" = "yes"; then
221     if test "$cross_compiling" != "yes"; then
222       AC_MSG_WARN([
223 ***
224 *** Could not find GnuPG, install GnuPG or use --with-gpg=PATH to enable it
225 ***])
226     else
227       AC_MSG_ERROR([
228 ***
229 *** Can not determine path to GnuPG when cross-compiling, use --with-gpg=PATH
230 ***])
231     fi
232   fi
233 else
234   AC_DEFINE_UNQUOTED(GPG_PATH, "$GPG", [Path to the GnuPG binary.])
235   AC_SUBST(GPG)
236 fi
237 AM_CONDITIONAL(RUN_GPG_TESTS,
238   [test "$cross_compiling" != "yes" && test -n "$GPG" && test -r "$GPG"])
239 AC_SUBST(GPG_PATH)
240
241 NO_OVERRIDE=no
242 AC_ARG_WITH(gpgsm,
243             AC_HELP_STRING([--with-gpgsm=PATH], [use GpgSM binary at PATH]),
244             GPGSM=$withval, NO_OVERRIDE=yes)
245 if test "$NO_OVERRIDE" = "yes" || test "$GPGSM" = "yes"; then
246   GPGSM=
247   NO_OVERRIDE=yes
248   if test "$cross_compiling" != "yes"; then
249     AC_PATH_PROG(GPGSM, gpgsm)
250   fi
251   if test -z "$GPGSM"; then
252     GPGSM="$GPGSM_DEFAULT"
253   fi
254 fi
255 if test "$GPGSM" = no; then
256   if test "$NO_OVERRIDE" = "yes"; then
257     if test "$cross_compiling" != "yes"; then
258       AC_MSG_WARN([
259 ***
260 *** Could not find GpgSM, install GpgSM or use --with-gpgsm=PATH to enable it
261 ***])
262     else
263       AC_MSG_ERROR([
264 ***
265 *** Can not determine path to GpgSM when cross-compiling, use --with-gpgsm=PATH
266 ***])
267     fi
268   fi
269 else
270   AC_DEFINE_UNQUOTED(GPGSM_PATH, "$GPGSM", [Path to the GPGSM binary.])
271   AC_SUBST(GPGSM)
272 fi
273 AM_CONDITIONAL(HAVE_GPGSM, [test -n "$GPGSM" && test -r "$GPGSM"])
274 AM_CONDITIONAL(RUN_GPGSM_TESTS,
275   [test "$cross_compiling" != "yes" && test -n "$GPGSM" && test -r "$GPGSM"])
276
277 # FIXME: Only build if supported.
278 AM_CONDITIONAL(BUILD_ASSUAN, test "$GPGSM" != "no")
279
280
281 # The assuan code uses funopen but it will also build without it.  So
282 # test for it.  Frankly, this is not required in gpgme, but thats the
283 # way we handle it in libassuan.
284 AC_CHECK_FUNCS(funopen)
285 if test $ac_cv_func_funopen != yes; then
286     # No funopen but we can implement that in terms of fopencookie.
287     AC_CHECK_FUNCS(fopencookie)
288     if test $ac_cv_func_fopencookie = yes; then
289         AC_LIBOBJ([funopen])
290     else
291         AC_MSG_WARN([
292 ***
293 *** No implementation of fopencookie or funopen available
294 ***])
295     fi
296 fi
297
298 AC_REPLACE_FUNCS(isascii)
299 AC_REPLACE_FUNCS(putc_unlocked)
300 AC_REPLACE_FUNCS(memrchr)
301
302
303 AM_CONDITIONAL(BUILD_COMPLUS, test "$component_system" = "COM+")
304
305 # Make the version number in gpgme/gpgme.h the same as the one here.
306 # (this is easier than to have a *.in file just for one substitution)
307 GNUPG_FIX_HDR_VERSION(gpgme/gpgme.h, GPGME_VERSION)
308
309 # Substitution used for gpgme-config 
310 GPGME_CONFIG_LIBS="-lgpgme"
311 GPGME_CONFIG_CFLAGS=""
312 AC_SUBST(GPGME_CONFIG_LIBS)
313 AC_SUBST(GPGME_CONFIG_CFLAGS)
314
315 # Frob'da Variables
316 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
317            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
318 AC_SUBST(LTLIBOBJS)
319
320 #
321 # Create config files 
322
323 AC_CONFIG_FILES(Makefile assuan/Makefile gpgme/Makefile
324                 tests/Makefile tests/gpg/Makefile tests/gpgsm/Makefile
325                 doc/Makefile complus/Makefile)
326 AC_CONFIG_FILES(gpgme/gpgme-config, chmod +x gpgme/gpgme-config)
327 AC_OUTPUT
328
329 echo "
330         GPGME v${VERSION} has been configured as follows:
331
332         GnuPG version: min. $NEED_GPG_VERSION
333         GnuPG path:    $GPG
334
335         GpgSM version: min. $NEED_GPGSM_VERSION
336         GpgSM path:    $GPGSM
337 "