2007-09-07 Marcus Brinkmann <marcus@g10code.de>
[gpgme.git] / configure.ac
1 # configure.ac for GPGME
2 # Copyright (C) 2000 Werner Koch (dd9jn)
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007 g10 Code GmbH
4
5 # This file is part of GPGME.
6
7 # GPGME is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU Lesser General Public License as
9 # published by the Free Software Foundation; either version 2.1 of the
10 # License, or (at your option) any later version.
11
12 # GPGME is distributed in the hope that it will be useful, but WITHOUT
13 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
15 # Public License for more details.
16
17 # You should have received a copy of the GNU Lesser General Public
18 # License along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20  
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.59)
23 min_automake_version="1.9.3"
24
25 # Version number: Remember to change it immediately *after* a release.
26 #                 Make sure to run  "svn up" before a "make dist".
27 #                 See below for the LT versions.
28 #
29 # The CVS version is usually the next intended release version with
30 # the string "-cvs" appended.  The reason for this is that tests for a
31 # specific feature can already be done under the assumption that the
32 # CVS version is the most recent one in a branch.  To disable the CVS
33 # version for the real release, just comment out the my_iscvs macro.
34 # Note, that we are now using Subversion instead of CVS and append the
35 # SVN revision number to the "cvs" suffix.  To make this most useful
36 # for snapshot releases please do an "svn up" right before recreating
37 # the configure script, so that a proper revision number for all files
38 # is available when running a "make distcheck".
39 m4_define(my_version, [1.1.5])
40 m4_define(my_iscvs, yes)
41 AC_INIT([gpgme], my_version[]m4_ifdef([my_iscvs], [-cvs[]m4_translit(
42                [$Revision$],[Ra-z $:])]),
43                [bug-gpgme@gnupg.org])
44
45 # LT Version numbers, remember to change them just *before* a release.
46 #   (Code changed:                      REVISION++)
47 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
48 #   (Interfaces added:                  AGE++)
49 #   (Interfaces removed/changed:        AGE=0)
50 #
51 LIBGPGME_LT_CURRENT=17
52 # Subtract 2 from this value if you want to make the LFS transition an
53 # ABI break.  [Note to self: Remove this comment with the next regular break.]
54 LIBGPGME_LT_AGE=6
55 LIBGPGME_LT_REVISION=4
56
57 # If the API is changed in an incompatible way: increment the next counter.
58 GPGME_CONFIG_API_VERSION=1
59 ##############################################
60
61
62 PACKAGE=$PACKAGE_NAME
63 VERSION=$PACKAGE_VERSION
64
65 AC_CONFIG_SRCDIR(gpgme/gpgme.h)
66 dnl FIXME: Enable this with autoconf 2.59.
67 dnl AC_CONFIG_MACRO_DIR(m4)
68 AM_CONFIG_HEADER(config.h)
69 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
70 AM_MAINTAINER_MODE
71 AC_CANONICAL_HOST
72
73 # Enable GNU extensions on systems that have them.
74 AC_GNU_SOURCE
75
76 AH_VERBATIM([_REENTRANT],
77 [/* To allow the use of GPGME in multithreaded programs we have to use
78   special features from the library.
79   IMPORTANT: gpgme is not yet fully reentrant and you should use it
80   only from one thread.  */
81 #ifndef _REENTRANT
82 # define _REENTRANT 1
83 #endif])
84
85 AC_PROG_CC
86 AC_PROG_CXX
87
88 AC_SUBST(LIBGPGME_LT_CURRENT)
89 AC_SUBST(LIBGPGME_LT_AGE)
90 AC_SUBST(LIBGPGME_LT_REVISION)
91
92 AC_SUBST(PACKAGE)
93 AC_SUBST(VERSION)
94 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
95 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
96
97 # Don't default to build static libs.
98 AC_DISABLE_STATIC
99 AC_LIBTOOL_WIN32_DLL
100 AC_LIBTOOL_RC
101 AC_PROG_LIBTOOL
102
103 # For now we hardcode the use of version scripts.  It would be better
104 # to write a test for this or even implement this within libtool.
105 have_ld_version_script=no
106 case "${host}" in
107     *-*-linux*)
108         have_ld_version_script=yes
109         ;;
110     *-*-gnu*)
111         have_ld_version_script=yes
112         ;;
113 esac
114 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
115
116 GPG_DEFAULT=no
117 GPGSM_DEFAULT=no
118 component_system=None
119 have_dosish_system=no
120 have_w32_system=no
121 build_w32_glib=no
122 build_w32_qt=no
123 case "${host}" in
124     *-mingw32*)
125         # special stuff for Windoze NT
126         have_dosish_system=yes
127         have_w32_system=yes
128         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
129         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
130         #component_system='COM+'
131
132         AM_PATH_GLIB_2_0
133         AC_ARG_ENABLE(w32-glib,
134             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
135                            build_w32_glib=$enableval)
136
137         # Check disabled, because the qt-dev packages in gpg4win do
138         # not provide any support for cross compilation.
139         # PKG_CHECK_MODULES(QT4_CORE, QtCore)
140
141         # Use it like this:
142         # ./configure --enable-w32-qt QT4_CORE_CFLAGS="..." QT4_CORE_LIBS="..."
143         AC_SUBST(QT4_CORE_CFLAGS)
144         AC_SUBST(QT4_CORE_LIBS)
145         AC_ARG_ENABLE(w32-qt,
146             AC_HELP_STRING([--enable-w32-qt], [build GPGME Qt for W32]),
147                            build_w32_qt=$enableval)
148         ;;
149     *)
150         AC_CHECK_PTH(1.2.0,,,no,have_pth=yes)
151         if test "$have_pth" = yes; then
152           AC_DEFINE(HAVE_PTH, ,[Define if we have Pth.])
153         fi
154         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
155         if test "$have_pthread" = yes; then
156           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
157         fi
158
159         # XXX: Probably use exec-prefix here?
160 #       GPG_DEFAULT='/usr/bin/gpg'
161 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
162         ;;
163 esac
164
165 if test "$have_dosish_system" = yes; then
166    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
167              [Defined if we run on some of the PCDOS like systems 
168               (DOS, Windoze. OS/2) with special properties like
169               no file modes])
170 fi
171 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
172
173 if test "$have_w32_system" = yes; then
174    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
175 fi
176 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
177 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
178 AM_CONDITIONAL(BUILD_W32_QT, test "$build_w32_qt" = yes)
179
180 AM_CONDITIONAL(HAVE_PTH, test "$have_pth" = "yes")
181 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
182
183
184 # Checks for header files.
185 AC_CHECK_HEADERS(sys/select.h)
186
187
188 # Type checks.
189 AC_C_INLINE
190 AC_CHECK_SIZEOF(unsigned int)
191 AC_SYS_LARGEFILE
192 AC_TYPE_OFF_T
193
194 # Checks for compiler features.
195 if test "$GCC" = yes; then
196     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
197     if test "$have_w32_system" = yes; then
198        CFLAGS="$CFLAGS -mms-bitfields"
199     fi
200 fi
201
202 # Network library fun.
203 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
204         [NETLIBS="-lnsl $NETLIBS"]))
205 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
206         [NETLIBS="-lsocket $NETLIBS"]))
207 AC_SUBST(NETLIBS)
208
209 # Checks for library functions.
210 AC_FUNC_FSEEKO
211
212 AC_REPLACE_FUNCS(vasprintf)
213 if test "$ac_cv_func_vasprintf" != yes; then
214   GNUPG_CHECK_VA_COPY
215 fi
216
217 # Try to find a thread-safe version of ttyname().
218 AC_REPLACE_FUNCS(ttyname_r)
219 if test "$ac_cv_func_ttyname_r" != yes; then
220   AC_MSG_WARN([
221 ***
222 *** ttyname() is not thread-safe and ttyname_r() does not exist
223 ***])
224 fi
225
226 # Try to find a thread-safe version of getenv().
227 have_thread_safe_getenv=no
228 jm_GLIBC21
229 if test $GLIBC21 = yes; then
230   have_thread_safe_getenv=yes
231 fi
232 if test $have_thread_safe_getenv = yes; then
233   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
234 fi
235 have_getenv_r=no
236 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
237 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
238   AC_MSG_WARN([
239 ***
240 *** getenv() is not thread-safe and getenv_r() does not exist
241 ***])
242 fi
243
244 # For converting time strings to seconds since Epoch, we need the timegm
245 # function.
246 AC_CHECK_FUNCS(timegm)
247 if test "$ac_cv_func_timegm" != yes; then
248   AC_MSG_WARN([
249 ***
250 *** timegm() not available - a non-thread-safe kludge will be used
251 *** and the TZ variable might be changed at runtime.
252 ***])
253 fi
254
255 # Checking for libgpg-error.
256 AM_PATH_GPG_ERROR(1.4,, AC_MSG_ERROR([libgpg-error was not found]))
257 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
258           [The default error source for GPGME.])
259
260
261
262 # Checks for system services
263 NEED_GPG_VERSION_DEFAULT=1.3.0
264 NEED_GPGSM_VERSION_DEFAULT=1.9.6
265 NEED_GPG_VERSION="$NEED_GPG_VERSION_DEFAULT"
266 NEED_GPGSM_VERSION="$NEED_GPGSM_VERSION_DEFAULT"
267 AC_ARG_WITH(gpg-version,
268             AC_HELP_STRING([--with-gpg-version=VER], [require GnuPG version VER]),
269             NEED_GPG_VERSION=$withval)
270 if test "$NEED_GPG_VERSION" = "yes"; then
271   NEED_GPG_VERSION="$NEED_GPG_VERSION_DEFAULT"
272 fi
273 if test "$NEED_GPG_VERSION" = "no"; then
274   NEED_GPG_VERSION=0.0.0
275 fi
276 AC_ARG_WITH(gpgsm-version,
277             AC_HELP_STRING([--with-gpgsm-version=VER], [require GPGSM version VER]),
278             NEED_GPGSM_VERSION=$withval)
279 if test "$NEED_GPGSM_VERSION" = "yes"; then
280   NEED_GPGSM_VERSION="$NEED_GPGSM_VERSION_DEFAULT"
281 fi
282 if test "$NEED_GPGSM_VERSION" = "no"; then
283   NEED_GPGSM_VERSION=0.0.0
284 fi
285
286 AC_DEFINE_UNQUOTED(NEED_GPG_VERSION, "$NEED_GPG_VERSION",
287                                      [Min. needed GnuPG version.])
288 AC_DEFINE_UNQUOTED(NEED_GPGSM_VERSION, "$NEED_GPGSM_VERSION",
289                                        [Min. needed GPGSM version.])
290
291
292 NO_OVERRIDE=no
293 AC_ARG_WITH(gpg,
294             AC_HELP_STRING([--with-gpg=PATH], [use GnuPG binary at PATH]),
295             GPG=$withval, NO_OVERRIDE=yes)
296 if test "$NO_OVERRIDE" = "yes" || test "$GPG" = "yes"; then
297   GPG=
298   NO_OVERRIDE=yes
299   if test "$cross_compiling" != "yes"; then
300     AC_PATH_PROG(GPG, gpg)
301   fi
302   if test -z "$GPG"; then
303     GPG="$GPG_DEFAULT"
304   fi
305 fi
306 if test "$GPG" = no; then
307   if test "$NO_OVERRIDE" = "yes"; then
308     if test "$cross_compiling" != "yes"; then
309       AC_MSG_WARN([
310 ***
311 *** Could not find GnuPG, install GnuPG or use --with-gpg=PATH to enable it
312 ***])
313     else
314       AC_MSG_ERROR([
315 ***
316 *** Can not determine path to GnuPG when cross-compiling, use --with-gpg=PATH
317 ***])
318     fi
319   fi
320 else
321   AC_DEFINE_UNQUOTED(GPG_PATH, "$GPG", [Path to the GnuPG binary.])
322   AC_SUBST(GPG)
323 fi
324 dnl Check for GnuPG version requirement.
325 GPG_VERSION=unknown
326 ok=maybe
327 if test -z "$GPG" -o "x$GPG" = "xno"; then
328   ok=no
329 else
330   if test "$cross_compiling" = "yes"; then
331     AC_MSG_WARN([GnuPG version can not be checked when cross compiling])
332     ok=no
333   else
334     if test ! -x "$GPG"; then
335       AC_MSG_WARN([GnuPG not executable, version check disabled])
336       ok=no
337     fi
338   fi
339 fi
340 if test "$ok" = "maybe"; then
341   AC_MSG_CHECKING(for GPG >= $NEED_GPG_VERSION)
342   req_major=`echo $NEED_GPG_VERSION | \
343              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
344   req_minor=`echo $NEED_GPG_VERSION | \
345              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
346   req_micro=`echo $NEED_GPG_VERSION | \
347              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
348   GPG_VERSION=`$GPG --version | sed -n '1 s/[[^0-9]]*\(.*\)/\1/p'`
349   major=`echo $GPG_VERSION | \
350          sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
351   minor=`echo $GPG_VERSION | \
352          sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
353   micro=`echo $GPG_VERSION | \
354          sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
355
356   if test "$major" -gt "$req_major"; then
357     ok=yes
358   else
359     if test "$major" -eq "$req_major"; then
360       if test "$minor" -gt "$req_minor"; then
361         ok=yes
362       else
363         if test "$minor" -eq "$req_minor"; then
364           if test "$micro" -ge "$req_micro"; then
365             ok=yes
366           fi
367         fi
368       fi
369     fi
370   fi
371   if test "$ok" = "yes"; then
372     AC_MSG_RESULT(yes)
373   else
374     AC_MSG_RESULT(no)
375     AC_MSG_WARN([GPG must be at least version $NEED_GPG_VERSION])
376   fi
377 fi
378 run_gpg_test="$ok"
379 AC_ARG_ENABLE(gpg-test,
380   AC_HELP_STRING([--disable-gpg-test], [disable GPG run test]),
381          run_gpg_test=$enableval)
382 AM_CONDITIONAL(RUN_GPG_TESTS, test "$run_gpg_test" = "yes")
383 AC_SUBST(GPG_PATH)
384
385 NO_OVERRIDE=no
386 AC_ARG_WITH(gpgsm,
387             AC_HELP_STRING([--with-gpgsm=PATH], [use GpgSM binary at PATH]),
388             GPGSM=$withval, NO_OVERRIDE=yes)
389 if test "$NO_OVERRIDE" = "yes" || test "$GPGSM" = "yes"; then
390   GPGSM=
391   NO_OVERRIDE=yes
392   if test "$cross_compiling" != "yes"; then
393     AC_PATH_PROG(GPGSM, gpgsm)
394   fi
395   if test -z "$GPGSM"; then
396     GPGSM="$GPGSM_DEFAULT"
397   fi
398 fi
399 if test "$GPGSM" = no; then
400   if test "$NO_OVERRIDE" = "yes"; then
401     if test "$cross_compiling" != "yes"; then
402       AC_MSG_WARN([
403 ***
404 *** Could not find GpgSM, install GpgSM or use --with-gpgsm=PATH to enable it
405 ***])
406     else
407       AC_MSG_ERROR([
408 ***
409 *** Can not determine path to GpgSM when cross-compiling, use --with-gpgsm=PATH
410 ***])
411     fi
412   fi
413 else
414   AC_DEFINE_UNQUOTED(GPGSM_PATH, "$GPGSM", [Path to the GPGSM binary.])
415   AC_DEFINE(ENABLE_GPGSM,1,[Whether GPGSM support is enabled])
416 fi
417 AM_CONDITIONAL(HAVE_GPGSM, test "$GPGSM" != "no")
418
419
420 dnl Check for GPGSM version requirement.
421 GPGSM_VERSION=unknown
422 ok=maybe
423 if test -z "$GPGSM" -o "x$GPGSM" = "xno"; then
424   ok=no
425 else
426   if test "$cross_compiling" = "yes"; then
427     AC_MSG_WARN([GPGSM version can not be checked when cross compiling])
428     ok=no
429   else
430     if test ! -x "$GPGSM"; then
431       AC_MSG_WARN([GPGSM not executable, version check disabled])
432       ok=no
433     fi
434   fi
435 fi
436 if test "$ok" = "maybe"; then
437   AC_MSG_CHECKING(for GPGSM >= $NEED_GPGSM_VERSION)
438   req_major=`echo $NEED_GPGSM_VERSION | \
439              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
440   req_minor=`echo $NEED_GPGSM_VERSION | \
441              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
442   req_micro=`echo $NEED_GPGSM_VERSION | \
443              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
444   GPGSM_VERSION=`$GPGSM --version | sed -n '1 s/[[^0-9]]*\(.*\)/\1/p'`
445   major=`echo $GPGSM_VERSION | \
446          sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
447   minor=`echo $GPGSM_VERSION | \
448          sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
449   micro=`echo $GPGSM_VERSION | \
450          sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
451
452   if test "$major" -gt "$req_major"; then
453     ok=yes
454   else
455     if test "$major" -eq "$req_major"; then
456       if test "$minor" -gt "$req_minor"; then
457         ok=yes
458       else
459         if test "$minor" -eq "$req_minor"; then
460           if test "$micro" -ge "$req_micro"; then
461             ok=yes
462           fi
463         fi
464       fi
465     fi
466   fi
467   if test "$ok" = "yes"; then
468     AC_MSG_RESULT(yes)
469   else
470     AC_MSG_RESULT(no)
471     AC_MSG_WARN([GPGSM must be at least version $NEED_GPGSM_VERSION])
472   fi
473 fi
474 run_gpgsm_test="$ok"
475 AC_ARG_ENABLE(gpgsm-test,
476   AC_HELP_STRING([--disable-gpgsm-test], [disable GPGSM run test]),
477          run_gpgsm_test=$enableval)
478 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$run_gpgsm_test" = "yes")
479
480
481 # FIXME: Only build if supported.
482 AM_CONDITIONAL(BUILD_ASSUAN, test "$GPGSM" != "no")
483 if test "$GPGSM" != "no"; then
484   AC_DEFINE(HAVE_ASSUAN_H, 1,
485             [Defined if we are building with assuan support.])
486 fi
487
488 # Check for funopen
489 AC_CHECK_FUNCS(funopen)
490 if test $ac_cv_func_funopen != yes; then
491     # No funopen but we can implement that in terms of fopencookie.
492     AC_CHECK_FUNCS(fopencookie)
493     if test $ac_cv_func_fopencookie = yes; then
494         AC_REPLACE_FUNCS(funopen)
495     else
496         AC_MSG_WARN([
497 ***
498 *** No implementation of fopencookie or funopen available
499 ***])
500     fi
501 fi
502
503 # More assuan replacement functions.
504 AC_REPLACE_FUNCS(isascii)
505 AC_REPLACE_FUNCS(putc_unlocked)
506 AC_REPLACE_FUNCS(memrchr)
507 AC_REPLACE_FUNCS(stpcpy)
508 # Check for unistd.h for setenv replacement function.
509 AC_CHECK_HEADERS(unistd.h)
510 AC_REPLACE_FUNCS(setenv)
511
512 # More assuan checks.
513 AC_CHECK_HEADERS([sys/uio.h])
514
515 # Assuan check for descriptor passing.
516 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
517                 [supports_descriptor_passing=yes],
518                 [supports_descriptor_passing=no
519                  AC_MSG_WARN([
520 ***
521 *** Data structure for sending ancillary data missing.
522 *** Descriptor passing won't work.
523 ***])],[
524 #include <stdlib.h>
525 #include <stddef.h>
526 #include <stdio.h>
527 #include <sys/types.h>
528 #include <sys/socket.h>
529 #include <sys/un.h>
530 #if HAVE_SYS_UIO_H
531 #include <sys/uio.h>
532 #endif
533 #include <unistd.h>
534        ])
535
536 AC_ARG_ENABLE(fd-passing,
537   AC_HELP_STRING([--enable-fd-passing], [use FD passing if supported]),
538   use_descriptor_passing=$enableval)
539
540 if test "$supports_descriptor_passing" != "yes"; then
541   use_descriptor_passing=no
542 fi
543
544 if test "$use_descriptor_passing" = "yes"; then
545 AC_DEFINE(USE_DESCRIPTOR_PASSING,1,
546           [Defined if descriptor passing is enabled and supported])
547 fi
548
549 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
550
551 # Assuan check for the getsockopt SO_PEERCRED
552 AC_MSG_CHECKING(for SO_PEERCRED)
553 AC_CACHE_VAL(assuan_cv_sys_so_peercred,
554       [AC_TRY_COMPILE([#include <sys/socket.h>], 
555          [struct ucred cr; 
556           int cl = sizeof cr;
557           getsockopt (1, SOL_SOCKET, SO_PEERCRED, &cr, &cl);],
558           assuan_cv_sys_so_peercred=yes,
559           assuan_cv_sys_so_peercred=no)
560        ])
561 AC_MSG_RESULT($assuan_cv_sys_so_peercred) 
562 if test $assuan_cv_sys_so_peercred = yes; then
563   AC_DEFINE(HAVE_SO_PEERCRED, 1,
564             [Defined if SO_PEERCRED is supported (Linux specific)])
565 fi
566
567 if test "$have_w32_system" = yes; then
568    NETLIBS="-lws2_32 $NETLIBS"
569 fi
570
571 # End of assuan checks.
572
573 AM_CONDITIONAL(BUILD_COMPLUS, test "$component_system" = "COM+")
574
575 # Make the version number in gpgme/gpgme.h the same as the one here.
576 # (this is easier than to have a *.in file just for one substitution)
577 GNUPG_FIX_HDR_VERSION(gpgme/gpgme.h, GPGME_VERSION)
578
579 # Generate values for the DLL version info
580 changequote(,)dnl 
581 BUILD_REVISION="`echo '$Revision$' | sed 's/[^0-9]//g'`"
582 changequote([,])dnl
583 test -z "$BUILD_REVISION" && BUILD_REVISION="0"
584 if test "$have_w32_system" = yes; then
585     BUILD_TIMESTAMP=`date --iso-8601=minutes`
586     changequote(,)dnl 
587     BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
588     changequote([,])dnl
589     BUILD_FILEVERSION="${BUILD_FILEVERSION}${BUILD_REVISION}"
590 fi
591 AC_SUBST(BUILD_REVISION)
592 AC_SUBST(BUILD_TIMESTAMP)
593 AC_SUBST(BUILD_FILEVERSION)
594
595 # Add a few constants to help porting to W32
596 AH_VERBATIM([SEPCONSTANTS],
597 [
598 /* Separators as used in $PATH.  */
599 #ifdef HAVE_DOSISH_SYSTEM
600 #define PATHSEP_C ';'
601 #else
602 #define PATHSEP_C ':'
603 #endif
604 ])
605
606 AH_BOTTOM([
607 /* Definition of GCC specific attributes.  */
608 #if __GNUC__ > 2 
609 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
610 #else
611 # define GPGME_GCC_A_PURE
612 #endif
613 ])
614
615
616 # Substitution used for gpgme-config 
617 GPGME_CONFIG_LIBS="-lgpgme"
618 GPGME_CONFIG_CFLAGS=""
619 AC_SUBST(GPGME_CONFIG_API_VERSION)
620 AC_SUBST(GPGME_CONFIG_LIBS)
621 AC_SUBST(GPGME_CONFIG_CFLAGS)
622
623 # Frob'da Variables
624 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
625            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
626 AC_SUBST(LTLIBOBJS)
627
628 #
629 # Create config files 
630
631 AC_CONFIG_FILES(Makefile assuan/Makefile gpgme/Makefile
632                 tests/Makefile tests/gpg/Makefile tests/gpgsm/Makefile
633                 doc/Makefile complus/Makefile
634                 gpgme/versioninfo.rc)
635 AC_CONFIG_FILES(gpgme/gpgme-config, chmod +x gpgme/gpgme-config)
636 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
637 AC_OUTPUT
638
639 echo "
640         GPGME v${VERSION} has been configured as follows:
641
642         GnuPG path:    $GPG
643         GnuPG version: $GPG_VERSION, min. $NEED_GPG_VERSION
644
645         GpgSM path:    $GPGSM
646         GpgSM version: $GPGSM_VERSION, min. $NEED_GPGSM_VERSION
647
648         GPGME Pthread: $have_pthread
649         GPGME Pth:     $have_pth
650 "