w32: Change the way the I/O threads are cleaned up.
[gpgme.git] / m4 / libassuan.m4
1 dnl Autoconf macros for libassuan
2 dnl Copyright (C) 2002, 2003, 2011 Free Software Foundation, Inc.
3 dnl
4 dnl This file is free software; as a special exception the author gives
5 dnl unlimited permission to copy and/or distribute it, with or without
6 dnl modifications, as long as this notice is preserved.
7 dnl
8 dnl This file is distributed in the hope that it will be useful, but
9 dnl WITHOUT ANY WARRANTY, to the extent permitted by law; without even the
10 dnl implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
11
12 dnl
13 dnl Common code used for libassuan detection [internal]
14 dnl Returns ok set to yes or no.
15 dnl
16 AC_DEFUN([_AM_PATH_LIBASSUAN_COMMON],
17 [ AC_REQUIRE([AC_CANONICAL_HOST])
18   AC_ARG_WITH(libassuan-prefix,
19               AC_HELP_STRING([--with-libassuan-prefix=PFX],
20                              [prefix where LIBASSUAN is installed (optional)]),
21      libassuan_config_prefix="$withval", libassuan_config_prefix="")
22   if test x$libassuan_config_prefix != x ; then
23     libassuan_config_args="$libassuan_config_args --prefix=$libassuan_config_prefix"
24     if test x${LIBASSUAN_CONFIG+set} != xset ; then
25       LIBASSUAN_CONFIG=$libassuan_config_prefix/bin/libassuan-config
26     fi
27   fi
28
29   AC_PATH_TOOL(LIBASSUAN_CONFIG, libassuan-config, no)
30
31   tmp=ifelse([$1], ,1:0.9.2,$1)
32   if echo "$tmp" | grep ':' >/dev/null 2>/dev/null ; then
33     req_libassuan_api=`echo "$tmp"     | sed 's/\(.*\):\(.*\)/\1/'`
34     min_libassuan_version=`echo "$tmp" | sed 's/\(.*\):\(.*\)/\2/'`
35   else
36     req_libassuan_api=0
37     min_libassuan_version="$tmp"
38   fi
39
40   AC_MSG_CHECKING(for LIBASSUAN - version >= $min_libassuan_version)
41   ok=no
42   if test "$LIBASSUAN_CONFIG" != "no" \
43      && test -f "$LIBASSUAN_CONFIG" ; then
44     req_major=`echo $min_libassuan_version | \
45                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
46     req_minor=`echo $min_libassuan_version | \
47                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
48     req_micro=`echo $min_libassuan_version | \
49                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
50
51     libassuan_config_version=`$LIBASSUAN_CONFIG --version`
52     major=`echo $libassuan_config_version | \
53                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
54     minor=`echo $libassuan_config_version | \
55                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
56     micro=`echo $libassuan_config_version | \
57                sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
58
59     if test "$major" -gt "$req_major"; then
60         ok=yes
61     else 
62         if test "$major" -eq "$req_major"; then
63             if test "$minor" -gt "$req_minor"; then
64                ok=yes
65             else
66                if test "$minor" -eq "$req_minor"; then
67                    if test "$micro" -ge "$req_micro"; then
68                      ok=yes
69                    fi
70                fi
71             fi
72         fi
73     fi
74   fi
75
76   if test $ok = yes; then
77     AC_MSG_RESULT([yes ($libassuan_config_version)])
78   else
79     AC_MSG_RESULT(no)
80   fi
81
82   if test $ok = yes; then
83     if test "$req_libassuan_api" -gt 0 ; then
84       tmp=`$LIBASSUAN_CONFIG --api-version 2>/dev/null || echo 0`
85       if test "$tmp" -gt 0 ; then
86         AC_MSG_CHECKING([LIBASSUAN API version])
87         if test "$req_libassuan_api" -eq "$tmp" ; then
88           AC_MSG_RESULT(okay)
89         else
90           ok=no
91           AC_MSG_RESULT([does not match.  want=$req_libassuan_api got=$tmp.])
92         fi
93       fi
94     fi
95   fi
96
97   if test $ok = yes; then
98     if test x"$host" != x ; then
99       libassuan_config_host=`$LIBASSUAN_CONFIG --host 2>/dev/null || echo none`
100       if test x"$libassuan_config_host" != xnone ; then
101         if test x"$libassuan_config_host" != x"$host" ; then
102   AC_MSG_WARN([[
103 ***
104 *** The config script $LIBASSUAN_CONFIG was
105 *** built for $libassuan_config_host and thus may not match the
106 *** used host $host.
107 *** You may want to use the configure option --with-libassuan-prefix
108 *** to specify a matching config script.
109 ***]])
110         fi
111       fi
112     fi
113   fi
114 ])
115
116 dnl AM_CHECK_LIBASSUAN([MINIMUM-VERSION,
117 dnl                    [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
118 dnl Test whether libassuan has at least MINIMUM-VERSION. This is
119 dnl used to test for features only available in newer versions.
120 dnl
121 AC_DEFUN([AM_CHECK_LIBASSUAN],
122 [ _AM_PATH_LIBASSUAN_COMMON($1)
123   if test $ok = yes; then
124     ifelse([$2], , :, [$2])
125   else
126     ifelse([$3], , :, [$3])
127   fi
128 ])
129
130
131
132
133 dnl AM_PATH_LIBASSUAN([MINIMUM-VERSION,
134 dnl                   [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND ]]])
135 dnl Test for libassuan and define LIBASSUAN_CFLAGS and LIBASSUAN_LIBS
136 dnl
137 AC_DEFUN([AM_PATH_LIBASSUAN],
138 [ _AM_PATH_LIBASSUAN_COMMON($1)
139   if test $ok = yes; then
140     LIBASSUAN_CFLAGS=`$LIBASSUAN_CONFIG $libassuan_config_args --cflags`
141     LIBASSUAN_LIBS=`$LIBASSUAN_CONFIG $libassuan_config_args --libs`
142     ifelse([$2], , :, [$2])
143   else
144     LIBASSUAN_CFLAGS=""
145     LIBASSUAN_LIBS=""
146     ifelse([$3], , :, [$3])
147   fi
148   AC_SUBST(LIBASSUAN_CFLAGS)
149   AC_SUBST(LIBASSUAN_LIBS)
150 ])