build: Fix build with !HAVE_PTHREAD
[libgcrypt.git] / cipher / sha1-armv8-aarch64-ce.S
1 /* sha1-armv8-aarch64-ce.S - ARM/CE accelerated SHA-1 transform function
2  * Copyright (C) 2016 Jussi Kivilinna <jussi.kivilinna@iki.fi>
3  *
4  * This file is part of Libgcrypt.
5  *
6  * Libgcrypt is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU Lesser General Public License as
8  * published by the Free Software Foundation; either version 2.1 of
9  * the License, or (at your option) any later version.
10  *
11  * Libgcrypt is distributed in the hope that it will be useful,
12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14  * GNU Lesser General Public License for more details.
15  *
16  * You should have received a copy of the GNU Lesser General Public
17  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
18  */
19
20 #include "asm-common-aarch64.h"
21
22 #if defined(__AARCH64EL__) && \
23     defined(HAVE_COMPATIBLE_GCC_AARCH64_PLATFORM_AS) && \
24     defined(HAVE_GCC_INLINE_ASM_AARCH64_CRYPTO) && defined(USE_SHA1)
25
26 .cpu generic+simd+crypto
27
28 .text
29
30
31 /* Constants */
32
33 #define K1  0x5A827999
34 #define K2  0x6ED9EBA1
35 #define K3  0x8F1BBCDC
36 #define K4  0xCA62C1D6
37 .align 4
38 gcry_sha1_aarch64_ce_K_VEC:
39 .LK_VEC:
40 .LK1:   .long K1, K1, K1, K1
41 .LK2:   .long K2, K2, K2, K2
42 .LK3:   .long K3, K3, K3, K3
43 .LK4:   .long K4, K4, K4, K4
44
45
46 /* Register macros */
47
48 #define sH4    s0
49 #define vH4    v0
50 #define vH0123 v1
51
52 #define qABCD q2
53 #define sABCD s2
54 #define vABCD v2
55 #define sE0   s3
56 #define vE0   v3
57 #define sE1   s4
58 #define vE1   v4
59
60 #define vT0   v5
61 #define vT1   v6
62
63 #define vW0 v16
64 #define vW1 v17
65 #define vW2 v18
66 #define vW3 v19
67
68 #define vK1 v20
69 #define vK2 v21
70 #define vK3 v22
71 #define vK4 v23
72
73
74 /* Round macros */
75
76 #define _(...) /*_*/
77 #define do_add(dst, src0, src1) add dst.4s, src0.4s, src1.4s;
78 #define do_sha1su0(w0,w1,w2) sha1su0 w0.4s,w1.4s,w2.4s;
79 #define do_sha1su1(w0,w3) sha1su1 w0.4s,w3.4s;
80
81 #define do_rounds(f, e0, e1, t, k, w0, w1, w2, w3, add_fn, sha1su0_fn, sha1su1_fn) \
82         sha1su1_fn( v##w3, v##w2     ); \
83         sha1h       e0, sABCD; \
84         sha1##f     qABCD, e1, v##t.4s; \
85         add_fn(     v##t, v##w2, v##k   ); \
86         sha1su0_fn( v##w0, v##w1, v##w2 );
87
88
89 /* Other functional macros */
90
91 #define CLEAR_REG(reg) eor reg.16b, reg.16b, reg.16b;
92
93
94 /*
95  * unsigned int
96  * _gcry_sha1_transform_armv8_ce (void *ctx, const unsigned char *data,
97  *                                size_t nblks)
98  */
99 .align 3
100 .globl _gcry_sha1_transform_armv8_ce
101 ELF(.type  _gcry_sha1_transform_armv8_ce,%function;)
102 _gcry_sha1_transform_armv8_ce:
103   /* input:
104    *    x0: ctx, CTX
105    *    x1: data (64*nblks bytes)
106    *    x2: nblks
107    */
108   CFI_STARTPROC();
109
110   cbz x2, .Ldo_nothing;
111
112   GET_DATA_POINTER(x4, .LK_VEC);
113
114   ld1 {vH0123.4s}, [x0]     /* load h0,h1,h2,h3 */
115   ld1 {vK1.4s-vK4.4s}, [x4] /* load K1,K2,K3,K4 */
116   ldr sH4, [x0, #16]        /* load h4 */
117
118   ld1 {vW0.16b-vW3.16b}, [x1], #64
119   mov vABCD.16b, vH0123.16b
120
121   rev32 vW0.16b, vW0.16b
122   rev32 vW1.16b, vW1.16b
123   rev32 vW2.16b, vW2.16b
124   do_add(vT0, vW0, vK1)
125   rev32 vW3.16b, vW3.16b
126   do_add(vT1, vW1, vK1)
127
128 .Loop:
129   do_rounds(c, sE1, sH4, T0, K1, W0, W1, W2, W3, do_add, do_sha1su0, _)
130   sub x2, x2, #1
131   do_rounds(c, sE0, sE1, T1, K1, W1, W2, W3, W0, do_add, do_sha1su0, do_sha1su1)
132   do_rounds(c, sE1, sE0, T0, K1, W2, W3, W0, W1, do_add, do_sha1su0, do_sha1su1)
133   do_rounds(c, sE0, sE1, T1, K2, W3, W0, W1, W2, do_add, do_sha1su0, do_sha1su1)
134   do_rounds(c, sE1, sE0, T0, K2, W0, W1, W2, W3, do_add, do_sha1su0, do_sha1su1)
135
136   do_rounds(p, sE0, sE1, T1, K2, W1, W2, W3, W0, do_add, do_sha1su0, do_sha1su1)
137   do_rounds(p, sE1, sE0, T0, K2, W2, W3, W0, W1, do_add, do_sha1su0, do_sha1su1)
138   do_rounds(p, sE0, sE1, T1, K2, W3, W0, W1, W2, do_add, do_sha1su0, do_sha1su1)
139   do_rounds(p, sE1, sE0, T0, K3, W0, W1, W2, W3, do_add, do_sha1su0, do_sha1su1)
140   do_rounds(p, sE0, sE1, T1, K3, W1, W2, W3, W0, do_add, do_sha1su0, do_sha1su1)
141
142   do_rounds(m, sE1, sE0, T0, K3, W2, W3, W0, W1, do_add, do_sha1su0, do_sha1su1)
143   do_rounds(m, sE0, sE1, T1, K3, W3, W0, W1, W2, do_add, do_sha1su0, do_sha1su1)
144   do_rounds(m, sE1, sE0, T0, K3, W0, W1, W2, W3, do_add, do_sha1su0, do_sha1su1)
145   do_rounds(m, sE0, sE1, T1, K4, W1, W2, W3, W0, do_add, do_sha1su0, do_sha1su1)
146   do_rounds(m, sE1, sE0, T0, K4, W2, W3, W0, W1, do_add, do_sha1su0, do_sha1su1)
147
148   do_rounds(p, sE0, sE1, T1, K4, W3, W0, W1, W2, do_add, do_sha1su0, do_sha1su1)
149   cbz x2, .Lend
150
151   ld1 {vW0.16b-vW1.16b}, [x1], #32 /* preload */
152   do_rounds(p, sE1, sE0, T0, K4, _  , _  , W2, W3, do_add, _, do_sha1su1)
153   rev32 vW0.16b, vW0.16b
154   ld1 {vW2.16b}, [x1], #16
155   rev32 vW1.16b, vW1.16b
156   do_rounds(p, sE0, sE1, T1, K4, _  , _  , W3, _  , do_add, _, _)
157   ld1 {vW3.16b}, [x1], #16
158   rev32 vW2.16b, vW2.16b
159   do_rounds(p, sE1, sE0, T0, _, _, _, _, _, _, _, _)
160   rev32 vW3.16b, vW3.16b
161   do_rounds(p, sE0, sE1, T1, _, _, _, _, _, _, _, _)
162
163   do_add(vT0, vW0, vK1)
164   add vH4.2s, vH4.2s, vE0.2s
165   add vABCD.4s, vABCD.4s, vH0123.4s
166   do_add(vT1, vW1, vK1)
167
168   mov vH0123.16b, vABCD.16b
169
170   b .Loop
171
172 .Lend:
173   do_rounds(p, sE1, sE0, T0, K4, _  , _  , W2, W3, do_add, _, do_sha1su1)
174   do_rounds(p, sE0, sE1, T1, K4, _  , _  , W3, _  , do_add, _, _)
175   do_rounds(p, sE1, sE0, T0, _, _, _, _, _, _, _, _)
176   do_rounds(p, sE0, sE1, T1, _, _, _, _, _, _, _, _)
177
178   add vH4.2s, vH4.2s, vE0.2s
179   add vH0123.4s, vH0123.4s, vABCD.4s
180
181   CLEAR_REG(vW0)
182   CLEAR_REG(vW1)
183   CLEAR_REG(vW2)
184   CLEAR_REG(vW3)
185   CLEAR_REG(vABCD)
186   CLEAR_REG(vE1)
187   CLEAR_REG(vE0)
188
189   str sH4, [x0, #16]    /* store h4 */
190   st1 {vH0123.4s}, [x0] /* store h0,h1,h2,h3 */
191
192   CLEAR_REG(vH0123)
193   CLEAR_REG(vH4)
194
195 .Ldo_nothing:
196   mov x0, #0
197   ret
198   CFI_ENDPROC();
199 ELF(.size _gcry_sha1_transform_armv8_ce,.-_gcry_sha1_transform_armv8_ce;)
200
201 #endif