Add ARMv8/CE acceleration for AES-XTS
[libgcrypt.git] / cipher / sha1-avx-bmi2-amd64.S
1 /* sha1-avx-bmi2-amd64.S - Intel AVX/BMI2 accelerated SHA-1 transform function
2  * Copyright (C) 2013 Jussi Kivilinna <jussi.kivilinna@iki.fi>
3  *
4  * Based on sha1.c:
5  *  Copyright (C) 1998, 2001, 2002, 2003, 2008 Free Software Foundation, Inc.
6  *
7  * This file is part of Libgcrypt.
8  *
9  * Libgcrypt is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU Lesser General Public License as
11  * published by the Free Software Foundation; either version 2.1 of
12  * the License, or (at your option) any later version.
13  *
14  * Libgcrypt is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU Lesser General Public License for more details.
18  *
19  * You should have received a copy of the GNU Lesser General Public
20  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
21  */
22
23 /*
24  * Intel SSSE3 accelerated SHA-1 implementation based on white paper:
25  *  "Improving the Performance of the Secure Hash Algorithm (SHA-1)"
26  *  http://software.intel.com/en-us/articles/improving-the-performance-of-the-secure-hash-algorithm-1
27  */
28
29 #ifdef __x86_64__
30 #include <config.h>
31
32 #if (defined(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS) || \
33      defined(HAVE_COMPATIBLE_GCC_WIN64_PLATFORM_AS)) && \
34     defined(HAVE_GCC_INLINE_ASM_BMI2) && \
35     defined(HAVE_GCC_INLINE_ASM_AVX) && defined(USE_SHA1)
36
37 #ifdef __PIC__
38 #  define RIP (%rip)
39 #else
40 #  define RIP
41 #endif
42
43
44 #ifdef HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS
45 # define ELF(...) __VA_ARGS__
46 #else
47 # define ELF(...) /*_*/
48 #endif
49
50
51 /* Context structure */
52
53 #define state_h0 0
54 #define state_h1 4
55 #define state_h2 8
56 #define state_h3 12
57 #define state_h4 16
58
59
60 /* Constants */
61
62 .text
63 #define K1  0x5A827999
64 #define K2  0x6ED9EBA1
65 #define K3  0x8F1BBCDC
66 #define K4  0xCA62C1D6
67 .align 16
68 .LK_XMM:
69 .LK1:   .long K1, K1, K1, K1
70 .LK2:   .long K2, K2, K2, K2
71 .LK3:   .long K3, K3, K3, K3
72 .LK4:   .long K4, K4, K4, K4
73
74 .Lbswap_shufb_ctl:
75         .long 0x00010203, 0x04050607, 0x08090a0b, 0x0c0d0e0f
76
77
78 /* Register macros */
79
80 #define RSTATE %r8
81 #define RDATA %r9
82 #define ROLDSTACK %r10
83 #define RNBLKS %r11
84
85 #define a %eax
86 #define b %ebx
87 #define c %ecx
88 #define d %edx
89 #define e %edi
90
91 #define RT0 %esi
92 #define RT1 %ebp
93
94 #define Wtmp0 %xmm0
95 #define Wtmp1 %xmm1
96
97 #define W0 %xmm2
98 #define W1 %xmm3
99 #define W2 %xmm4
100 #define W3 %xmm5
101 #define W4 %xmm6
102 #define W5 %xmm7
103 #define W6 %xmm8
104 #define W7 %xmm9
105
106 #define BSWAP_REG %xmm10
107
108
109 /* Round function macros. */
110
111 #define WK(i) (((i) & 15) * 4)(%rsp)
112
113 #define R_F1(a,b,c,d,e,i) \
114         movl c, RT0; \
115         andn d, b, RT1; \
116         addl WK(i), e; \
117         andl b, RT0; \
118         rorxl $2, b, b; \
119         addl RT1, e; \
120         leal (RT0,e), e; \
121         rorxl $27, a, RT1; \
122         addl RT1, e;
123
124 #define R_F2(a,b,c,d,e,i) \
125         movl c, RT0; \
126         addl WK(i), e; \
127         xorl b, RT0; \
128         rorxl $2, b, b; \
129         xorl d, RT0; \
130         leal (RT0,e), e; \
131         rorxl $27, a, RT1; \
132         addl RT1, e;
133
134 #define R_F3(a,b,c,d,e,i) \
135         movl c, RT0; \
136         movl b, RT1; \
137         xorl b, RT0; \
138         andl c, RT1; \
139         andl d, RT0; \
140         addl RT1, e; \
141         addl WK(i), e; \
142         rorxl $2, b, b; \
143         leal (RT0,e), e; \
144         rorxl $27, a, RT1; \
145         addl RT1, e;
146
147 #define R_F4(a,b,c,d,e,i) R_F2(a,b,c,d,e,i)
148
149 #define R(a,b,c,d,e,f,i) \
150         R_##f(a,b,c,d,e,i)
151
152
153 /* Input expansion macros. */
154
155 #define W_PRECALC_00_15_0(i, W, tmp0) \
156         vmovdqu (4*(i))(RDATA), tmp0;
157
158 #define W_PRECALC_00_15_1(i, W, tmp0) \
159         vpshufb BSWAP_REG, tmp0, W;
160
161 #define W_PRECALC_00_15_2(i, W, tmp0) \
162         vpaddd (.LK_XMM + ((i)/20)*16) RIP, W, tmp0;
163
164 #define W_PRECALC_00_15_3(i, W, tmp0) \
165         vmovdqa tmp0, WK(i&~3);
166
167 #define W_PRECALC_16_31_0(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
168         vpalignr $8, W_m16, W_m12, W; \
169         vpsrldq $4, W_m04, tmp0; \
170         vpxor W_m08, W, W;
171
172 #define W_PRECALC_16_31_1(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
173         vpxor W_m16, tmp0, tmp0; \
174         vpxor tmp0, W, W; \
175         vpslld $1, W, tmp0; \
176         vpslldq $12, W, tmp1; \
177         vpsrld $31, W, W;
178
179 #define W_PRECALC_16_31_2(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
180         vpor W, tmp0, tmp0; \
181         vpsrld $30, tmp1, W; \
182         vpslld $2, tmp1, tmp1;
183
184 #define W_PRECALC_16_31_3(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
185         vpxor W, tmp0, tmp0; \
186         vpxor tmp1, tmp0, W; \
187         vpaddd (.LK_XMM + ((i)/20)*16) RIP, W, tmp0; \
188         vmovdqa tmp0, WK((i)&~3);
189
190 #define W_PRECALC_32_79_0(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
191         vpxor W_m28, W, W; \
192         vpalignr $8, W_m08, W_m04, tmp0;
193
194 #define W_PRECALC_32_79_1(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
195         vpxor W_m16, W, W; \
196         vpxor tmp0, W, W;
197
198 #define W_PRECALC_32_79_2(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
199         vpsrld $30, W, tmp0; \
200         vpslld $2, W, W;
201
202 #define W_PRECALC_32_79_3(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
203         vpor W, tmp0, W; \
204         vpaddd (.LK_XMM + ((i)/20)*16) RIP, W, tmp0; \
205         vmovdqa tmp0, WK((i)&~3);
206
207
208 /*
209  * Transform nblks*64 bytes (nblks*16 32-bit words) at DATA.
210  *
211  * unsigned int
212  * _gcry_sha1_transform_amd64_avx_bmi2 (void *ctx, const unsigned char *data,
213  *                                      size_t nblks)
214  */
215 .globl _gcry_sha1_transform_amd64_avx_bmi2
216 ELF(.type _gcry_sha1_transform_amd64_avx_bmi2,@function)
217 .align 16
218 _gcry_sha1_transform_amd64_avx_bmi2:
219   /* input:
220    *    %rdi: ctx, CTX
221    *    %rsi: data (64*nblks bytes)
222    *    %rdx: nblks
223    */
224
225   xorl %eax, %eax;
226   cmpq $0, %rdx;
227   jz .Lret;
228
229   vzeroupper;
230
231   movq %rdx, RNBLKS;
232   movq %rdi, RSTATE;
233   movq %rsi, RDATA;
234   pushq %rbx;
235   pushq %rbp;
236
237   movq %rsp, ROLDSTACK;
238
239   subq $(16*4), %rsp;
240   andq $(~31), %rsp;
241
242   /* Get the values of the chaining variables. */
243   movl state_h0(RSTATE), a;
244   movl state_h1(RSTATE), b;
245   movl state_h2(RSTATE), c;
246   movl state_h3(RSTATE), d;
247   movl state_h4(RSTATE), e;
248
249   movdqa .Lbswap_shufb_ctl RIP, BSWAP_REG;
250
251   /* Precalc 0-15. */
252   W_PRECALC_00_15_0(0, W0, Wtmp0);
253   W_PRECALC_00_15_1(1, W0, Wtmp0);
254   W_PRECALC_00_15_2(2, W0, Wtmp0);
255   W_PRECALC_00_15_3(3, W0, Wtmp0);
256   W_PRECALC_00_15_0(4, W7, Wtmp0);
257   W_PRECALC_00_15_1(5, W7, Wtmp0);
258   W_PRECALC_00_15_2(6, W7, Wtmp0);
259   W_PRECALC_00_15_3(7, W7, Wtmp0);
260   W_PRECALC_00_15_0(8, W6, Wtmp0);
261   W_PRECALC_00_15_1(9, W6, Wtmp0);
262   W_PRECALC_00_15_2(10, W6, Wtmp0);
263   W_PRECALC_00_15_3(11, W6, Wtmp0);
264   W_PRECALC_00_15_0(12, W5, Wtmp0);
265   W_PRECALC_00_15_1(13, W5, Wtmp0);
266   W_PRECALC_00_15_2(14, W5, Wtmp0);
267   W_PRECALC_00_15_3(15, W5, Wtmp0);
268
269 .align 8
270 .Loop:
271   addq $64, RDATA;
272
273   /* Transform 0-15 + Precalc 16-31. */
274   R( a, b, c, d, e, F1,  0 ); W_PRECALC_16_31_0(16, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
275   R( e, a, b, c, d, F1,  1 ); W_PRECALC_16_31_1(17, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
276   R( d, e, a, b, c, F1,  2 ); W_PRECALC_16_31_2(18, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
277   R( c, d, e, a, b, F1,  3 ); W_PRECALC_16_31_3(19, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
278   R( b, c, d, e, a, F1,  4 ); W_PRECALC_16_31_0(20, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
279   R( a, b, c, d, e, F1,  5 ); W_PRECALC_16_31_1(21, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
280   R( e, a, b, c, d, F1,  6 ); W_PRECALC_16_31_2(22, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
281   R( d, e, a, b, c, F1,  7 ); W_PRECALC_16_31_3(23, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
282   R( c, d, e, a, b, F1,  8 ); W_PRECALC_16_31_0(24, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
283   R( b, c, d, e, a, F1,  9 ); W_PRECALC_16_31_1(25, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
284   R( a, b, c, d, e, F1, 10 ); W_PRECALC_16_31_2(26, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
285   R( e, a, b, c, d, F1, 11 ); W_PRECALC_16_31_3(27, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
286   R( d, e, a, b, c, F1, 12 ); W_PRECALC_16_31_0(28, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
287   R( c, d, e, a, b, F1, 13 ); W_PRECALC_16_31_1(29, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
288   R( b, c, d, e, a, F1, 14 ); W_PRECALC_16_31_2(30, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
289   R( a, b, c, d, e, F1, 15 ); W_PRECALC_16_31_3(31, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
290
291   /* Transform 16-63 + Precalc 32-79. */
292   R( e, a, b, c, d, F1, 16 ); W_PRECALC_32_79_0(32, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
293   R( d, e, a, b, c, F1, 17 ); W_PRECALC_32_79_1(33, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
294   R( c, d, e, a, b, F1, 18 ); W_PRECALC_32_79_2(34, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
295   R( b, c, d, e, a, F1, 19 ); W_PRECALC_32_79_3(35, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
296   R( a, b, c, d, e, F2, 20 ); W_PRECALC_32_79_0(36, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
297   R( e, a, b, c, d, F2, 21 ); W_PRECALC_32_79_1(37, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
298   R( d, e, a, b, c, F2, 22 ); W_PRECALC_32_79_2(38, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
299   R( c, d, e, a, b, F2, 23 ); W_PRECALC_32_79_3(39, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
300   R( b, c, d, e, a, F2, 24 ); W_PRECALC_32_79_0(40, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
301   R( a, b, c, d, e, F2, 25 ); W_PRECALC_32_79_1(41, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
302   R( e, a, b, c, d, F2, 26 ); W_PRECALC_32_79_2(42, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
303   R( d, e, a, b, c, F2, 27 ); W_PRECALC_32_79_3(43, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
304   R( c, d, e, a, b, F2, 28 ); W_PRECALC_32_79_0(44, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
305   R( b, c, d, e, a, F2, 29 ); W_PRECALC_32_79_1(45, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
306   R( a, b, c, d, e, F2, 30 ); W_PRECALC_32_79_2(46, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
307   R( e, a, b, c, d, F2, 31 ); W_PRECALC_32_79_3(47, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
308   R( d, e, a, b, c, F2, 32 ); W_PRECALC_32_79_0(48, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
309   R( c, d, e, a, b, F2, 33 ); W_PRECALC_32_79_1(49, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
310   R( b, c, d, e, a, F2, 34 ); W_PRECALC_32_79_2(50, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
311   R( a, b, c, d, e, F2, 35 ); W_PRECALC_32_79_3(51, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
312   R( e, a, b, c, d, F2, 36 ); W_PRECALC_32_79_0(52, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
313   R( d, e, a, b, c, F2, 37 ); W_PRECALC_32_79_1(53, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
314   R( c, d, e, a, b, F2, 38 ); W_PRECALC_32_79_2(54, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
315   R( b, c, d, e, a, F2, 39 ); W_PRECALC_32_79_3(55, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
316   R( a, b, c, d, e, F3, 40 ); W_PRECALC_32_79_0(56, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
317   R( e, a, b, c, d, F3, 41 ); W_PRECALC_32_79_1(57, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
318   R( d, e, a, b, c, F3, 42 ); W_PRECALC_32_79_2(58, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
319   R( c, d, e, a, b, F3, 43 ); W_PRECALC_32_79_3(59, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
320   R( b, c, d, e, a, F3, 44 ); W_PRECALC_32_79_0(60, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
321   R( a, b, c, d, e, F3, 45 ); W_PRECALC_32_79_1(61, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
322   R( e, a, b, c, d, F3, 46 ); W_PRECALC_32_79_2(62, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
323   R( d, e, a, b, c, F3, 47 ); W_PRECALC_32_79_3(63, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
324   R( c, d, e, a, b, F3, 48 ); W_PRECALC_32_79_0(64, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
325   R( b, c, d, e, a, F3, 49 ); W_PRECALC_32_79_1(65, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
326   R( a, b, c, d, e, F3, 50 ); W_PRECALC_32_79_2(66, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
327   R( e, a, b, c, d, F3, 51 ); W_PRECALC_32_79_3(67, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
328   R( d, e, a, b, c, F3, 52 ); W_PRECALC_32_79_0(68, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
329   R( c, d, e, a, b, F3, 53 ); W_PRECALC_32_79_1(69, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
330   R( b, c, d, e, a, F3, 54 ); W_PRECALC_32_79_2(70, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
331   R( a, b, c, d, e, F3, 55 ); W_PRECALC_32_79_3(71, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
332   R( e, a, b, c, d, F3, 56 ); W_PRECALC_32_79_0(72, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
333   R( d, e, a, b, c, F3, 57 ); W_PRECALC_32_79_1(73, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
334   R( c, d, e, a, b, F3, 58 ); W_PRECALC_32_79_2(74, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
335   R( b, c, d, e, a, F3, 59 ); W_PRECALC_32_79_3(75, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
336   R( a, b, c, d, e, F4, 60 ); W_PRECALC_32_79_0(76, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
337   R( e, a, b, c, d, F4, 61 ); W_PRECALC_32_79_1(77, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
338   R( d, e, a, b, c, F4, 62 ); W_PRECALC_32_79_2(78, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
339   R( c, d, e, a, b, F4, 63 ); W_PRECALC_32_79_3(79, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
340
341   decq RNBLKS;
342   jz .Lend;
343
344   /* Transform 64-79 + Precalc 0-15 of next block. */
345   R( b, c, d, e, a, F4, 64 ); W_PRECALC_00_15_0(0, W0, Wtmp0);
346   R( a, b, c, d, e, F4, 65 ); W_PRECALC_00_15_1(1, W0, Wtmp0);
347   R( e, a, b, c, d, F4, 66 ); W_PRECALC_00_15_2(2, W0, Wtmp0);
348   R( d, e, a, b, c, F4, 67 ); W_PRECALC_00_15_3(3, W0, Wtmp0);
349   R( c, d, e, a, b, F4, 68 ); W_PRECALC_00_15_0(4, W7, Wtmp0);
350   R( b, c, d, e, a, F4, 69 ); W_PRECALC_00_15_1(5, W7, Wtmp0);
351   R( a, b, c, d, e, F4, 70 ); W_PRECALC_00_15_2(6, W7, Wtmp0);
352   R( e, a, b, c, d, F4, 71 ); W_PRECALC_00_15_3(7, W7, Wtmp0);
353   R( d, e, a, b, c, F4, 72 ); W_PRECALC_00_15_0(8, W6, Wtmp0);
354   R( c, d, e, a, b, F4, 73 ); W_PRECALC_00_15_1(9, W6, Wtmp0);
355   R( b, c, d, e, a, F4, 74 ); W_PRECALC_00_15_2(10, W6, Wtmp0);
356   R( a, b, c, d, e, F4, 75 ); W_PRECALC_00_15_3(11, W6, Wtmp0);
357   R( e, a, b, c, d, F4, 76 ); W_PRECALC_00_15_0(12, W5, Wtmp0);
358   R( d, e, a, b, c, F4, 77 ); W_PRECALC_00_15_1(13, W5, Wtmp0);
359   R( c, d, e, a, b, F4, 78 );
360   addl state_h0(RSTATE), a;   W_PRECALC_00_15_2(14, W5, Wtmp0);
361   R( b, c, d, e, a, F4, 79 ); W_PRECALC_00_15_3(15, W5, Wtmp0);
362
363   /* Update the chaining variables. */
364   addl state_h3(RSTATE), d;
365   addl state_h2(RSTATE), c;
366   addl state_h1(RSTATE), b;
367   addl state_h4(RSTATE), e;
368
369   movl d, state_h3(RSTATE);
370   movl c, state_h2(RSTATE);
371   movl b, state_h1(RSTATE);
372   movl a, state_h0(RSTATE);
373   movl e, state_h4(RSTATE);
374
375   jmp .Loop;
376
377 .align 16
378 .Lend:
379   vzeroall;
380
381   /* Transform 64-79. */
382   R( b, c, d, e, a, F4, 64 );
383   R( a, b, c, d, e, F4, 65 );
384   R( e, a, b, c, d, F4, 66 );
385   R( d, e, a, b, c, F4, 67 );
386   R( c, d, e, a, b, F4, 68 );
387   R( b, c, d, e, a, F4, 69 );
388   R( a, b, c, d, e, F4, 70 );
389   R( e, a, b, c, d, F4, 71 );
390   R( d, e, a, b, c, F4, 72 );
391   R( c, d, e, a, b, F4, 73 );
392   R( b, c, d, e, a, F4, 74 );
393   R( a, b, c, d, e, F4, 75 );
394   R( e, a, b, c, d, F4, 76 );
395   R( d, e, a, b, c, F4, 77 );
396   R( c, d, e, a, b, F4, 78 );
397   addl state_h0(RSTATE), a;
398   R( b, c, d, e, a, F4, 79 );
399
400   /* Update the chaining variables. */
401   addl state_h3(RSTATE), d;
402   addl state_h2(RSTATE), c;
403   addl state_h1(RSTATE), b;
404   addl state_h4(RSTATE), e;
405
406   movl d, state_h3(RSTATE);
407   movl c, state_h2(RSTATE);
408   movl b, state_h1(RSTATE);
409   movl a, state_h0(RSTATE);
410   movl e, state_h4(RSTATE);
411
412   movq ROLDSTACK, %rsp;
413
414   popq %rbp;
415   popq %rbx;
416
417   /* burn_stack */
418   movl $(16*4 + 2*8 + 31), %eax;
419
420 .Lret:
421   ret;
422
423 #endif
424 #endif