SHA-1/SSSE3: Do not check for Intel syntax assembly support
[libgcrypt.git] / cipher / sha1-ssse3-amd64.S
1 /* sha1-ssse3-amd64.c - Intel SSSE3 accelerated SHA-1 transform function
2  * Copyright © 2013 Jussi Kivilinna <jussi.kivilinna@iki.fi>
3  *
4  * Based on sha1.c:
5  *  Copyright (C) 1998, 2001, 2002, 2003, 2008 Free Software Foundation, Inc.
6  *
7  * This file is part of Libgcrypt.
8  *
9  * Libgcrypt is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU Lesser General Public License as
11  * published by the Free Software Foundation; either version 2.1 of
12  * the License, or (at your option) any later version.
13  *
14  * Libgcrypt is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU Lesser General Public License for more details.
18  *
19  * You should have received a copy of the GNU Lesser General Public
20  * License along with this program; if not, see <http://www.gnu.org/licenses/>.
21  */
22
23 /*
24  * Intel SSSE3 accelerated SHA-1 implementation based on white paper:
25  *  "Improving the Performance of the Secure Hash Algorithm (SHA-1)"
26  *  http://software.intel.com/en-us/articles/improving-the-performance-of-the-secure-hash-algorithm-1
27  */
28
29 #ifdef __x86_64__
30 #include <config.h>
31
32 #if defined(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS) && \
33     defined(HAVE_GCC_INLINE_ASM_SSSE3) && defined(USE_SHA1)
34
35 #ifdef __PIC__
36 #  define RIP (%rip)
37 #else
38 #  define RIP
39 #endif
40
41
42 /* Context structure */
43
44 #define state_h0 0
45 #define state_h1 4
46 #define state_h2 8
47 #define state_h3 12
48 #define state_h4 16
49
50
51 /* Constants */
52
53 .data
54 #define K1  0x5A827999
55 #define K2  0x6ED9EBA1
56 #define K3  0x8F1BBCDC
57 #define K4  0xCA62C1D6
58 .align 16
59 .LK_XMM:
60 .LK1:   .long K1, K1, K1, K1
61 .LK2:   .long K2, K2, K2, K2
62 .LK3:   .long K3, K3, K3, K3
63 .LK4:   .long K4, K4, K4, K4
64
65 .Lbswap_shufb_ctl:
66         .long 0x00010203, 0x04050607, 0x08090a0b, 0x0c0d0e0f
67
68
69 /* Register macros */
70
71 #define RSTATE %r8
72 #define RDATA %r9
73 #define ROLDSTACK %r10
74
75 #define a %eax
76 #define b %ebx
77 #define c %ecx
78 #define d %edx
79 #define e %edi
80
81 #define RT0 %esi
82 #define RT1 %ebp
83
84 #define Wtmp0 %xmm0
85 #define Wtmp1 %xmm1
86
87 #define W0 %xmm2
88 #define W1 %xmm3
89 #define W2 %xmm4
90 #define W3 %xmm5
91 #define W4 %xmm6
92 #define W5 %xmm7
93 #define W6 %xmm8
94 #define W7 %xmm9
95
96 #define BSWAP_REG %xmm10
97
98
99 /* Round function macros. */
100
101 #define WK(i) (((i) & 15) * 4)(%rsp)
102
103 #define R_F1(a,b,c,d,e,i) \
104         movl c, RT0; \
105         addl WK(i), e; \
106         xorl d, RT0; \
107         movl a, RT1; \
108         andl b, RT0; \
109         roll $30, b; \
110         xorl d, RT0; \
111         leal (RT0,e), e; \
112         roll $5, RT1; \
113         addl RT1, e;
114
115 #define R_F2(a,b,c,d,e,i) \
116         movl c, RT0; \
117         addl WK(i), e; \
118         xorl b, RT0; \
119         roll $30, b; \
120         xorl d, RT0; \
121         movl a, RT1; \
122         leal (RT0,e), e; \
123         roll $5, RT1; \
124         addl RT1, e;
125
126 #define R_F3(a,b,c,d,e,i) \
127         movl c, RT0; \
128         movl b, RT1; \
129         xorl b, RT0; \
130         andl c, RT1; \
131         andl d, RT0; \
132         addl RT1, e; \
133         addl WK(i), e; \
134         roll $30, b; \
135         movl a, RT1; \
136         leal (RT0,e), e; \
137         roll $5, RT1; \
138         addl RT1, e;
139
140 #define R_F4(a,b,c,d,e,i) R_F2(a,b,c,d,e,i)
141
142 #define R(a,b,c,d,e,f,i) \
143         R_##f(a,b,c,d,e,i)
144
145
146 /* Input expansion macros. */
147
148 #define W_PRECALC_00_15_0(i, W, tmp0) \
149         movdqu (4*(i))(RDATA), tmp0;
150
151 #define W_PRECALC_00_15_1(i, W, tmp0) \
152         pshufb BSWAP_REG, tmp0; \
153         movdqa tmp0, W;
154
155 #define W_PRECALC_00_15_2(i, W, tmp0) \
156         paddd (.LK_XMM + ((i)/20)*16) RIP, tmp0;
157
158 #define W_PRECALC_00_15_3(i, W, tmp0) \
159         movdqa tmp0, WK(i&~3);
160
161 #define W_PRECALC_16_31_0(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
162         movdqa W_m12, W; \
163         palignr $8, W_m16, W; \
164         movdqa W_m04, tmp0; \
165         psrldq $4, tmp0; \
166         pxor W_m08, W;
167
168 #define W_PRECALC_16_31_1(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
169         pxor W_m16, tmp0; \
170         pxor tmp0, W; \
171         movdqa W, tmp1; \
172         movdqa W, tmp0; \
173         pslldq $12, tmp1;
174
175 #define W_PRECALC_16_31_2(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
176         psrld $31, W; \
177         pslld $1, tmp0; \
178         por W, tmp0; \
179         movdqa tmp1, W; \
180         psrld $30, tmp1; \
181         pslld $2, W;
182
183 #define W_PRECALC_16_31_3(i, W, W_m04, W_m08, W_m12, W_m16, tmp0, tmp1) \
184         pxor W, tmp0; \
185         pxor tmp1, tmp0; \
186         movdqa tmp0, W; \
187         paddd (.LK_XMM + ((i)/20)*16) RIP, tmp0; \
188         movdqa tmp0, WK((i)&~3);
189
190 #define W_PRECALC_32_79_0(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
191         movdqa W_m04, tmp0; \
192         pxor W_m28, W; \
193         palignr $8, W_m08, tmp0;
194
195 #define W_PRECALC_32_79_1(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
196         pxor W_m16, W; \
197         pxor tmp0, W; \
198         movdqa W, tmp0;
199
200 #define W_PRECALC_32_79_2(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
201         psrld $30, W; \
202         pslld $2, tmp0; \
203         por W, tmp0;
204
205 #define W_PRECALC_32_79_3(i, W, W_m04, W_m08, W_m12, W_m16, W_m20, W_m24, W_m28, tmp0) \
206         movdqa tmp0, W; \
207         paddd (.LK_XMM + ((i)/20)*16) RIP, tmp0; \
208         movdqa tmp0, WK((i)&~3);
209
210 #define CLEAR_REG(reg) pxor reg, reg;
211
212
213 /*
214  * Transform 64 bytes (16 32-bit words) at DATA.
215  *
216  * unsigned int
217  * _gcry_sha1_transform_amd64_ssse3 (void *ctx, const unsigned char *data)
218  */
219 .text
220 .globl _gcry_sha1_transform_amd64_ssse3
221 .type _gcry_sha1_transform_amd64_ssse3,@function
222 .align 16
223 _gcry_sha1_transform_amd64_ssse3:
224   /* input:
225    *    %rdi: ctx, CTX
226    *    %rsi: data (64 bytes)
227    *    %rdx: ...
228    */
229
230   movq %rdi, RSTATE;
231   movq %rsi, RDATA;
232   pushq %rbx;
233   pushq %rbp;
234
235   movq %rsp, ROLDSTACK;
236
237   subq $(16*4), %rsp;
238   andq $(~31), %rsp;
239
240   /* Get the values of the chaining variables. */
241   movl state_h0(RSTATE), a;
242   movl state_h1(RSTATE), b;
243   movl state_h2(RSTATE), c;
244   movl state_h3(RSTATE), d;
245   movl state_h4(RSTATE), e;
246
247   movdqa .Lbswap_shufb_ctl RIP, BSWAP_REG;
248
249   /* Precalc 0-15. */
250   W_PRECALC_00_15_0(0, W0, Wtmp0);
251   W_PRECALC_00_15_1(1, W0, Wtmp0);
252   W_PRECALC_00_15_2(2, W0, Wtmp0);
253   W_PRECALC_00_15_3(3, W0, Wtmp0);
254   W_PRECALC_00_15_0(4, W7, Wtmp0);
255   W_PRECALC_00_15_1(5, W7, Wtmp0);
256   W_PRECALC_00_15_2(6, W7, Wtmp0);
257   W_PRECALC_00_15_3(7, W7, Wtmp0);
258   W_PRECALC_00_15_0(8, W6, Wtmp0);
259   W_PRECALC_00_15_1(9, W6, Wtmp0);
260   W_PRECALC_00_15_2(10, W6, Wtmp0);
261   W_PRECALC_00_15_3(11, W6, Wtmp0);
262   W_PRECALC_00_15_0(12, W5, Wtmp0);
263   W_PRECALC_00_15_1(13, W5, Wtmp0);
264   W_PRECALC_00_15_2(14, W5, Wtmp0);
265   W_PRECALC_00_15_3(15, W5, Wtmp0);
266
267   /* Transform 0-15 + Precalc 16-31. */
268   R( a, b, c, d, e, F1,  0 ); W_PRECALC_16_31_0(16, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
269   R( e, a, b, c, d, F1,  1 ); W_PRECALC_16_31_1(17, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
270   R( d, e, a, b, c, F1,  2 ); W_PRECALC_16_31_2(18, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
271   R( c, d, e, a, b, F1,  3 ); W_PRECALC_16_31_3(19, W4, W5, W6, W7, W0, Wtmp0, Wtmp1);
272   R( b, c, d, e, a, F1,  4 ); W_PRECALC_16_31_0(20, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
273   R( a, b, c, d, e, F1,  5 ); W_PRECALC_16_31_1(21, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
274   R( e, a, b, c, d, F1,  6 ); W_PRECALC_16_31_2(22, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
275   R( d, e, a, b, c, F1,  7 ); W_PRECALC_16_31_3(23, W3, W4, W5, W6, W7, Wtmp0, Wtmp1);
276   R( c, d, e, a, b, F1,  8 ); W_PRECALC_16_31_0(24, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
277   R( b, c, d, e, a, F1,  9 ); W_PRECALC_16_31_1(25, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
278   R( a, b, c, d, e, F1, 10 ); W_PRECALC_16_31_2(26, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
279   R( e, a, b, c, d, F1, 11 ); W_PRECALC_16_31_3(27, W2, W3, W4, W5, W6, Wtmp0, Wtmp1);
280   R( d, e, a, b, c, F1, 12 ); W_PRECALC_16_31_0(28, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
281   R( c, d, e, a, b, F1, 13 ); W_PRECALC_16_31_1(29, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
282   R( b, c, d, e, a, F1, 14 ); W_PRECALC_16_31_2(30, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
283   R( a, b, c, d, e, F1, 15 ); W_PRECALC_16_31_3(31, W1, W2, W3, W4, W5, Wtmp0, Wtmp1);
284
285   /* Transform 16-63 + Precalc 32-79. */
286   R( e, a, b, c, d, F1, 16 ); W_PRECALC_32_79_0(32, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
287   R( d, e, a, b, c, F1, 17 ); W_PRECALC_32_79_1(33, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
288   R( c, d, e, a, b, F1, 18 ); W_PRECALC_32_79_2(34, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
289   R( b, c, d, e, a, F1, 19 ); W_PRECALC_32_79_3(35, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
290   R( a, b, c, d, e, F2, 20 ); W_PRECALC_32_79_0(36, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
291   R( e, a, b, c, d, F2, 21 ); W_PRECALC_32_79_1(37, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
292   R( d, e, a, b, c, F2, 22 ); W_PRECALC_32_79_2(38, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
293   R( c, d, e, a, b, F2, 23 ); W_PRECALC_32_79_3(39, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
294   R( b, c, d, e, a, F2, 24 ); W_PRECALC_32_79_0(40, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
295   R( a, b, c, d, e, F2, 25 ); W_PRECALC_32_79_1(41, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
296   R( e, a, b, c, d, F2, 26 ); W_PRECALC_32_79_2(42, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
297   R( d, e, a, b, c, F2, 27 ); W_PRECALC_32_79_3(43, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
298   R( c, d, e, a, b, F2, 28 ); W_PRECALC_32_79_0(44, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
299   R( b, c, d, e, a, F2, 29 ); W_PRECALC_32_79_1(45, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
300   R( a, b, c, d, e, F2, 30 ); W_PRECALC_32_79_2(46, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
301   R( e, a, b, c, d, F2, 31 ); W_PRECALC_32_79_3(47, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
302   R( d, e, a, b, c, F2, 32 ); W_PRECALC_32_79_0(48, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
303   R( c, d, e, a, b, F2, 33 ); W_PRECALC_32_79_1(49, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
304   R( b, c, d, e, a, F2, 34 ); W_PRECALC_32_79_2(50, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
305   R( a, b, c, d, e, F2, 35 ); W_PRECALC_32_79_3(51, W4, W5, W6, W7, W0, W1, W2, W3, Wtmp0);
306   R( e, a, b, c, d, F2, 36 ); W_PRECALC_32_79_0(52, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
307   R( d, e, a, b, c, F2, 37 ); W_PRECALC_32_79_1(53, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
308   R( c, d, e, a, b, F2, 38 ); W_PRECALC_32_79_2(54, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
309   R( b, c, d, e, a, F2, 39 ); W_PRECALC_32_79_3(55, W3, W4, W5, W6, W7, W0, W1, W2, Wtmp0);
310   R( a, b, c, d, e, F3, 40 ); W_PRECALC_32_79_0(56, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
311   R( e, a, b, c, d, F3, 41 ); W_PRECALC_32_79_1(57, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
312   R( d, e, a, b, c, F3, 42 ); W_PRECALC_32_79_2(58, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
313   R( c, d, e, a, b, F3, 43 ); W_PRECALC_32_79_3(59, W2, W3, W4, W5, W6, W7, W0, W1, Wtmp0);
314   R( b, c, d, e, a, F3, 44 ); W_PRECALC_32_79_0(60, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
315   R( a, b, c, d, e, F3, 45 ); W_PRECALC_32_79_1(61, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
316   R( e, a, b, c, d, F3, 46 ); W_PRECALC_32_79_2(62, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
317   R( d, e, a, b, c, F3, 47 ); W_PRECALC_32_79_3(63, W1, W2, W3, W4, W5, W6, W7, W0, Wtmp0);
318   R( c, d, e, a, b, F3, 48 ); W_PRECALC_32_79_0(64, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
319   R( b, c, d, e, a, F3, 49 ); W_PRECALC_32_79_1(65, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
320   R( a, b, c, d, e, F3, 50 ); W_PRECALC_32_79_2(66, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
321   R( e, a, b, c, d, F3, 51 ); W_PRECALC_32_79_3(67, W0, W1, W2, W3, W4, W5, W6, W7, Wtmp0);
322   R( d, e, a, b, c, F3, 52 ); W_PRECALC_32_79_0(68, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
323   R( c, d, e, a, b, F3, 53 ); W_PRECALC_32_79_1(69, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
324   R( b, c, d, e, a, F3, 54 ); W_PRECALC_32_79_2(70, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
325   R( a, b, c, d, e, F3, 55 ); W_PRECALC_32_79_3(71, W7, W0, W1, W2, W3, W4, W5, W6, Wtmp0);
326   R( e, a, b, c, d, F3, 56 ); W_PRECALC_32_79_0(72, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
327   R( d, e, a, b, c, F3, 57 ); W_PRECALC_32_79_1(73, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
328   R( c, d, e, a, b, F3, 58 ); W_PRECALC_32_79_2(74, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
329   R( b, c, d, e, a, F3, 59 ); W_PRECALC_32_79_3(75, W6, W7, W0, W1, W2, W3, W4, W5, Wtmp0);
330   R( a, b, c, d, e, F4, 60 ); W_PRECALC_32_79_0(76, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
331   R( e, a, b, c, d, F4, 61 ); W_PRECALC_32_79_1(77, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
332   R( d, e, a, b, c, F4, 62 ); W_PRECALC_32_79_2(78, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
333   R( c, d, e, a, b, F4, 63 ); W_PRECALC_32_79_3(79, W5, W6, W7, W0, W1, W2, W3, W4, Wtmp0);
334
335   /* Transform 64-79 + Clear XMM registers. */
336   R( b, c, d, e, a, F4, 64 ); CLEAR_REG(BSWAP_REG);
337   R( a, b, c, d, e, F4, 65 ); CLEAR_REG(Wtmp0);
338   R( e, a, b, c, d, F4, 66 ); CLEAR_REG(Wtmp1);
339   R( d, e, a, b, c, F4, 67 ); CLEAR_REG(W0);
340   R( c, d, e, a, b, F4, 68 ); CLEAR_REG(W1);
341   R( b, c, d, e, a, F4, 69 ); CLEAR_REG(W2);
342   R( a, b, c, d, e, F4, 70 ); CLEAR_REG(W3);
343   R( e, a, b, c, d, F4, 71 ); CLEAR_REG(W4);
344   R( d, e, a, b, c, F4, 72 ); CLEAR_REG(W5);
345   R( c, d, e, a, b, F4, 73 ); CLEAR_REG(W6);
346   R( b, c, d, e, a, F4, 74 ); CLEAR_REG(W7);
347   R( a, b, c, d, e, F4, 75 );
348   R( e, a, b, c, d, F4, 76 );
349   R( d, e, a, b, c, F4, 77 );
350   R( c, d, e, a, b, F4, 78 );
351   R( b, c, d, e, a, F4, 79 );
352
353   /* Update the chaining variables. */
354   addl state_h0(RSTATE), a;
355   addl state_h1(RSTATE), b;
356   addl state_h2(RSTATE), c;
357   addl state_h3(RSTATE), d;
358   addl state_h4(RSTATE), e;
359
360   movl a, state_h0(RSTATE);
361   movl b, state_h1(RSTATE);
362   movl c, state_h2(RSTATE);
363   movl d, state_h3(RSTATE);
364   movl e, state_h4(RSTATE);
365
366   movq ROLDSTACK, %rsp;
367
368   popq %rbp;
369   popq %rbx;
370
371   /* burn_stack */
372   movl $(16*4 + 2*8 + 31), %eax;
373
374   ret;
375
376 #endif
377 #endif