pkgconfig: Fix libgcrypt.pc.
[libgcrypt.git] / cipher / sha512-ssse3-amd64.S
1 /*
2 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
3 ; Copyright (c) 2012, Intel Corporation
4 ;
5 ; All rights reserved.
6 ;
7 ; Redistribution and use in source and binary forms, with or without
8 ; modification, are permitted provided that the following conditions are
9 ; met:
10 ;
11 ; * Redistributions of source code must retain the above copyright
12 ;   notice, this list of conditions and the following disclaimer.
13 ;
14 ; * Redistributions in binary form must reproduce the above copyright
15 ;   notice, this list of conditions and the following disclaimer in the
16 ;   documentation and/or other materials provided with the
17 ;   distribution.
18 ;
19 ; * Neither the name of the Intel Corporation nor the names of its
20 ;   contributors may be used to endorse or promote products derived from
21 ;   this software without specific prior written permission.
22 ;
23 ;
24 ; THIS SOFTWARE IS PROVIDED BY INTEL CORPORATION "AS IS" AND ANY
25 ; EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
26 ; IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
27 ; PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL CORPORATION OR
28 ; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 ; EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 ; PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 ; PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
32 ; LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
33 ; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 ; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
36 */
37 /*
38  * Conversion to GAS assembly and integration to libgcrypt
39  *  by Jussi Kivilinna <jussi.kivilinna@iki.fi>
40  *
41  * Note: original implementation was named as SHA512-SSE4. However, only SSSE3
42  *       is required.
43  */
44
45 #ifdef __x86_64
46 #include <config.h>
47 #if (defined(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS) || \
48      defined(HAVE_COMPATIBLE_GCC_WIN64_PLATFORM_AS)) && \
49     defined(HAVE_INTEL_SYNTAX_PLATFORM_AS) && \
50     defined(HAVE_GCC_INLINE_ASM_SSSE3) && defined(USE_SHA512)
51
52 #include "asm-common-amd64.h"
53
54 .intel_syntax noprefix
55
56 .text
57
58 /* Virtual Registers */
59 msg = rdi /* ARG1 */
60 digest = rsi /* ARG2 */
61 msglen = rdx /* ARG3 */
62 T1 = rcx
63 T2 = r8
64 a_64 = r9
65 b_64 = r10
66 c_64 = r11
67 d_64 = r12
68 e_64 = r13
69 f_64 = r14
70 g_64 = r15
71 h_64 = rbx
72 tmp0 = rax
73
74 /*
75 ; Local variables (stack frame)
76 ; Note: frame_size must be an odd multiple of 8 bytes to XMM align RSP
77 */
78 frame_W      = 0 /* Message Schedule */
79 frame_W_size = (80 * 8)
80 frame_WK      = ((frame_W) + (frame_W_size)) /* W[t] + K[t] | W[t+1] + K[t+1] */
81 frame_WK_size = (2 * 8)
82 frame_GPRSAVE      = ((frame_WK) + (frame_WK_size))
83 frame_GPRSAVE_size = (5 * 8)
84 frame_size = ((frame_GPRSAVE) + (frame_GPRSAVE_size))
85
86
87 /* Useful QWORD "arrays" for simpler memory references */
88 #define MSG(i)    msg    + 8*(i)               /* Input message (arg1) */
89 #define DIGEST(i) digest + 8*(i)               /* Output Digest (arg2) */
90 #define K_t(i)    .LK512   + 8*(i) ADD_RIP     /* SHA Constants (static mem) */
91 #define W_t(i)    rsp + frame_W  + 8*(i)       /* Message Schedule (stack frame) */
92 #define WK_2(i)   rsp + frame_WK + 8*((i) % 2) /* W[t]+K[t] (stack frame) */
93 /* MSG, DIGEST, K_t, W_t are arrays */
94 /* WK_2(t) points to 1 of 2 qwords at frame.WK depdending on t being odd/even */
95
96 .macro RotateState
97         /* Rotate symbles a..h right */
98         __TMP = h_64
99         h_64 =  g_64
100         g_64 =  f_64
101         f_64 =  e_64
102         e_64 =  d_64
103         d_64 =  c_64
104         c_64 =  b_64
105         b_64 =  a_64
106         a_64 =  __TMP
107 .endm
108
109 .macro SHA512_Round t
110         /* Compute Round %%t */
111         mov     T1,   f_64        /* T1 = f */
112         mov     tmp0, e_64        /* tmp = e */
113         xor     T1,   g_64        /* T1 = f ^ g */
114         ror     tmp0, 23 /* 41     ; tmp = e ror 23 */
115         and     T1,   e_64        /* T1 = (f ^ g) & e */
116         xor     tmp0, e_64        /* tmp = (e ror 23) ^ e */
117         xor     T1,   g_64        /* T1 = ((f ^ g) & e) ^ g = CH(e,f,g) */
118         add     T1,   [WK_2(\t)] /* W[t] + K[t] from message scheduler */
119         ror     tmp0, 4 /* 18      ; tmp = ((e ror 23) ^ e) ror 4 */
120         xor     tmp0, e_64        /* tmp = (((e ror 23) ^ e) ror 4) ^ e */
121         mov     T2,   a_64        /* T2 = a */
122         add     T1,   h_64        /* T1 = CH(e,f,g) + W[t] + K[t] + h */
123         ror     tmp0, 14 /* 14     ; tmp = ((((e ror23)^e)ror4)^e)ror14 = S1(e) */
124         add     T1,   tmp0        /* T1 = CH(e,f,g) + W[t] + K[t] + S1(e) */
125         mov     tmp0, a_64        /* tmp = a */
126         xor     T2,   c_64        /* T2 = a ^ c */
127         and     tmp0, c_64        /* tmp = a & c */
128         and     T2,   b_64        /* T2 = (a ^ c) & b */
129         xor     T2,   tmp0        /* T2 = ((a ^ c) & b) ^ (a & c) = Maj(a,b,c) */
130         mov     tmp0, a_64        /* tmp = a */
131         ror     tmp0, 5 /* 39      ; tmp = a ror 5 */
132         xor     tmp0, a_64        /* tmp = (a ror 5) ^ a */
133         add     d_64, T1          /* e(next_state) = d + T1  */
134         ror     tmp0, 6 /* 34      ; tmp = ((a ror 5) ^ a) ror 6 */
135         xor     tmp0, a_64        /* tmp = (((a ror 5) ^ a) ror 6) ^ a */
136         lea     h_64, [T1 + T2]   /* a(next_state) = T1 + Maj(a,b,c) */
137         ror     tmp0, 28 /* 28     ; tmp = ((((a ror5)^a)ror6)^a)ror28 = S0(a) */
138         add     h_64, tmp0        /* a(next_state) = T1 + Maj(a,b,c) S0(a) */
139         RotateState
140 .endm
141
142 .macro SHA512_2Sched_2Round_sse t
143 /*      ; Compute rounds %%t-2 and %%t-1
144         ; Compute message schedule QWORDS %%t and %%t+1
145
146         ;   Two rounds are computed based on the values for K[t-2]+W[t-2] and
147         ; K[t-1]+W[t-1] which were previously stored at WK_2 by the message
148         ; scheduler.
149         ;   The two new schedule QWORDS are stored at [W_t(%%t)] and [W_t(%%t+1)].
150         ; They are then added to their respective SHA512 constants at
151         ; [K_t(%%t)] and [K_t(%%t+1)] and stored at dqword [WK_2(%%t)]
152         ;   For brievity, the comments following vectored instructions only refer to
153         ; the first of a pair of QWORDS.
154         ; Eg. XMM2=W[t-2] really means XMM2={W[t-2]|W[t-1]}
155         ;   The computation of the message schedule and the rounds are tightly
156         ; stitched to take advantage of instruction-level parallelism.
157         ; For clarity, integer instructions (for the rounds calculation) are indented
158         ; by one tab. Vectored instructions (for the message scheduler) are indented
159         ; by two tabs. */
160
161         mov     T1, f_64
162                 movdqa  xmm2, [W_t(\t-2)]  /* XMM2 = W[t-2] */
163         xor     T1,   g_64
164         and     T1,   e_64
165                 movdqa  xmm0, xmm2          /* XMM0 = W[t-2] */
166         xor     T1,   g_64
167         add     T1,   [WK_2(\t)]
168                 movdqu  xmm5, [W_t(\t-15)] /* XMM5 = W[t-15] */
169         mov     tmp0, e_64
170         ror     tmp0, 23 /* 41 */
171                 movdqa  xmm3, xmm5          /* XMM3 = W[t-15] */
172         xor     tmp0, e_64
173         ror     tmp0, 4 /* 18 */
174                 psrlq   xmm0, 61 - 19       /* XMM0 = W[t-2] >> 42 */
175         xor     tmp0, e_64
176         ror     tmp0, 14 /* 14 */
177                 psrlq   xmm3, (8 - 7)       /* XMM3 = W[t-15] >> 1 */
178         add     T1,   tmp0
179         add     T1,   h_64
180                 pxor    xmm0, xmm2          /* XMM0 = (W[t-2] >> 42) ^ W[t-2] */
181         mov     T2,   a_64
182         xor     T2,   c_64
183                 pxor    xmm3, xmm5          /* XMM3 = (W[t-15] >> 1) ^ W[t-15] */
184         and     T2,   b_64
185         mov     tmp0, a_64
186                 psrlq   xmm0, 19 - 6        /* XMM0 = ((W[t-2]>>42)^W[t-2])>>13 */
187         and     tmp0, c_64
188         xor     T2,   tmp0
189                 psrlq   xmm3, (7 - 1)       /* XMM3 = ((W[t-15]>>1)^W[t-15])>>6 */
190         mov     tmp0, a_64
191         ror     tmp0, 5 /* 39 */
192                 pxor    xmm0, xmm2          /* XMM0 = (((W[t-2]>>42)^W[t-2])>>13)^W[t-2] */
193         xor     tmp0, a_64
194         ror     tmp0, 6 /* 34 */
195                 pxor    xmm3, xmm5          /* XMM3 = (((W[t-15]>>1)^W[t-15])>>6)^W[t-15] */
196         xor     tmp0, a_64
197         ror     tmp0, 28 /* 28 */
198                 psrlq   xmm0, 6             /* XMM0 = ((((W[t-2]>>42)^W[t-2])>>13)^W[t-2])>>6 */
199         add     T2,   tmp0
200         add     d_64, T1
201                 psrlq   xmm3, 1             /* XMM3 = (((W[t-15]>>1)^W[t-15])>>6)^W[t-15]>>1 */
202         lea     h_64, [T1 + T2]
203         RotateState
204                 movdqa  xmm1, xmm2          /* XMM1 = W[t-2] */
205         mov     T1, f_64
206         xor     T1,   g_64
207                 movdqa  xmm4, xmm5          /* XMM4 = W[t-15] */
208         and     T1,   e_64
209         xor     T1,   g_64
210                 psllq   xmm1, (64 - 19) - (64 - 61) /* XMM1 = W[t-2] << 42 */
211         add     T1,   [WK_2(\t+1)]
212         mov     tmp0, e_64
213                 psllq   xmm4, (64 - 1) - (64 - 8) /* XMM4 = W[t-15] << 7 */
214         ror     tmp0, 23 /* 41 */
215         xor     tmp0, e_64
216                 pxor    xmm1, xmm2          /* XMM1 = (W[t-2] << 42)^W[t-2] */
217         ror     tmp0, 4 /* 18 */
218         xor     tmp0, e_64
219                 pxor    xmm4, xmm5          /* XMM4 = (W[t-15]<<7)^W[t-15] */
220         ror     tmp0, 14 /* 14 */
221         add     T1,   tmp0
222                 psllq   xmm1, (64 - 61)     /* XMM1 = ((W[t-2] << 42)^W[t-2])<<3 */
223         add     T1,   h_64
224         mov     T2,   a_64
225                 psllq   xmm4, (64 - 8)      /* XMM4 = ((W[t-15]<<7)^W[t-15])<<56 */
226         xor     T2,   c_64
227         and     T2,   b_64
228                 pxor    xmm0, xmm1          /* XMM0 = s1(W[t-2]) */
229         mov     tmp0, a_64
230         and     tmp0, c_64
231                 movdqu  xmm1, [W_t(\t- 7)] /* XMM1 = W[t-7] */
232         xor     T2,   tmp0
233                 pxor    xmm3, xmm4          /* XMM3 = s0(W[t-15]) */
234         mov     tmp0, a_64
235                 paddq   xmm0, xmm3          /* XMM0 = s1(W[t-2]) + s0(W[t-15]) */
236         ror     tmp0, 5 /* 39 */
237                 paddq   xmm0, [W_t(\t-16)] /* XMM0 = s1(W[t-2]) + s0(W[t-15]) + W[t-16] */
238         xor     tmp0, a_64
239                 paddq   xmm0, xmm1          /* XMM0 = s1(W[t-2]) + W[t-7] + s0(W[t-15]) + W[t-16] */
240         ror     tmp0, 6 /* 34 */
241                 movdqa  [W_t(\t)], xmm0     /* Store scheduled qwords */
242         xor     tmp0, a_64
243                 paddq   xmm0, [K_t(t)]      /* Compute W[t]+K[t] */
244         ror     tmp0, 28 /* 28 */
245                 movdqa  [WK_2(t)], xmm0     /* Store W[t]+K[t] for next rounds */
246         add     T2,   tmp0
247         add     d_64, T1
248         lea     h_64, [T1 + T2]
249         RotateState
250 .endm
251
252 /*
253 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
254 ; void sha512_sse4(const void* M, void* D, uint64_t L);
255 ; Purpose: Updates the SHA512 digest stored at D with the message stored in M.
256 ; The size of the message pointed to by M must be an integer multiple of SHA512
257 ;   message blocks.
258 ; L is the message length in SHA512 blocks.
259 */
260 .globl _gcry_sha512_transform_amd64_ssse3
261 ELF(.type _gcry_sha512_transform_amd64_ssse3,@function;)
262 .align 16
263 _gcry_sha512_transform_amd64_ssse3:
264         CFI_STARTPROC()
265         xor eax, eax
266
267         cmp msglen, 0
268         je .Lnowork
269
270         /* Allocate Stack Space */
271         sub     rsp, frame_size
272         CFI_ADJUST_CFA_OFFSET(frame_size);
273
274         /* Save GPRs */
275         mov     [rsp + frame_GPRSAVE + 8 * 0], rbx
276         mov     [rsp + frame_GPRSAVE + 8 * 1], r12
277         mov     [rsp + frame_GPRSAVE + 8 * 2], r13
278         mov     [rsp + frame_GPRSAVE + 8 * 3], r14
279         mov     [rsp + frame_GPRSAVE + 8 * 4], r15
280         CFI_REL_OFFSET(rbx, frame_GPRSAVE + 8 * 0);
281         CFI_REL_OFFSET(r12, frame_GPRSAVE + 8 * 1);
282         CFI_REL_OFFSET(r13, frame_GPRSAVE + 8 * 2);
283         CFI_REL_OFFSET(r14, frame_GPRSAVE + 8 * 3);
284         CFI_REL_OFFSET(r15, frame_GPRSAVE + 8 * 4);
285
286 .Lupdateblock:
287
288         /* Load state variables */
289         mov     a_64, [DIGEST(0)]
290         mov     b_64, [DIGEST(1)]
291         mov     c_64, [DIGEST(2)]
292         mov     d_64, [DIGEST(3)]
293         mov     e_64, [DIGEST(4)]
294         mov     f_64, [DIGEST(5)]
295         mov     g_64, [DIGEST(6)]
296         mov     h_64, [DIGEST(7)]
297
298         t = 0
299         .rept 80/2 + 1
300         /* (80 rounds) / (2 rounds/iteration) + (1 iteration) */
301         /* +1 iteration because the scheduler leads hashing by 1 iteration */
302                 .if t < 2
303                         /* BSWAP 2 QWORDS */
304                         movdqa  xmm1, [.LXMM_QWORD_BSWAP ADD_RIP]
305                         movdqu  xmm0, [MSG(t)]
306                         pshufb  xmm0, xmm1      /* BSWAP */
307                         movdqa  [W_t(t)], xmm0  /* Store Scheduled Pair */
308                         paddq   xmm0, [K_t(t)]  /* Compute W[t]+K[t] */
309                         movdqa  [WK_2(t)], xmm0 /* Store into WK for rounds */
310                 .elseif t < 16
311                         /* BSWAP 2 QWORDS; Compute 2 Rounds */
312                         movdqu  xmm0, [MSG(t)]
313                         pshufb  xmm0, xmm1      /* BSWAP */
314                         SHA512_Round (t - 2)    /* Round t-2 */
315                         movdqa  [W_t(t)], xmm0  /* Store Scheduled Pair */
316                         paddq   xmm0, [K_t(t)]  /* Compute W[t]+K[t] */
317                         SHA512_Round (t - 1)    /* Round t-1 */
318                         movdqa  [WK_2(t)], xmm0 /* Store W[t]+K[t] into WK */
319                 .elseif t < 79
320                         /* Schedule 2 QWORDS; Compute 2 Rounds */
321                         SHA512_2Sched_2Round_sse t
322                 .else
323                         /* Compute 2 Rounds */
324                         SHA512_Round (t - 2)
325                         SHA512_Round (t - 1)
326                 .endif
327                 t = (t)+2
328         .endr
329
330         /* Update digest */
331         add     [DIGEST(0)], a_64
332         add     [DIGEST(1)], b_64
333         add     [DIGEST(2)], c_64
334         add     [DIGEST(3)], d_64
335         add     [DIGEST(4)], e_64
336         add     [DIGEST(5)], f_64
337         add     [DIGEST(6)], g_64
338         add     [DIGEST(7)], h_64
339
340         /* Advance to next message block */
341         add     msg, 16*8
342         dec     msglen
343         jnz     .Lupdateblock
344
345         /* Restore GPRs */
346         mov     rbx, [rsp + frame_GPRSAVE + 8 * 0]
347         mov     r12, [rsp + frame_GPRSAVE + 8 * 1]
348         mov     r13, [rsp + frame_GPRSAVE + 8 * 2]
349         mov     r14, [rsp + frame_GPRSAVE + 8 * 3]
350         mov     r15, [rsp + frame_GPRSAVE + 8 * 4]
351         CFI_RESTORE(rbx)
352         CFI_RESTORE(r12)
353         CFI_RESTORE(r13)
354         CFI_RESTORE(r14)
355         CFI_RESTORE(r15)
356
357         pxor    xmm0, xmm0
358         pxor    xmm1, xmm1
359         pxor    xmm2, xmm2
360         pxor    xmm3, xmm3
361         pxor    xmm4, xmm4
362         pxor    xmm5, xmm5
363
364         /* Burn stack */
365         t = 0
366         .rept frame_W_size / 16
367                 movdqu [rsp + frame_W + (t) * 16], xmm0
368                 t = ((t)+1)
369         .endr
370         movdqu [rsp + frame_WK], xmm0
371         xor     eax, eax
372
373         /* Restore Stack Pointer */
374         add     rsp, frame_size
375         CFI_ADJUST_CFA_OFFSET(-frame_size);
376
377 .Lnowork:
378         ret
379         CFI_ENDPROC()
380
381 /*
382 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
383 ;;; Binary Data
384 */
385
386 .align 16
387
388 /* Mask for byte-swapping a couple of qwords in an XMM register using (v)pshufb. */
389 .LXMM_QWORD_BSWAP:
390         .octa 0x08090a0b0c0d0e0f0001020304050607
391
392 /* K[t] used in SHA512 hashing */
393 .LK512:
394         .quad 0x428a2f98d728ae22,0x7137449123ef65cd
395         .quad 0xb5c0fbcfec4d3b2f,0xe9b5dba58189dbbc
396         .quad 0x3956c25bf348b538,0x59f111f1b605d019
397         .quad 0x923f82a4af194f9b,0xab1c5ed5da6d8118
398         .quad 0xd807aa98a3030242,0x12835b0145706fbe
399         .quad 0x243185be4ee4b28c,0x550c7dc3d5ffb4e2
400         .quad 0x72be5d74f27b896f,0x80deb1fe3b1696b1
401         .quad 0x9bdc06a725c71235,0xc19bf174cf692694
402         .quad 0xe49b69c19ef14ad2,0xefbe4786384f25e3
403         .quad 0x0fc19dc68b8cd5b5,0x240ca1cc77ac9c65
404         .quad 0x2de92c6f592b0275,0x4a7484aa6ea6e483
405         .quad 0x5cb0a9dcbd41fbd4,0x76f988da831153b5
406         .quad 0x983e5152ee66dfab,0xa831c66d2db43210
407         .quad 0xb00327c898fb213f,0xbf597fc7beef0ee4
408         .quad 0xc6e00bf33da88fc2,0xd5a79147930aa725
409         .quad 0x06ca6351e003826f,0x142929670a0e6e70
410         .quad 0x27b70a8546d22ffc,0x2e1b21385c26c926
411         .quad 0x4d2c6dfc5ac42aed,0x53380d139d95b3df
412         .quad 0x650a73548baf63de,0x766a0abb3c77b2a8
413         .quad 0x81c2c92e47edaee6,0x92722c851482353b
414         .quad 0xa2bfe8a14cf10364,0xa81a664bbc423001
415         .quad 0xc24b8b70d0f89791,0xc76c51a30654be30
416         .quad 0xd192e819d6ef5218,0xd69906245565a910
417         .quad 0xf40e35855771202a,0x106aa07032bbd1b8
418         .quad 0x19a4c116b8d2d0c8,0x1e376c085141ab53
419         .quad 0x2748774cdf8eeb99,0x34b0bcb5e19b48a8
420         .quad 0x391c0cb3c5c95a63,0x4ed8aa4ae3418acb
421         .quad 0x5b9cca4f7763e373,0x682e6ff3d6b2b8a3
422         .quad 0x748f82ee5defb2fc,0x78a5636f43172f60
423         .quad 0x84c87814a1f0ab72,0x8cc702081a6439ec
424         .quad 0x90befffa23631e28,0xa4506cebde82bde9
425         .quad 0xbef9a3f7b2c67915,0xc67178f2e372532b
426         .quad 0xca273eceea26619c,0xd186b8c721c0c207
427         .quad 0xeada7dd6cde0eb1e,0xf57d4f7fee6ed178
428         .quad 0x06f067aa72176fba,0x0a637dc5a2c898a6
429         .quad 0x113f9804bef90dae,0x1b710b35131c471b
430         .quad 0x28db77f523047d84,0x32caab7b40c72493
431         .quad 0x3c9ebe0a15c9bebc,0x431d67c49c100d4c
432         .quad 0x4cc5d4becb3e42b6,0x597f299cfc657e2a
433         .quad 0x5fcb6fab3ad6faec,0x6c44198c4a475817
434
435 #endif
436 #endif