Add carryless 8-bit addition fast-path for AES-NI CTR mode
[libgcrypt.git] / cipher / sha512-ssse3-amd64.S
1 /*
2 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
3 ; Copyright (c) 2012, Intel Corporation
4 ;
5 ; All rights reserved.
6 ;
7 ; Redistribution and use in source and binary forms, with or without
8 ; modification, are permitted provided that the following conditions are
9 ; met:
10 ;
11 ; * Redistributions of source code must retain the above copyright
12 ;   notice, this list of conditions and the following disclaimer.
13 ;
14 ; * Redistributions in binary form must reproduce the above copyright
15 ;   notice, this list of conditions and the following disclaimer in the
16 ;   documentation and/or other materials provided with the
17 ;   distribution.
18 ;
19 ; * Neither the name of the Intel Corporation nor the names of its
20 ;   contributors may be used to endorse or promote products derived from
21 ;   this software without specific prior written permission.
22 ;
23 ;
24 ; THIS SOFTWARE IS PROVIDED BY INTEL CORPORATION "AS IS" AND ANY
25 ; EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
26 ; IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
27 ; PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL CORPORATION OR
28 ; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 ; EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 ; PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 ; PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
32 ; LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
33 ; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 ; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
36 */
37 /*
38  * Conversion to GAS assembly and integration to libgcrypt
39  *  by Jussi Kivilinna <jussi.kivilinna@iki.fi>
40  *
41  * Note: original implementation was named as SHA512-SSE4. However, only SSSE3
42  *       is required.
43  */
44
45 #ifdef __x86_64
46 #include <config.h>
47 #if (defined(HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS) || \
48      defined(HAVE_COMPATIBLE_GCC_WIN64_PLATFORM_AS)) && \
49     defined(HAVE_INTEL_SYNTAX_PLATFORM_AS) && \
50     defined(HAVE_GCC_INLINE_ASM_SSSE3) && defined(USE_SHA512)
51
52 #ifdef __PIC__
53 #  define ADD_RIP +rip
54 #else
55 #  define ADD_RIP
56 #endif
57
58 #ifdef HAVE_COMPATIBLE_GCC_AMD64_PLATFORM_AS
59 # define ELF(...) __VA_ARGS__
60 #else
61 # define ELF(...) /*_*/
62 #endif
63
64 .intel_syntax noprefix
65
66 .text
67
68 /* Virtual Registers */
69 msg = rdi /* ARG1 */
70 digest = rsi /* ARG2 */
71 msglen = rdx /* ARG3 */
72 T1 = rcx
73 T2 = r8
74 a_64 = r9
75 b_64 = r10
76 c_64 = r11
77 d_64 = r12
78 e_64 = r13
79 f_64 = r14
80 g_64 = r15
81 h_64 = rbx
82 tmp0 = rax
83
84 /*
85 ; Local variables (stack frame)
86 ; Note: frame_size must be an odd multiple of 8 bytes to XMM align RSP
87 */
88 frame_W      = 0 /* Message Schedule */
89 frame_W_size = (80 * 8)
90 frame_WK      = ((frame_W) + (frame_W_size)) /* W[t] + K[t] | W[t+1] + K[t+1] */
91 frame_WK_size = (2 * 8)
92 frame_GPRSAVE      = ((frame_WK) + (frame_WK_size))
93 frame_GPRSAVE_size = (5 * 8)
94 frame_size = ((frame_GPRSAVE) + (frame_GPRSAVE_size))
95
96
97 /* Useful QWORD "arrays" for simpler memory references */
98 #define MSG(i)    msg    + 8*(i)               /* Input message (arg1) */
99 #define DIGEST(i) digest + 8*(i)               /* Output Digest (arg2) */
100 #define K_t(i)    .LK512   + 8*(i) ADD_RIP     /* SHA Constants (static mem) */
101 #define W_t(i)    rsp + frame_W  + 8*(i)       /* Message Schedule (stack frame) */
102 #define WK_2(i)   rsp + frame_WK + 8*((i) % 2) /* W[t]+K[t] (stack frame) */
103 /* MSG, DIGEST, K_t, W_t are arrays */
104 /* WK_2(t) points to 1 of 2 qwords at frame.WK depdending on t being odd/even */
105
106 .macro RotateState
107         /* Rotate symbles a..h right */
108         __TMP = h_64
109         h_64 =  g_64
110         g_64 =  f_64
111         f_64 =  e_64
112         e_64 =  d_64
113         d_64 =  c_64
114         c_64 =  b_64
115         b_64 =  a_64
116         a_64 =  __TMP
117 .endm
118
119 .macro SHA512_Round t
120         /* Compute Round %%t */
121         mov     T1,   f_64        /* T1 = f */
122         mov     tmp0, e_64        /* tmp = e */
123         xor     T1,   g_64        /* T1 = f ^ g */
124         ror     tmp0, 23 /* 41     ; tmp = e ror 23 */
125         and     T1,   e_64        /* T1 = (f ^ g) & e */
126         xor     tmp0, e_64        /* tmp = (e ror 23) ^ e */
127         xor     T1,   g_64        /* T1 = ((f ^ g) & e) ^ g = CH(e,f,g) */
128         add     T1,   [WK_2(\t)] /* W[t] + K[t] from message scheduler */
129         ror     tmp0, 4 /* 18      ; tmp = ((e ror 23) ^ e) ror 4 */
130         xor     tmp0, e_64        /* tmp = (((e ror 23) ^ e) ror 4) ^ e */
131         mov     T2,   a_64        /* T2 = a */
132         add     T1,   h_64        /* T1 = CH(e,f,g) + W[t] + K[t] + h */
133         ror     tmp0, 14 /* 14     ; tmp = ((((e ror23)^e)ror4)^e)ror14 = S1(e) */
134         add     T1,   tmp0        /* T1 = CH(e,f,g) + W[t] + K[t] + S1(e) */
135         mov     tmp0, a_64        /* tmp = a */
136         xor     T2,   c_64        /* T2 = a ^ c */
137         and     tmp0, c_64        /* tmp = a & c */
138         and     T2,   b_64        /* T2 = (a ^ c) & b */
139         xor     T2,   tmp0        /* T2 = ((a ^ c) & b) ^ (a & c) = Maj(a,b,c) */
140         mov     tmp0, a_64        /* tmp = a */
141         ror     tmp0, 5 /* 39      ; tmp = a ror 5 */
142         xor     tmp0, a_64        /* tmp = (a ror 5) ^ a */
143         add     d_64, T1          /* e(next_state) = d + T1  */
144         ror     tmp0, 6 /* 34      ; tmp = ((a ror 5) ^ a) ror 6 */
145         xor     tmp0, a_64        /* tmp = (((a ror 5) ^ a) ror 6) ^ a */
146         lea     h_64, [T1 + T2]   /* a(next_state) = T1 + Maj(a,b,c) */
147         ror     tmp0, 28 /* 28     ; tmp = ((((a ror5)^a)ror6)^a)ror28 = S0(a) */
148         add     h_64, tmp0        /* a(next_state) = T1 + Maj(a,b,c) S0(a) */
149         RotateState
150 .endm
151
152 .macro SHA512_2Sched_2Round_sse t
153 /*      ; Compute rounds %%t-2 and %%t-1
154         ; Compute message schedule QWORDS %%t and %%t+1
155
156         ;   Two rounds are computed based on the values for K[t-2]+W[t-2] and
157         ; K[t-1]+W[t-1] which were previously stored at WK_2 by the message
158         ; scheduler.
159         ;   The two new schedule QWORDS are stored at [W_t(%%t)] and [W_t(%%t+1)].
160         ; They are then added to their respective SHA512 constants at
161         ; [K_t(%%t)] and [K_t(%%t+1)] and stored at dqword [WK_2(%%t)]
162         ;   For brievity, the comments following vectored instructions only refer to
163         ; the first of a pair of QWORDS.
164         ; Eg. XMM2=W[t-2] really means XMM2={W[t-2]|W[t-1]}
165         ;   The computation of the message schedule and the rounds are tightly
166         ; stitched to take advantage of instruction-level parallelism.
167         ; For clarity, integer instructions (for the rounds calculation) are indented
168         ; by one tab. Vectored instructions (for the message scheduler) are indented
169         ; by two tabs. */
170
171         mov     T1, f_64
172                 movdqa  xmm2, [W_t(\t-2)]  /* XMM2 = W[t-2] */
173         xor     T1,   g_64
174         and     T1,   e_64
175                 movdqa  xmm0, xmm2          /* XMM0 = W[t-2] */
176         xor     T1,   g_64
177         add     T1,   [WK_2(\t)]
178                 movdqu  xmm5, [W_t(\t-15)] /* XMM5 = W[t-15] */
179         mov     tmp0, e_64
180         ror     tmp0, 23 /* 41 */
181                 movdqa  xmm3, xmm5          /* XMM3 = W[t-15] */
182         xor     tmp0, e_64
183         ror     tmp0, 4 /* 18 */
184                 psrlq   xmm0, 61 - 19       /* XMM0 = W[t-2] >> 42 */
185         xor     tmp0, e_64
186         ror     tmp0, 14 /* 14 */
187                 psrlq   xmm3, (8 - 7)       /* XMM3 = W[t-15] >> 1 */
188         add     T1,   tmp0
189         add     T1,   h_64
190                 pxor    xmm0, xmm2          /* XMM0 = (W[t-2] >> 42) ^ W[t-2] */
191         mov     T2,   a_64
192         xor     T2,   c_64
193                 pxor    xmm3, xmm5          /* XMM3 = (W[t-15] >> 1) ^ W[t-15] */
194         and     T2,   b_64
195         mov     tmp0, a_64
196                 psrlq   xmm0, 19 - 6        /* XMM0 = ((W[t-2]>>42)^W[t-2])>>13 */
197         and     tmp0, c_64
198         xor     T2,   tmp0
199                 psrlq   xmm3, (7 - 1)       /* XMM3 = ((W[t-15]>>1)^W[t-15])>>6 */
200         mov     tmp0, a_64
201         ror     tmp0, 5 /* 39 */
202                 pxor    xmm0, xmm2          /* XMM0 = (((W[t-2]>>42)^W[t-2])>>13)^W[t-2] */
203         xor     tmp0, a_64
204         ror     tmp0, 6 /* 34 */
205                 pxor    xmm3, xmm5          /* XMM3 = (((W[t-15]>>1)^W[t-15])>>6)^W[t-15] */
206         xor     tmp0, a_64
207         ror     tmp0, 28 /* 28 */
208                 psrlq   xmm0, 6             /* XMM0 = ((((W[t-2]>>42)^W[t-2])>>13)^W[t-2])>>6 */
209         add     T2,   tmp0
210         add     d_64, T1
211                 psrlq   xmm3, 1             /* XMM3 = (((W[t-15]>>1)^W[t-15])>>6)^W[t-15]>>1 */
212         lea     h_64, [T1 + T2]
213         RotateState
214                 movdqa  xmm1, xmm2          /* XMM1 = W[t-2] */
215         mov     T1, f_64
216         xor     T1,   g_64
217                 movdqa  xmm4, xmm5          /* XMM4 = W[t-15] */
218         and     T1,   e_64
219         xor     T1,   g_64
220                 psllq   xmm1, (64 - 19) - (64 - 61) /* XMM1 = W[t-2] << 42 */
221         add     T1,   [WK_2(\t+1)]
222         mov     tmp0, e_64
223                 psllq   xmm4, (64 - 1) - (64 - 8) /* XMM4 = W[t-15] << 7 */
224         ror     tmp0, 23 /* 41 */
225         xor     tmp0, e_64
226                 pxor    xmm1, xmm2          /* XMM1 = (W[t-2] << 42)^W[t-2] */
227         ror     tmp0, 4 /* 18 */
228         xor     tmp0, e_64
229                 pxor    xmm4, xmm5          /* XMM4 = (W[t-15]<<7)^W[t-15] */
230         ror     tmp0, 14 /* 14 */
231         add     T1,   tmp0
232                 psllq   xmm1, (64 - 61)     /* XMM1 = ((W[t-2] << 42)^W[t-2])<<3 */
233         add     T1,   h_64
234         mov     T2,   a_64
235                 psllq   xmm4, (64 - 8)      /* XMM4 = ((W[t-15]<<7)^W[t-15])<<56 */
236         xor     T2,   c_64
237         and     T2,   b_64
238                 pxor    xmm0, xmm1          /* XMM0 = s1(W[t-2]) */
239         mov     tmp0, a_64
240         and     tmp0, c_64
241                 movdqu  xmm1, [W_t(\t- 7)] /* XMM1 = W[t-7] */
242         xor     T2,   tmp0
243                 pxor    xmm3, xmm4          /* XMM3 = s0(W[t-15]) */
244         mov     tmp0, a_64
245                 paddq   xmm0, xmm3          /* XMM0 = s1(W[t-2]) + s0(W[t-15]) */
246         ror     tmp0, 5 /* 39 */
247                 paddq   xmm0, [W_t(\t-16)] /* XMM0 = s1(W[t-2]) + s0(W[t-15]) + W[t-16] */
248         xor     tmp0, a_64
249                 paddq   xmm0, xmm1          /* XMM0 = s1(W[t-2]) + W[t-7] + s0(W[t-15]) + W[t-16] */
250         ror     tmp0, 6 /* 34 */
251                 movdqa  [W_t(\t)], xmm0     /* Store scheduled qwords */
252         xor     tmp0, a_64
253                 paddq   xmm0, [K_t(t)]      /* Compute W[t]+K[t] */
254         ror     tmp0, 28 /* 28 */
255                 movdqa  [WK_2(t)], xmm0     /* Store W[t]+K[t] for next rounds */
256         add     T2,   tmp0
257         add     d_64, T1
258         lea     h_64, [T1 + T2]
259         RotateState
260 .endm
261
262 /*
263 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
264 ; void sha512_sse4(const void* M, void* D, uint64_t L);
265 ; Purpose: Updates the SHA512 digest stored at D with the message stored in M.
266 ; The size of the message pointed to by M must be an integer multiple of SHA512
267 ;   message blocks.
268 ; L is the message length in SHA512 blocks.
269 */
270 .globl _gcry_sha512_transform_amd64_ssse3
271 ELF(.type _gcry_sha512_transform_amd64_ssse3,@function;)
272 .align 16
273 _gcry_sha512_transform_amd64_ssse3:
274         xor eax, eax
275
276         cmp msglen, 0
277         je .Lnowork
278
279         /* Allocate Stack Space */
280         sub     rsp, frame_size
281
282         /* Save GPRs */
283         mov     [rsp + frame_GPRSAVE + 8 * 0], rbx
284         mov     [rsp + frame_GPRSAVE + 8 * 1], r12
285         mov     [rsp + frame_GPRSAVE + 8 * 2], r13
286         mov     [rsp + frame_GPRSAVE + 8 * 3], r14
287         mov     [rsp + frame_GPRSAVE + 8 * 4], r15
288
289 .Lupdateblock:
290
291         /* Load state variables */
292         mov     a_64, [DIGEST(0)]
293         mov     b_64, [DIGEST(1)]
294         mov     c_64, [DIGEST(2)]
295         mov     d_64, [DIGEST(3)]
296         mov     e_64, [DIGEST(4)]
297         mov     f_64, [DIGEST(5)]
298         mov     g_64, [DIGEST(6)]
299         mov     h_64, [DIGEST(7)]
300
301         t = 0
302         .rept 80/2 + 1
303         /* (80 rounds) / (2 rounds/iteration) + (1 iteration) */
304         /* +1 iteration because the scheduler leads hashing by 1 iteration */
305                 .if t < 2
306                         /* BSWAP 2 QWORDS */
307                         movdqa  xmm1, [.LXMM_QWORD_BSWAP ADD_RIP]
308                         movdqu  xmm0, [MSG(t)]
309                         pshufb  xmm0, xmm1      /* BSWAP */
310                         movdqa  [W_t(t)], xmm0  /* Store Scheduled Pair */
311                         paddq   xmm0, [K_t(t)]  /* Compute W[t]+K[t] */
312                         movdqa  [WK_2(t)], xmm0 /* Store into WK for rounds */
313                 .elseif t < 16
314                         /* BSWAP 2 QWORDS; Compute 2 Rounds */
315                         movdqu  xmm0, [MSG(t)]
316                         pshufb  xmm0, xmm1      /* BSWAP */
317                         SHA512_Round (t - 2)    /* Round t-2 */
318                         movdqa  [W_t(t)], xmm0  /* Store Scheduled Pair */
319                         paddq   xmm0, [K_t(t)]  /* Compute W[t]+K[t] */
320                         SHA512_Round (t - 1)    /* Round t-1 */
321                         movdqa  [WK_2(t)], xmm0 /* Store W[t]+K[t] into WK */
322                 .elseif t < 79
323                         /* Schedule 2 QWORDS; Compute 2 Rounds */
324                         SHA512_2Sched_2Round_sse t
325                 .else
326                         /* Compute 2 Rounds */
327                         SHA512_Round (t - 2)
328                         SHA512_Round (t - 1)
329                 .endif
330                 t = (t)+2
331         .endr
332
333         /* Update digest */
334         add     [DIGEST(0)], a_64
335         add     [DIGEST(1)], b_64
336         add     [DIGEST(2)], c_64
337         add     [DIGEST(3)], d_64
338         add     [DIGEST(4)], e_64
339         add     [DIGEST(5)], f_64
340         add     [DIGEST(6)], g_64
341         add     [DIGEST(7)], h_64
342
343         /* Advance to next message block */
344         add     msg, 16*8
345         dec     msglen
346         jnz     .Lupdateblock
347
348         /* Restore GPRs */
349         mov     rbx, [rsp + frame_GPRSAVE + 8 * 0]
350         mov     r12, [rsp + frame_GPRSAVE + 8 * 1]
351         mov     r13, [rsp + frame_GPRSAVE + 8 * 2]
352         mov     r14, [rsp + frame_GPRSAVE + 8 * 3]
353         mov     r15, [rsp + frame_GPRSAVE + 8 * 4]
354
355         /* Restore Stack Pointer */
356         add     rsp, frame_size
357
358         pxor    xmm0, xmm0
359         pxor    xmm1, xmm1
360         pxor    xmm2, xmm2
361         pxor    xmm3, xmm3
362         pxor    xmm4, xmm4
363         pxor    xmm5, xmm5
364
365         /* Return stack burn depth */
366         mov     rax, frame_size
367
368 .Lnowork:
369         ret
370
371 /*
372 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
373 ;;; Binary Data
374 */
375
376 .data
377
378 .align 16
379
380 /* Mask for byte-swapping a couple of qwords in an XMM register using (v)pshufb. */
381 .LXMM_QWORD_BSWAP:
382         .octa 0x08090a0b0c0d0e0f0001020304050607
383
384 /* K[t] used in SHA512 hashing */
385 .LK512:
386         .quad 0x428a2f98d728ae22,0x7137449123ef65cd
387         .quad 0xb5c0fbcfec4d3b2f,0xe9b5dba58189dbbc
388         .quad 0x3956c25bf348b538,0x59f111f1b605d019
389         .quad 0x923f82a4af194f9b,0xab1c5ed5da6d8118
390         .quad 0xd807aa98a3030242,0x12835b0145706fbe
391         .quad 0x243185be4ee4b28c,0x550c7dc3d5ffb4e2
392         .quad 0x72be5d74f27b896f,0x80deb1fe3b1696b1
393         .quad 0x9bdc06a725c71235,0xc19bf174cf692694
394         .quad 0xe49b69c19ef14ad2,0xefbe4786384f25e3
395         .quad 0x0fc19dc68b8cd5b5,0x240ca1cc77ac9c65
396         .quad 0x2de92c6f592b0275,0x4a7484aa6ea6e483
397         .quad 0x5cb0a9dcbd41fbd4,0x76f988da831153b5
398         .quad 0x983e5152ee66dfab,0xa831c66d2db43210
399         .quad 0xb00327c898fb213f,0xbf597fc7beef0ee4
400         .quad 0xc6e00bf33da88fc2,0xd5a79147930aa725
401         .quad 0x06ca6351e003826f,0x142929670a0e6e70
402         .quad 0x27b70a8546d22ffc,0x2e1b21385c26c926
403         .quad 0x4d2c6dfc5ac42aed,0x53380d139d95b3df
404         .quad 0x650a73548baf63de,0x766a0abb3c77b2a8
405         .quad 0x81c2c92e47edaee6,0x92722c851482353b
406         .quad 0xa2bfe8a14cf10364,0xa81a664bbc423001
407         .quad 0xc24b8b70d0f89791,0xc76c51a30654be30
408         .quad 0xd192e819d6ef5218,0xd69906245565a910
409         .quad 0xf40e35855771202a,0x106aa07032bbd1b8
410         .quad 0x19a4c116b8d2d0c8,0x1e376c085141ab53
411         .quad 0x2748774cdf8eeb99,0x34b0bcb5e19b48a8
412         .quad 0x391c0cb3c5c95a63,0x4ed8aa4ae3418acb
413         .quad 0x5b9cca4f7763e373,0x682e6ff3d6b2b8a3
414         .quad 0x748f82ee5defb2fc,0x78a5636f43172f60
415         .quad 0x84c87814a1f0ab72,0x8cc702081a6439ec
416         .quad 0x90befffa23631e28,0xa4506cebde82bde9
417         .quad 0xbef9a3f7b2c67915,0xc67178f2e372532b
418         .quad 0xca273eceea26619c,0xd186b8c721c0c207
419         .quad 0xeada7dd6cde0eb1e,0xf57d4f7fee6ed178
420         .quad 0x06f067aa72176fba,0x0a637dc5a2c898a6
421         .quad 0x113f9804bef90dae,0x1b710b35131c471b
422         .quad 0x28db77f523047d84,0x32caab7b40c72493
423         .quad 0x3c9ebe0a15c9bebc,0x431d67c49c100d4c
424         .quad 0x4cc5d4becb3e42b6,0x597f299cfc657e2a
425         .quad 0x5fcb6fab3ad6faec,0x6c44198c4a475817
426
427 #endif
428 #endif