See ChangeLog: Thu Dec 10 20:15:36 CET 1998 Werner Koch
[libgcrypt.git] / configure.in
1 dnl
2 dnl Configure template for GNUPG
3 dnl
4 dnl (Process this file with autoconf to produce a configure script.)
5 AC_REVISION($Revision$)dnl
6
7 dnl Must reset CDPATH so that bash's cd does not print to stdout
8 CDPATH=
9
10 AC_INIT(g10/g10.c)
11 AC_CONFIG_AUX_DIR(scripts)
12 AM_CONFIG_HEADER(config.h)
13
14
15 VERSION=`cat $srcdir/VERSION`
16 PACKAGE=gnupg
17 ALL_LINGUAS="de it fr ru es_ES pt_BR"
18 AC_SUBST(VERSION)
19 AC_SUBST(PACKAGE)
20 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
21 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
22
23 AC_MSG_CHECKING([whether use of /dev/random is requested])
24 AC_ARG_ENABLE(dev-random,
25 [  --disable-dev-random    disable the use of dev random],
26     try_dev_random=$enableval, try_dev_random=yes)
27 AC_MSG_RESULT($try_dev_random)
28
29 AC_MSG_CHECKING([whether use of extensions is requested])
30 AC_ARG_ENABLE(dynload,
31 [  --disable-dynload       disable use of extensions],
32     try_dynload=$enableval, try_dynload=yes)
33 AC_MSG_RESULT($try_dynload)
34
35 AC_MSG_CHECKING([whether assembler modules are requested])
36 AC_ARG_ENABLE(asm,
37 [  --disable-asm           do not use assembler modules],
38      try_asm_modules=$enableval, try_asm_modules=yes)
39 AC_MSG_RESULT($try_asm_modules)
40
41 AC_MSG_CHECKING([whether memory debugging is requested])
42 AC_ARG_ENABLE(m-debug,
43 [  --enable-m-debug        enable debugging of memory allocation],
44 use_m_debug=$enableval, use_m_debug=no)
45 AC_MSG_RESULT($use_m_debug)
46 if test "$use_m_debug" = yes; then
47     AC_DEFINE(M_DEBUG)
48     use_m_guard=yes
49 else
50     AC_MSG_CHECKING([whether memory guard is requested])
51     AC_ARG_ENABLE(m-guard,
52     [  --disable-m-guard       disable memory guard facility],
53     use_m_guard=$enableval, use_m_guard=yes)
54     AC_MSG_RESULT($use_m_guard)
55 fi
56 if test "$use_m_guard" = yes ; then
57     AC_DEFINE(M_GUARD)
58     CFLAGS="$CFLAGS -g"
59 else
60     CFLAGS="$CFLAGS -O2"
61 fi
62
63 if test "$GCC" = yes; then
64     CFLAGS="$CFLAGS -Wall"
65 fi
66
67
68 AC_MSG_CHECKING([whether included zlib is requested])
69 AC_ARG_WITH(included-zlib,
70     [  --with-included-zlib    use the zlib code included here],
71 [g10_force_zlib=yes], [g10_force_zlib=no] )
72 AC_MSG_RESULT($g10_force_zlib)
73
74 dnl Checks for programs.
75
76 AC_CANONICAL_SYSTEM
77 AC_ARG_PROGRAM
78 AC_PROG_MAKE_SET
79 AM_SANITY_CHECK
80 missing_dir=`cd $ac_aux_dir && pwd`
81 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
82 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
83 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
84 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
85 dnl AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
86 AC_PROG_CC
87 AC_PROG_CPP
88 AC_ISC_POSIX
89 AC_PROG_RANLIB
90 AC_PROG_INSTALL
91 AM_CYGWIN32
92
93
94 case "${target}" in
95     i386--mingw32)
96         # special stuff for Windoze NT
97         cross_compiling=yes
98         CC="i386--mingw32-gcc"
99         CPP="i386--mingw32-gcc -E"
100         RANLIB="i386--mingw32-ranlib"
101         ac_cv_have_dev_random=no
102         AC_DEFINE(USE_RNDW32)
103         ;;
104     *-*-hpux*)
105         if test -z "$GCC" ; then
106             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
107         fi
108         AC_DEFINE(USE_RNDUNIX)
109         ;;
110     *)
111        ;;
112 esac
113
114
115 GNUPG_CHECK_PIC
116 if test "$NO_PIC" = yes; then
117     try_dynload=no
118 fi
119
120
121 case "${target}" in
122     i386--mingw32)
123         PRINTABLE_OS_NAME="MingW32"
124         ;;
125     *-linux*)
126         PRINTABLE_OS_NAME="GNU/Linux"
127         ;;
128     *)
129         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
130         ;;
131 esac
132 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME")
133
134 dnl  Fixme: Are these the best flags for OpenBSD????
135 case "${target}" in
136     *-openbsd*)
137         NAME_OF_DEV_RANDOM="/dev/srandom"
138         NAME_OF_DEV_URANDOM="/dev/urandom"
139         DYNLINK_MOD_CFLAGS="-shared -rdynamic -fpic -Wl,-Bshareable -Wl,-x"
140         ;;
141     *)
142         NAME_OF_DEV_RANDOM="/dev/random"
143         NAME_OF_DEV_URANDOM="/dev/urandom"
144         DYNLINK_MOD_CFLAGS="-shared $CFLAGS_PIC -lc"
145         ;;
146 esac
147 AC_DEFINE_UNQUOTED(NAME_OF_DEV_RANDOM, "$NAME_OF_DEV_RANDOM")
148 AC_DEFINE_UNQUOTED(NAME_OF_DEV_URANDOM, "$NAME_OF_DEV_URANDOM")
149
150
151 dnl Checks for libraries.
152
153 AM_GNU_GETTEXT
154
155 AC_CHECK_LIB(gdbm,gdbm_firstkey)
156
157
158 if test "$try_dynload" = yes ; then
159 AC_CHECK_LIB(dl,dlopen)
160 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
161   AC_DEFINE(USE_DYNAMIC_LINKING)
162   AC_DEFINE(HAVE_DL_DLOPEN)
163   DYNLINK_LDFLAGS="-Wl,-export-dynamic"
164   use_gnupg_extensions=yes
165 else
166 AC_CHECK_LIB(dld,dld_link)
167 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
168   AC_DEFINE(USE_DYNAMIC_LINKING)
169   AC_DEFINE(HAVE_DLD_DLD_LINK)
170   DYNLINK_LDFLAGS="-Wl,-export-dynamic"
171   use_gnupg_extensions=yes
172 fi
173 fi
174 else
175   AC_MSG_CHECKING(for dynamic loading)
176   DYNLINK_LDFLAGS=
177   DYNLINK_MOD_CFLAGS=
178   use_gnupg_extensions=no
179   AC_MSG_RESULT(has been disabled)
180 fi
181
182 AM_CONDITIONAL(ENABLE_GNUPG_EXTENSIONS, test "$use_gnupg_extensions" = yes )
183 AC_SUBST(DYNLINK_LDFLAGS)
184 AC_SUBST(DYNLINK_MOD_CFLAGS)
185
186
187 dnl Checks for header files.
188 AC_HEADER_STDC
189 AC_CHECK_HEADERS(unistd.h)
190
191
192 dnl Checks for typedefs, structures, and compiler characteristics.
193 AC_C_CONST
194 AC_C_INLINE
195 AC_TYPE_SIZE_T
196 AC_TYPE_SIGNAL
197 AC_DECL_SYS_SIGLIST
198
199 GNUPG_CHECK_ENDIAN
200
201
202 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
203 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
204 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
205 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
206 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
207
208 AC_CHECK_SIZEOF(unsigned short, 2)
209 AC_CHECK_SIZEOF(unsigned int, 4)
210 AC_CHECK_SIZEOF(unsigned long, 4)
211
212 if test "$ac_cv_sizeof_unsigned_short" = "0" \
213    || test "$ac_cv_sizeof_unsigned_int" = "0" \
214    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
215     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
216 fi
217
218
219
220 dnl Checks for library functions.
221 AC_FUNC_VPRINTF
222 AC_CHECK_FUNCS(strerror stpcpy strlwr tcgetattr rand strtoul mmap)
223 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime setrlimit)
224 AC_CHECK_FUNCS(memicmp atexit raise getpagesize strftime)
225
226 GNUPG_CHECK_MLOCK
227
228 GNUPG_CHECK_IPC
229 if test "$ac_cv_header_sys_shm_h" = "yes"; then
230   AC_DEFINE(USE_SHM_COPROCESSING)
231 fi
232
233 dnl check whether we have a random device
234 if test "$try_dev_random" = yes ; then
235 AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
236 [if test -c "$NAME_OF_DEV_RANDOM" && test -c "$NAME_OF_DEV_URANDOM" ; then
237   ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
238 if test "$ac_cv_have_dev_random" = yes; then
239     AC_DEFINE(HAVE_DEV_RANDOM)
240     AC_DEFINE(USE_RNDLINUX)
241 fi
242 else
243     AC_MSG_CHECKING(for random device)
244     ac_cv_have_dev_random=no
245     AC_MSG_RESULT(has been disabled)
246 fi
247
248
249 dnl setup assembler stuff
250 AC_MSG_CHECKING(for mpi assembler functions)
251 if test -f $srcdir/mpi/config.links ; then
252     . $srcdir/mpi/config.links
253     GNUPG_LINK_FILES($mpi_ln_src, $mpi_ln_dst)
254     ac_cv_mpi_extra_asm_modules="$mpi_extra_modules"
255     ac_cv_mpi_sflags="$mpi_sflags"
256     ac_cv_mpi_config_done="yes"
257     AC_MSG_RESULT(done)
258 else
259     AC_MSG_RESULT(failed)
260     AC_MSG_ERROR([mpi/config.links missing!])
261 fi
262 MPI_EXTRA_ASM_OBJS=""
263 if test "$ac_cv_mpi_extra_asm_modules" != ""; then
264 GNUPG_MSG_PRINT([mpi extra asm functions:])
265 for i in $ac_cv_mpi_extra_asm_modules; do
266     GNUPG_MSG_PRINT([$i])
267     MPI_EXTRA_ASM_OBJS="$MPI_EXTRA_ASM_OBJS $i.o"
268 done
269 AC_MSG_RESULT()
270 fi
271 AC_SUBST(MPI_EXTRA_ASM_OBJS)
272 MPI_SFLAGS="$ac_cv_mpi_sflags"
273 AC_SUBST(MPI_SFLAGS)
274
275 dnl Do we have zlib? Must do it here because Solaris failed
276 dnl when compiling a conftest (due to the "-lz" from LIBS).
277 if test "$g10_force_zlib" = "yes"; then
278     ZLIBS="../zlib/libzlib.a"
279     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
280     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
281     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
282 else
283 AC_CHECK_HEADERS(zlib.h)
284 if test "$ac_cv_header_zlib_h" = yes ; then
285     LIBS="$LIBS -lz"
286     ZLIBS=
287     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, false)
288 else
289     ZLIBS="../zlib/libzlib.a"
290     AM_CONDITIONAL(ENABLE_LOCAL_ZLIB, true)
291     GNUPG_LINK_FILES(zlib/zlib.h, zlib.h )
292     GNUPG_LINK_FILES(zlib/zconf.h, zconf.h )
293 fi
294 fi
295 AC_SUBST(ZLIBS)
296
297 GNUPG_DO_LINK_FILES
298
299
300 AC_OUTPUT([
301 Makefile
302 intl/Makefile
303 po/Makefile.in
304 util/Makefile
305 mpi/Makefile
306 cipher/Makefile
307 g10/Makefile
308 doc/Makefile
309 tools/Makefile
310 zlib/Makefile
311 checks/Makefile
312 ])
313
314 dnl *-*wedit:notab*-*  Please keep this as the last line.