added assembler stuff for hppa
[libgcrypt.git] / mpi / hppa / mpih-sub1.S
1 /* hppa   sub_n -- Sub two limb vectors of the same length > 0 and store
2  *                 sum in a third limb vector.
3  *      Copyright (C) 1992, 1994 Free Software Foundation, Inc.
4  *      Copyright (c) 1998 by Werner Koch (dd9jn)
5  *
6  * This file is part of G10.
7  *
8  * G10 is free software; you can redistribute it and/or modify
9  * it under the terms of the GNU General Public License as published by
10  * the Free Software Foundation; either version 2 of the License, or
11  * (at your option) any later version.
12  *
13  * G10 is distributed in the hope that it will be useful,
14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16  * GNU General Public License for more details.
17  *
18  * You should have received a copy of the GNU General Public License
19  * along with this program; if not, write to the Free Software
20  * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
21  *
22  * Note: This code is heavily based on the GNU MP Library.
23  *       Actually it's the same code with only minor changes in the
24  *       way the data is stored; this is to support the abstraction
25  *       of an optional secure memory allocation which may be used
26  *       to avoid revealing of sensitive data due to paging etc.
27  *       The GNU MP Library itself is published under the LGPL;
28  *       however I decided to publish this code under the plain GPL.
29  */
30
31
32 #include "sysdep.h"
33 #include "asm-syntax.h"
34
35
36 /*******************
37  *  mpi_limb_t
38  *  mpihelp_sub_n( mpi_ptr_t res_ptr,   (gr26)
39  *                 mpi_ptr_t s1_ptr,    (gr25)
40  *                 mpi_ptr_t s2_ptr,    (gr24)
41  *                 mpi_size_t size)     (gr23)
42  *
43  * One might want to unroll this as for other processors, but it turns
44  * out that the data cache contention after a store makes such
45  * unrolling useless.  We can't come under 5 cycles/limb anyway.
46  */
47
48
49         .code
50         .export         mpihelp_sub_n
51 mpihelp_sub_n
52         .proc
53         .callinfo       frame=0,no_calls
54         .entry
55
56         ldws,ma         4(0,%r25),%r20
57         ldws,ma         4(0,%r24),%r19
58
59         addib,=         -1,%r23,L$end   ; check for (SIZE == 1)
60          sub            %r20,%r19,%r28  ; subtract first limbs ignoring cy
61
62 L$loop  ldws,ma         4(0,%r25),%r20
63         ldws,ma         4(0,%r24),%r19
64         stws,ma         %r28,4(0,%r26)
65         addib,<>        -1,%r23,L$loop
66          subb           %r20,%r19,%r28
67
68 L$end   stws            %r28,0(0,%r26)
69         addc            %r0,%r0,%r28
70         bv              0(%r2)
71          subi           1,%r28,%r28
72
73         .exit
74         .procend
75
76
77