ChangeLog:
[libgcrypt.git] / mpi / hppa1.1 / mpih-mul2.S
1 /* hppa1.1   addmul_1 -- Multiply a limb vector with a limb and add
2  *                       the result to a second limb vector.
3  *
4  *      Copyright (C) 1992, 1993, 1994, 1998,
5  *                    2001, 2002 Free Software Foundation, Inc.
6  *
7  * This file is part of Libgcrypt.
8  *
9  * Libgcrypt is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU Lesser General Public License as
11  * published by the Free Software Foundation; either version 2.1 of
12  * the License, or (at your option) any later version.
13  *
14  * Libgcrypt is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU Lesser General Public License for more details.
18  *
19  * You should have received a copy of the GNU Lesser General Public
20  * License along with this program; if not, write to the Free Software
21  * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
22  *
23  * Note: This code is heavily based on the GNU MP Library.
24  *       Actually it's the same code with only minor changes in the
25  *       way the data is stored; this is to support the abstraction
26  *       of an optional secure memory allocation which may be used
27  *       to avoid revealing of sensitive data due to paging etc.
28  */
29
30
31 /*******************
32  * mpi_limb_t
33  * _gcry_mpih_addmul_1( mpi_ptr_t res_ptr,      (r26)
34  *                   mpi_ptr_t s1_ptr,       (r25)
35  *                   mpi_size_t s1_size,     (r24)
36  *                   mpi_limb_t s2_limb)     (r23)
37  *
38  * This runs at 11 cycles/limb on a PA7000.  With the used instructions, it
39  * can not become faster due to data cache contention after a store.  On the
40  * PA7100 it runs at 10 cycles/limb, and that can not be improved either,
41  * since only the xmpyu does not need the integer pipeline, so the only
42  * dual-issue we will get are addc+xmpyu.  Unrolling could gain a cycle/limb
43  * on the PA7100.
44  *
45  * There are some ideas described in mul1.S that applies to this code too.
46  */
47
48         .level          1.1
49
50         .code
51         .export         _gcry_mpih_addmul_1
52         .label          _gcry_mpih_addmul_1
53         .proc
54         .callinfo       frame=64,no_calls
55         .entry
56
57         ldo             64(%r30),%r30
58         fldws,ma        4(%r25),%fr5
59         stw             %r23,-16(%r30)          ; move s2_limb ...
60         addib,=         -1,%r24,L$just_one_limb
61          fldws          -16(%r30),%fr4          ; ... into fr4
62         add             %r0,%r0,%r0             ; clear carry
63         xmpyu           %fr4,%fr5,%fr6
64         fldws,ma        4(%r25),%fr7
65         fstds           %fr6,-16(%r30)
66         xmpyu           %fr4,%fr7,%fr8
67         ldw             -12(%r30),%r19          ; least significant limb in product
68         ldw             -16(%r30),%r28
69
70         fstds           %fr8,-16(%r30)
71         addib,=         -1,%r24,L$end
72          ldw            -12(%r30),%r1
73
74 ; Main loop
75         .label  L$loop
76         ldws            0(%r26),%r29
77         fldws,ma        4(%r25),%fr5
78         add             %r29,%r19,%r19
79         stws,ma         %r19,4(%r26)
80         addc            %r28,%r1,%r19
81         xmpyu           %fr4,%fr5,%fr6
82         ldw             -16(%r30),%r28
83         fstds           %fr6,-16(%r30)
84         addc            %r0,%r28,%r28
85         addib,<>        -1,%r24,L$loop
86          ldw            -12(%r30),%r1
87
88         .label  L$end
89         ldw             0(%r26),%r29
90         add             %r29,%r19,%r19
91         stws,ma         %r19,4(%r26)
92         addc            %r28,%r1,%r19
93         ldw             -16(%r30),%r28
94         ldws            0(%r26),%r29
95         addc            %r0,%r28,%r28
96         add             %r29,%r19,%r19
97         stws,ma         %r19,4(%r26)
98         addc            %r0,%r28,%r28
99         bv              0(%r2)
100          ldo            -64(%r30),%r30
101
102         .label L$just_one_limb
103         xmpyu           %fr4,%fr5,%fr6
104         ldw             0(%r26),%r29
105         fstds           %fr6,-16(%r30)
106         ldw             -12(%r30),%r1
107         ldw             -16(%r30),%r28
108         add             %r29,%r1,%r19
109         stw             %r19,0(%r26)
110         addc            %r0,%r28,%r28
111         bv              0(%r2)
112          ldo            -64(%r30),%r30
113
114         .exit
115         .procend
116
117