84b9d4abd09c1888802eb3eb31ebdffbddd7e350
[libgcrypt.git] / mpi / hppa1.1 / mpih-mul2.S
1 /* hppa1.1   addmul_1 -- Multiply a limb vector with a limb and add
2  *                       the result to a second limb vector.
3  *
4  *      Copyright (C) 1992, 1993, 1994, 1998,
5  *                    2001, 2002 Free Software Foundation, Inc.
6  *
7  * This file is part of Libgcrypt.
8  *
9  * Libgcrypt is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU Lesser General Public License as
11  * published by the Free Software Foundation; either version 2.1 of
12  * the License, or (at your option) any later version.
13  *
14  * Libgcrypt is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU Lesser General Public License for more details.
18  *
19  * You should have received a copy of the GNU Lesser General Public
20  * License along with this program; if not, write to the Free Software
21  * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
22  *
23  * Note: This code is heavily based on the GNU MP Library.
24  *       Actually it's the same code with only minor changes in the
25  *       way the data is stored; this is to support the abstraction
26  *       of an optional secure memory allocation which may be used
27  *       to avoid revealing of sensitive data due to paging etc.
28  */
29
30
31 /*******************
32  * mpi_limb_t
33  * _gcry_mpih_addmul_1( mpi_ptr_t res_ptr,      (r26)
34  *                   mpi_ptr_t s1_ptr,       (r25)
35  *                   mpi_size_t s1_size,     (r24)
36  *                   mpi_limb_t s2_limb)     (r23)
37  *
38  * This runs at 11 cycles/limb on a PA7000.  With the used instructions, it
39  * can not become faster due to data cache contention after a store.  On the
40  * PA7100 it runs at 10 cycles/limb, and that can not be improved either,
41  * since only the xmpyu does not need the integer pipeline, so the only
42  * dual-issue we will get are addc+xmpyu.  Unrolling could gain a cycle/limb
43  * on the PA7100.
44  *
45  * There are some ideas described in mul1.S that applies to this code too.
46  */
47
48         .code
49         .export         _gcry_mpih_addmul_1
50         .label          _gcry_mpih_addmul_1
51         .proc
52         .callinfo       frame=64,no_calls
53         .entry
54
55         ldo             64(%r30),%r30
56         fldws,ma        4(%r25),%fr5
57         stw             %r23,-16(%r30)          ; move s2_limb ...
58         addib,=         -1,%r24,L$just_one_limb
59          fldws          -16(%r30),%fr4          ; ... into fr4
60         add             %r0,%r0,%r0             ; clear carry
61         xmpyu           %fr4,%fr5,%fr6
62         fldws,ma        4(%r25),%fr7
63         fstds           %fr6,-16(%r30)
64         xmpyu           %fr4,%fr7,%fr8
65         ldw             -12(%r30),%r19          ; least significant limb in product
66         ldw             -16(%r30),%r28
67
68         fstds           %fr8,-16(%r30)
69         addib,=         -1,%r24,L$end
70          ldw            -12(%r30),%r1
71
72 ; Main loop
73         .label  L$loop
74         ldws            0(%r26),%r29
75         fldws,ma        4(%r25),%fr5
76         add             %r29,%r19,%r19
77         stws,ma         %r19,4(%r26)
78         addc            %r28,%r1,%r19
79         xmpyu           %fr4,%fr5,%fr6
80         ldw             -16(%r30),%r28
81         fstds           %fr6,-16(%r30)
82         addc            %r0,%r28,%r28
83         addib,<>        -1,%r24,L$loop
84          ldw            -12(%r30),%r1
85
86         .label  L$end
87         ldw             0(%r26),%r29
88         add             %r29,%r19,%r19
89         stws,ma         %r19,4(%r26)
90         addc            %r28,%r1,%r19
91         ldw             -16(%r30),%r28
92         ldws            0(%r26),%r29
93         addc            %r0,%r28,%r28
94         add             %r29,%r19,%r19
95         stws,ma         %r19,4(%r26)
96         addc            %r0,%r28,%r28
97         bv              0(%r2)
98          ldo            -64(%r30),%r30
99
100         .label L$just_one_limb
101         xmpyu           %fr4,%fr5,%fr6
102         ldw             0(%r26),%r29
103         fstds           %fr6,-16(%r30)
104         ldw             -12(%r30),%r1
105         ldw             -16(%r30),%r28
106         add             %r29,%r1,%r19
107         stw             %r19,0(%r26)
108         addc            %r0,%r28,%r28
109         bv              0(%r2)
110          ldo            -64(%r30),%r30
111
112         .exit
113         .procend
114
115