c4246e470dd5da2ae6b0ab93fa361e42560ee760
[libgcrypt.git] / mpi / hppa1.1 / mpih-mul3.S
1 /* hppa1.1   submul_1 -- Multiply a limb vector with a limb and add
2  *                       the result to a second limb vector.
3  *
4  *      Copyright (C) 1992, 1993, 1994, 1998, 
5  *                    2001, 2002 Free Software Foundation, Inc.
6  *
7  * This file is part of Libgcrypt.
8  *
9  * Libgcrypt is free software; you can redistribute it and/or modify
10  * it under the terms of the GNU Lesser General Public License as
11  * published by the Free Software Foundation; either version 2.1 of
12  * the License, or (at your option) any later version.
13  *
14  * Libgcrypt is distributed in the hope that it will be useful,
15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17  * GNU Lesser General Public License for more details.
18  *
19  * You should have received a copy of the GNU Lesser General Public
20  * License along with this program; if not, write to the Free Software
21  * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
22  *
23  * Note: This code is heavily based on the GNU MP Library.
24  *       Actually it's the same code with only minor changes in the
25  *       way the data is stored; this is to support the abstraction
26  *       of an optional secure memory allocation which may be used
27  *       to avoid revealing of sensitive data due to paging etc.
28  */
29
30
31 /*******************
32  * mpi_limb_t
33  * _gcry_mpih_submul_1( mpi_ptr_t res_ptr,      (r26)
34  *                   mpi_ptr_t s1_ptr,       (r25)
35  *                   mpi_size_t s1_size,     (r24)
36  *                   mpi_limb_t s2_limb)     (r23)
37  *
38  *
39  * This runs at 12 cycles/limb on a PA7000.  With the used instructions, it
40  * can not become faster due to data cache contention after a store.  On the
41  * PA7100 it runs at 11 cycles/limb, and that can not be improved either,
42  * since only the xmpyu does not need the integer pipeline, so the only
43  * dual-issue we will get are addc+xmpyu.  Unrolling could gain a cycle/limb
44  * on the PA7100.
45  *
46  * There are some ideas described in mul1.S that applies to this code too.
47  *
48  * It seems possible to make this run as fast as addmul_1, if we use
49  *       sub,>>= %r29,%r19,%r22
50  *       addi    1,%r28,%r28
51  * but that requires reworking the hairy software pipeline...
52  */
53
54
55         .code
56         .export         _gcry_mpih_submul_1
57         .label          _gcry_mpih_submul_1
58         .proc
59         .callinfo       frame=64,no_calls
60         .entry
61
62         ldo             64(%r30),%r30
63         fldws,ma        4(%r25),%fr5
64         stw             %r23,-16(%r30)          ; move s2_limb ...
65         addib,=         -1,%r24,L$just_one_limb
66          fldws          -16(%r30),%fr4          ; ... into fr4
67         add             %r0,%r0,%r0             ; clear carry
68         xmpyu           %fr4,%fr5,%fr6
69         fldws,ma        4(%r25),%fr7
70         fstds           %fr6,-16(%r30)
71         xmpyu           %fr4,%fr7,%fr8
72         ldw             -12(%r30),%r19          ; least significant limb in product
73         ldw             -16(%r30),%r28
74
75         fstds           %fr8,-16(%r30)
76         addib,=         -1,%r24,L$end
77          ldw            -12(%r30),%r1
78
79 ; Main loop
80         .label  L$loop
81         ldws            0(%r26),%r29
82         fldws,ma        4(%r25),%fr5
83         sub             %r29,%r19,%r22
84         add             %r22,%r19,%r0
85         stws,ma         %r22,4(%r26)
86         addc            %r28,%r1,%r19
87         xmpyu           %fr4,%fr5,%fr6
88         ldw             -16(%r30),%r28
89         fstds           %fr6,-16(%r30)
90         addc            %r0,%r28,%r28
91         addib,<>        -1,%r24,L$loop
92          ldw            -12(%r30),%r1
93
94         .label  L$end
95         ldw             0(%r26),%r29
96         sub             %r29,%r19,%r22
97         add             %r22,%r19,%r0
98         stws,ma         %r22,4(%r26)
99         addc            %r28,%r1,%r19
100         ldw             -16(%r30),%r28
101         ldws            0(%r26),%r29
102         addc            %r0,%r28,%r28
103         sub             %r29,%r19,%r22
104         add             %r22,%r19,%r0
105         stws,ma         %r22,4(%r26)
106         addc            %r0,%r28,%r28
107         bv              0(%r2)
108          ldo            -64(%r30),%r30
109
110         .label  L$just_one_limb
111         xmpyu           %fr4,%fr5,%fr6
112         ldw             0(%r26),%r29
113         fstds           %fr6,-16(%r30)
114         ldw             -12(%r30),%r1
115         ldw             -16(%r30),%r28
116         sub             %r29,%r1,%r22
117         add             %r22,%r1,%r0
118         stw             %r22,0(%r26)
119         addc            %r0,%r28,%r28
120         bv              0(%r2)
121          ldo            -64(%r30),%r30
122
123         .exit
124         .procend
125