nearly ready for 0.3.0
[libgcrypt.git] / mpi / mips3 / mpih-rshift.S
1 /* mips3    rshift
2  *      Copyright (C) 1995, 1998 Free Software Foundation, Inc.
3  *
4  * This file is part of GNUPG.
5  *
6  * GNUPG is free software; you can redistribute it and/or modify
7  * it under the terms of the GNU General Public License as published by
8  * the Free Software Foundation; either version 2 of the License, or
9  * (at your option) any later version.
10  *
11  * GNUPG is distributed in the hope that it will be useful,
12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14  * GNU General Public License for more details.
15  *
16  * You should have received a copy of the GNU General Public License
17  * along with this program; if not, write to the Free Software
18  * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
19  */
20
21 /*******************
22  * mpi_limb_t
23  * mpihelp_rshift( mpi_ptr_t wp,        ($4)
24  *                 mpi_ptr_t up,        ($5)
25  *                 mpi_size_t usize,    ($6)
26  *                 unsigned cnt)        ($7)
27  */
28
29         .text
30         .align  2
31         .globl  mpihelp_rshift
32         .ent    mpihelp_rshift
33 mpihelp_rshift:
34         .set    noreorder
35         .set    nomacro
36
37         ld      $10,0($5)       # load first limb
38         dsubu   $13,$0,$7
39         daddiu  $6,$6,-1
40         and     $9,$6,4-1       # number of limbs in first loop
41         beq     $9,$0,.L0       # if multiple of 4 limbs, skip first loop
42          dsll   $2,$10,$13      # compute function result
43
44         dsubu   $6,$6,$9
45
46 .Loop0: ld      $3,8($5)
47         daddiu  $4,$4,8
48         daddiu  $5,$5,8
49         daddiu  $9,$9,-1
50         dsrl    $11,$10,$7
51         dsll    $12,$3,$13
52         move    $10,$3
53         or      $8,$11,$12
54         bne     $9,$0,.Loop0
55          sd     $8,-8($4)
56
57 .L0:    beq     $6,$0,.Lend
58          nop
59
60 .Loop:  ld      $3,8($5)
61         daddiu  $4,$4,32
62         daddiu  $6,$6,-4
63         dsrl    $11,$10,$7
64         dsll    $12,$3,$13
65
66         ld      $10,16($5)
67         dsrl    $14,$3,$7
68         or      $8,$11,$12
69         sd      $8,-32($4)
70         dsll    $9,$10,$13
71
72         ld      $3,24($5)
73         dsrl    $11,$10,$7
74         or      $8,$14,$9
75         sd      $8,-24($4)
76         dsll    $12,$3,$13
77
78         ld      $10,32($5)
79         dsrl    $14,$3,$7
80         or      $8,$11,$12
81         sd      $8,-16($4)
82         dsll    $9,$10,$13
83
84         daddiu  $5,$5,32
85         or      $8,$14,$9
86         bgtz    $6,.Loop
87          sd     $8,-8($4)
88
89 .Lend:  dsrl    $8,$10,$7
90         j       $31
91         sd      $8,0($4)
92         .end    mpihelp_rshift
93