2003-02-07 Marcus Brinkmann <marcus@g10code.de>
[pinentry.git] / configure.ac
1 # configure.ac
2 # Copyright (C) 1999 Robert Bihlmeyer <robbe@orcus.priv.at>
3 # Copyright (C) 2001, 2002 g10 Code GmbH
4
5 # This file is part of PINENTRY.
6
7 # PINENTRY is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # PINENTRY is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20  
21 # (Process this file with autoconf to produce a configure script.)
22 AC_REVISION($Revision$)
23
24 AC_PREREQ(2.52)
25 # Remember to remove the "-cvs" suffix *before* a release and to bump the
26 # version number immediately *after* a release and to re-append the suffix.
27 AC_INIT(pinentry, 0.6.8, [gpa-dev@gnupg.org])
28 AM_CONFIG_HEADER(config.h)
29 AC_CONFIG_SRCDIR(pinentry/pinentry.h)
30 AM_INIT_AUTOMAKE($PACKAGE_NAME, $PACKAGE_VERSION)
31 AH_TOP([
32 /* We need this, because some autoconf tests rely on this (e.g. stpcpy)
33    and it should be used for new programs anyway */
34 #define _GNU_SOURCE  1
35 ])
36 AM_MAINTAINER_MODE
37
38 AC_CANONICAL_HOST
39
40 dnl Checks for programs.
41 missing_dir=`cd $ac_aux_dir && pwd`
42 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
43 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
44 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
45 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
46 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
47 AC_PROG_CC
48 AC_PROG_CPP
49 AC_PROG_INSTALL
50 AC_PROG_RANLIB
51
52 dnl Checks for compiler features.
53 if test "$GCC" = yes; then
54     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
55     CPPFLAGS="$CPPFLAGS -Wall"
56 fi
57
58 dnl Checks for library functions.
59 AC_CHECK_FUNCS(seteuid stpcpy)
60 GNUPG_CHECK_MLOCK
61
62 dnl Checks for libassuan.
63 AC_CHECK_FUNCS(fopencookie,,[
64     AC_MSG_ERROR([[
65 ***
66 *** fopencookie(3) is needed to build this package.
67 *** We will provide an replacement in a later release.
68 ***]])])
69
70 dnl Checks for libsecmem.
71 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
72 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
73
74 AC_PATH_PROG(SETCAP, setcap, :, "$PATH:/sbin:/usr/sbin")
75 AC_CHECK_LIB(cap, cap_set_proc, [
76   AC_DEFINE(USE_CAPABILITIES,1,[The capabilities support library is installed])
77   LIBCAP=-lcap
78 ])
79 AC_SUBST(LIBCAP)
80
81 dnl
82 dnl Check for curses pinentry program.
83 dnl
84 AC_ARG_ENABLE(pinentry-curses,
85             AC_HELP_STRING([--enable-pinentry-curses], [build curses pinentry]),
86             pinentry_curses=$enableval, pinentry_curses=maybe)
87 AC_ARG_ENABLE(fallback-curses,
88             AC_HELP_STRING([--enable-fallback-curses], [include curses fallback]),
89             fallback_curses=$enableval, fallback_curses=maybe)
90
91 dnl
92 dnl Checks for curses libraries.  Deal correctly with $pinentry_curses = maybe
93 dnl and $fallback_curses = maybe.
94 dnl
95 if test "$pinentry_curses" != "no" -o "$fallback_curses" != "no"; then
96   IU_LIB_CURSES
97 fi
98 if test "$LIBCURSES"; then
99   if test "$pinentry_curses" != "no"; then
100     pinentry_curses=yes
101   fi
102   if test "$fallback_curses" != "no"; then
103     fallback_curses=yes
104     AC_DEFINE(FALLBACK_CURSES, 1,
105               [The GUI pinentries should fall back to curses if X is not available.])
106   fi
107 else
108   if test "$pinentry_curses" = "yes" -o "$fallback_curses" = "yes"; then
109     AC_MSG_ERROR([[
110 *** The curses library is required. The latest version of
111 *** ncurses is always available from ftp://ftp.gnu.org/gnu/ncurses/.
112 ]])
113   fi
114   pinentry_curses=no
115   fallback_curses=no
116 fi
117 AM_CONDITIONAL(BUILD_LIBPINENTRY_CURSES, test "$pinentry_curses" = "yes" -o "$fallback_curses" = "yes")
118 AM_CONDITIONAL(BUILD_PINENTRY_CURSES, test "$pinentry_curses" = "yes")
119 AM_CONDITIONAL(FALLBACK_CURSES, test "$fallback_curses" = "yes")
120
121 if test "$pinentry_curses" = "yes" -o "$fallback_curses" = "yes"; then
122 dnl Additional checks for Curses pinentry.
123 AM_ICONV
124 fi
125
126 dnl
127 dnl Check for GTK+ pinentry program.
128 dnl
129 AC_ARG_ENABLE(pinentry-gtk,
130             AC_HELP_STRING([--enable-pinentry-gtk], [build GTK+ pinentry]),
131             pinentry_gtk=$enableval, pinentry_gtk=maybe)
132
133 dnl
134 dnl Checks for GTK+ libraries.  Deal correctly with $pinentry_gtk = maybe.
135 dnl
136 if test "$pinentry_gtk" != "no"; then
137 AM_PATH_GLIB(1.2.0,,
138 if test "$pinentry_gtk" = "yes"; then
139     AC_MSG_ERROR([[
140 *** GLIB 1.2.0 or newer is required. The latest version of GLIB
141 *** is always available from ftp://ftp.gtk.org/.
142 ]])
143 else
144     pinentry_gtk=no
145 fi)
146 fi
147
148 if test "$pinentry_gtk" != "no"; then
149 AM_PATH_GTK(1.2.0,
150     AC_DEFINE(HAVE_GTK, 1, [Defined if GTK is available]),
151 if test "$pinentry_gtk" = "yes"; then
152     AC_MSG_ERROR([[
153 *** GTK+ 1.2.0 or newer is required. The latest version of GTK+
154 *** is always available form ftp://ftp.gtk.org/.
155 ]])
156 else
157     pinentry_gtk=no
158 fi)
159 fi
160
161 dnl If we have come so far, GTK+ pinentry can be build.
162 if test "$pinentry_gtk" != "no"; then
163     pinentry_gtk=yes
164 fi
165 AM_CONDITIONAL(BUILD_PINENTRY_GTK, test "$pinentry_gtk" = "yes")
166
167 dnl if test "$pinentry_gtk" = "yes"; then
168 dnl Additional checks for GTK+ pinentry.
169 dnl End of additional checks for GTK+ pinentry.
170 dnl fi
171
172
173 dnl
174 dnl Check for Qt pinentry program.
175 dnl
176 AC_ARG_ENABLE(pinentry-qt,
177             AC_HELP_STRING([--enable-pinentry-qt], [build Qt pinentry]),
178             pinentry_qt=$enableval, pinentry_qt=maybe)
179 dnl
180 dnl Checks for Qt libraries.  Deal correctly with $pinentry_qt = maybe.
181 dnl
182 if test "$pinentry_qt" != "no"; then
183 QT_CHECK_COMPILERS
184 QT_PATH
185 if test $have_qt = "no"; then
186         if test $pinentry_qt = "yes"; then
187           AC_MSG_ERROR([Qt ($qt_minversion) $ac_qt_notfound not found. Please check your installation!
188           For more details about this problem, look at the end of config.log.$missing_qt_mt])
189         else
190           pinentry_qt="no"        
191         fi
192 fi
193 if test $have_moc = "no"; then
194         if test $pinentry_qt = "yes"; then
195         AC_MSG_ERROR([No Qt meta object compiler (moc) found!
196         Please check whether you installed Qt correctly.
197         You need to have a running moc binary.
198         configure tried to run $ac_cv_path_moc and the test didn't
199         succeed. If configure shouldn't have tried this one, set
200         the environment variable MOC to the right one before running
201         configure.
202         ])
203         else
204           pinentry_qt="no"        
205         fi
206 fi
207 fi
208
209 dnl If we have come so far, Qt pinentry can probably be build.
210 if test "$pinentry_qt" != "no"; then
211     pinentry_qt=yes
212 fi
213 AM_CONDITIONAL(BUILD_PINENTRY_QT, test "$pinentry_qt" = "yes")
214
215 dnl if test "$pinentry_qt" = "yes"; then
216 dnl dnl Additional checks for Qt pinentry.
217 dnl dnl End of checks for Qt pinentry.
218 dnl fi
219
220
221 AC_CONFIG_FILES([
222 assuan/Makefile
223 secmem/Makefile
224 pinentry/Makefile
225 curses/Makefile
226 gtk/Makefile
227 qt/Makefile
228 doc/Makefile
229 Makefile
230 ])
231
232 AC_OUTPUT
233
234 AC_MSG_NOTICE([
235         Pinentry v${VERSION} has been configured as follows:
236
237         Curses Pinentry: $pinentry_curses
238         GTK+ Pinentry: $pinentry_gtk
239         Qt Pinentry: $pinentry_qt
240
241         Fallback to Curses: $fallback_curses
242 ])