(configure_ac): Fixed version check (s/==/=/).
[pinentry.git] / configure.ac
1 # configure.ac
2 # Copyright (C) 1999 Robert Bihlmeyer <robbe@orcus.priv.at>
3 # Copyright (C) 2001, 2002, 2003, 2004 g10 Code GmbH
4
5 # This file is part of PINENTRY.
6
7 # PINENTRY is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11
12 # PINENTRY is distributed in the hope that it will be useful,
13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 # GNU General Public License for more details.
16
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
20  
21 # (Process this file with autoconf to produce a configure script.)
22 AC_PREREQ(2.57)
23 min_automake_version="1.7.6"
24
25 # Remember to remove the "-cvs" suffix *before* a release and to bump the
26 # version number immediately *after* a release and to re-append the suffix.
27 AC_INIT(pinentry, 0.7.1-cvs, [gpa-dev@gnupg.org])
28 AM_CONFIG_HEADER(config.h)
29 AC_CONFIG_SRCDIR(pinentry/pinentry.h)
30 AM_INIT_AUTOMAKE($PACKAGE_NAME, $PACKAGE_VERSION)
31 AH_TOP([
32 /* We need this, because some autoconf tests rely on this (e.g. stpcpy)
33    and it should be used for new programs anyway */
34 #define _GNU_SOURCE  1
35 ])
36 AM_MAINTAINER_MODE
37
38 AC_CANONICAL_HOST
39
40 dnl Checks for programs.
41 missing_dir=`cd $ac_aux_dir && pwd`
42 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
43 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
44 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
45 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
46 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
47 AC_PROG_CC
48 AC_PROG_CPP
49 AC_PROG_INSTALL
50 AC_PROG_RANLIB
51 # We need to check for cplusplus here becuase we may not do the test
52 # for Qt and autoconf does does not allow that.
53 AC_PROG_CXX
54
55 dnl Checks for compiler features.
56 if test "$GCC" = yes; then
57     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
58     CPPFLAGS="$CPPFLAGS -Wall"
59 fi
60
61 dnl Checks for library functions.
62 AC_CHECK_FUNCS(seteuid stpcpy mmap)
63 GNUPG_CHECK_MLOCK
64
65 dnl Checks for libassuan.
66 dnl -> None required becuase we use a stripped down version of libassuan.
67
68
69 dnl Checks for libsecmem.
70 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
71 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
72
73 AC_PATH_PROG(SETCAP, setcap, :, "$PATH:/sbin:/usr/sbin")
74 AC_CHECK_LIB(cap, cap_set_proc, [
75   AC_DEFINE(USE_CAPABILITIES,1,[The capabilities support library is installed])
76   LIBCAP=-lcap
77 ])
78 AC_SUBST(LIBCAP)
79
80 dnl
81 dnl Check for curses pinentry program.
82 dnl
83 AC_ARG_ENABLE(pinentry-curses,
84             AC_HELP_STRING([--enable-pinentry-curses], [build curses pinentry]),
85             pinentry_curses=$enableval, pinentry_curses=maybe)
86 AC_ARG_ENABLE(fallback-curses,
87             AC_HELP_STRING([--enable-fallback-curses], [include curses fallback]),
88             fallback_curses=$enableval, fallback_curses=maybe)
89
90 dnl
91 dnl Checks for curses libraries.  Deal correctly with $pinentry_curses = maybe
92 dnl and $fallback_curses = maybe.
93 dnl
94 if test "$pinentry_curses" != "no" -o "$fallback_curses" != "no"; then
95   IU_LIB_CURSES
96 fi
97 if test "$LIBCURSES"; then
98   if test "$pinentry_curses" != "no"; then
99     pinentry_curses=yes
100   fi
101   if test "$fallback_curses" != "no"; then
102     fallback_curses=yes
103     AC_DEFINE(FALLBACK_CURSES, 1,
104               [The GUI pinentries should fall back to curses if X is not available.])
105   fi
106 else
107   if test "$pinentry_curses" = "yes" -o "$fallback_curses" = "yes"; then
108     AC_MSG_ERROR([[
109 *** The curses library is required. The latest version of
110 *** ncurses is always available from ftp://ftp.gnu.org/gnu/ncurses/.
111 ]])
112   fi
113   pinentry_curses=no
114   fallback_curses=no
115 fi
116 AM_CONDITIONAL(BUILD_LIBPINENTRY_CURSES, test "$pinentry_curses" = "yes" -o "$fallback_curses" = "yes")
117 AM_CONDITIONAL(BUILD_PINENTRY_CURSES, test "$pinentry_curses" = "yes")
118 AM_CONDITIONAL(FALLBACK_CURSES, test "$fallback_curses" = "yes")
119
120 if test "$pinentry_curses" = "yes" -o "$fallback_curses" = "yes"; then
121 dnl Additional checks for Curses pinentry.
122 AM_ICONV
123 fi
124
125 dnl
126 dnl Check for GTK+ pinentry program.
127 dnl
128 AC_ARG_ENABLE(pinentry-gtk,
129             AC_HELP_STRING([--enable-pinentry-gtk], [build GTK+ pinentry]),
130             pinentry_gtk=$enableval, pinentry_gtk=maybe)
131
132 dnl
133 dnl Checks for GTK+ libraries.  Deal correctly with $pinentry_gtk = maybe.
134 dnl
135 if test "$pinentry_gtk" != "no"; then
136 AM_PATH_GLIB(1.2.0,,
137 if test "$pinentry_gtk" = "yes"; then
138     AC_MSG_ERROR([[
139 *** GLIB 1.2.0 or newer is required. The latest version of GLIB
140 *** is always available from ftp://ftp.gtk.org/.
141 ]])
142 else
143     pinentry_gtk=no
144 fi)
145 fi
146
147 if test "$pinentry_gtk" != "no"; then
148 AM_PATH_GTK(1.2.0,
149     AC_DEFINE(HAVE_GTK, 1, [Defined if GTK is available]),
150 if test "$pinentry_gtk" = "yes"; then
151     AC_MSG_ERROR([[
152 *** GTK+ 1.2.0 or newer is required. The latest version of GTK+
153 *** is always available form ftp://ftp.gtk.org/.
154 ]])
155 else
156     pinentry_gtk=no
157 fi)
158 fi
159
160 dnl If we have come so far, GTK+ pinentry can be build.
161 if test "$pinentry_gtk" != "no"; then
162     pinentry_gtk=yes
163 fi
164 AM_CONDITIONAL(BUILD_PINENTRY_GTK, test "$pinentry_gtk" = "yes")
165
166 dnl if test "$pinentry_gtk" = "yes"; then
167 dnl Additional checks for GTK+ pinentry.
168 dnl End of additional checks for GTK+ pinentry.
169 dnl fi
170
171
172 dnl
173 dnl Check for Qt pinentry program.
174 dnl
175 AC_ARG_ENABLE(pinentry-qt,
176             AC_HELP_STRING([--enable-pinentry-qt], [build Qt pinentry]),
177             pinentry_qt=$enableval, pinentry_qt=maybe)
178 dnl
179 dnl Checks for Qt libraries.  Deal correctly with $pinentry_qt = maybe.
180 dnl
181 if test "$pinentry_qt" != "no"; then
182 QT_CHECK_COMPILERS
183 QT_PATH
184 if test $have_qt = "no"; then
185         if test $pinentry_qt = "yes"; then
186           AC_MSG_ERROR([Qt ($qt_minversion) $ac_qt_notfound not found. Please check your installation!
187           For more details about this problem, look at the end of config.log.$missing_qt_mt])
188         else
189           pinentry_qt="no"        
190         fi
191 fi
192 if test $have_moc = "no"; then
193         if test $pinentry_qt = "yes"; then
194         AC_MSG_ERROR([No Qt meta object compiler (moc) found!
195         Please check whether you installed Qt correctly.
196         You need to have a running moc binary.
197         configure tried to run $ac_cv_path_moc and the test didn't
198         succeed. If configure shouldn't have tried this one, set
199         the environment variable MOC to the right one before running
200         configure.
201         ])
202         else
203           pinentry_qt="no"        
204         fi
205 fi
206 fi
207
208 dnl If we have come so far, Qt pinentry can probably be build.
209 if test "$pinentry_qt" != "no"; then
210     pinentry_qt=yes
211 fi
212 AM_CONDITIONAL(BUILD_PINENTRY_QT, test "$pinentry_qt" = "yes")
213
214 dnl if test "$pinentry_qt" = "yes"; then
215 dnl dnl Additional checks for Qt pinentry.
216 dnl dnl End of checks for Qt pinentry.
217 dnl fi
218
219
220 AC_CONFIG_FILES([
221 assuan/Makefile
222 secmem/Makefile
223 pinentry/Makefile
224 curses/Makefile
225 gtk/Makefile
226 qt/Makefile
227 doc/Makefile
228 Makefile
229 ])
230
231 AC_OUTPUT
232
233 AC_MSG_NOTICE([
234         Pinentry v${VERSION} has been configured as follows:
235
236         Curses Pinentry: $pinentry_curses
237         GTK+ Pinentry: $pinentry_gtk
238         Qt Pinentry: $pinentry_qt
239
240         Fallback to Curses: $fallback_curses
241 ])