speedo: Revamped speedo and include a w32 installer.
[gnupg.git] / build-aux / speedo / w32 / inst.nsi
1 # inst.nsi - Installer for GnuPG on Windows.      -*- coding: latin-1; -*-
2 # Copyright (C) 2005, 2014 g10 Code GmbH
3 #
4 # This file is part of GnuPG.
5 #
6 # GnuPG is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 3 of the License, or
9 # (at your option) any later version.
10 #
11 # GnuPG is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15 #
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, see <http://www.gnu.org/licenses/>.
18
19 # Macros to provide for invocation:
20 #  INST_DIR
21 #  INST6_DIR
22 #  BUILD_DIR
23 #  TOP_SRCDIR
24 #  W32_SRCDIR
25 #  BUILD_ISODATE
26 #  VERSION
27 #  PROD_VERSION
28
29 !cd "${INST_DIR}"
30 !addincludedir "${W32_SRCDIR}"
31 !addplugindir "${BUILD_DIR}"
32
33 # The package name and version.  PRETTY_PACKAGE is a user visible name
34 # only while PACKAGE is useful for filenames etc.  PROD_VERSION is the
35 # product version and needs to be in the format "MAJ.MIN.MIC.BUILDNR".
36 !define PACKAGE "gnupg"
37 !define PACKAGE_SHORT "gnupg"
38 !define PRETTY_PACKAGE "GNU Privacy Guard"
39 !define PRETTY_PACKAGE_SHORT "GnuPG"
40 !define COMPANY "The GnuPG Project"
41 !define COPYRIGHT "Copyright (C) 2014 The GnuPG Project"
42 !define DESCRIPTION "GnuPG: The GNU Privacy Guard for Windows"
43
44 !define INSTALL_DIR "GnuPG"
45
46 !define WELCOME_TITLE_ENGLISH \
47  "Welcome to the installation of GnuPG"
48
49 !define WELCOME_TITLE_GERMAN \
50  "Willkommen bei der Installation von GnuPG"
51
52 !define ABOUT_ENGLISH \
53  "GnuPG is the mostly used software for mail and data encryption. \
54   It can be used to encrypt data and to create digital signatures. \
55   It includes an advanced key management facility and is compliant \
56   with the proposed OpenPGP Internet standard as described in RFC-4880. \
57   \r\n\r\n$_CLICK \
58   \r\n\r\n\r\n\r\n\r\nThis is GnuPG version ${VERSION}\r\n\
59   file version ${PROD_VERSION}\r\n\
60   release date ${BUILD_ISODATE}"
61 !define ABOUT_GERMAN \
62  "GnuPG is die häufigst verwendete Software zur Mail- und Datenverschlüsselung.\
63    \r\n\r\n$_CLICK \
64    \r\n\r\n\r\n\r\n\r\nDies ist GnuPG Version ${VERSION}\r\n\
65    Dateiversion ${PROD_VERSION}\r\n\
66    Releasedatum ${BUILD_ISODATE}"
67
68
69 # The copyright license of the package.  Define only one of these.
70 !define LICENSE_GPL
71
72 # Select the best compression algorithm available.  The dictionary
73 # size is the default (8 MB).
74 !ifndef SOURCES
75 SetCompressor lzma
76 # SetCompressorDictSize 8
77 !endif
78
79 # Include the generic parts.
80 !define HAVE_STARTMENU
81
82 # We use the modern UI.
83 !include "MUI.nsh"
84
85 # Some helper some
86 !include "LogicLib.nsh"
87 !include "x64.nsh"
88
89 # Set the package name.  Note that this name should not be suffixed
90 # with the version because this would get displayed in the start menu.
91 # Given that a slash in the name troubles Windows startmenu creation
92 # we set the Startmenu explicit below.
93 Name "${PRETTY_PACKAGE}"
94
95 # Set the output filename.
96 OutFile "${PACKAGE}-${VERSION}.exe"
97
98 #Fixme: Do we need a logo
99 #Icon "${TOP_SRCDIR}/doc/logo/gnupg-logo-icon.ico"
100 #UninstallIcon "${TOP_SRCDIR}/doc/logo/gnupg-logo-icon.ico"
101
102 # Set the installation directory.
103 !ifndef INSTALL_DIR
104 !define INSTALL_DIR "GnuPG"
105 !endif
106 InstallDir "$PROGRAMFILES\GNU\${INSTALL_DIR}"
107
108 InstallDirRegKey HKLM "Software\GNU\${PACKAGE_SHORT}" "Install Directory"
109
110
111 # Add version information to the file properties.
112 VIProductVersion "${PROD_VERSION}"
113 VIAddVersionKey "ProductName" "${PRETTY_PACKAGE_SHORT} (${VERSION})"
114 VIAddVersionKey "Comments" \
115    "GnuPG is Free Software; you can redistribute it  \
116     and/or modify it under the terms of the GNU General Public License.  \
117     You should have received a copy of the GNU General Public License  \
118     along with this software; if not, write to the Free Software  \
119     Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston,  \
120     MA 02110-1301, USA"
121 VIAddVersionKey "CompanyName" "${COMPANY}"
122 VIAddVersionKey "LegalTrademarks" ""
123 VIAddVersionKey "LegalCopyright" "${COPYRIGHT}"
124 VIAddVersionKey "FileDescription" "${DESCRIPTION}"
125 VIAddVersionKey "FileVersion" "${PROD_VERSION}"
126
127 # Interface Settings
128
129 # !define MUI_ABORTWARNING
130 !define MUI_FINISHPAGE_NOAUTOCLOSE
131 !define MUI_UNFINISHPAGE_NOAUTOCLOSE
132
133 #!define MUI_HEADERIMAGE
134 #!define MUI_HEADERIMAGE_BITMAP \
135 #               "${TOP_SRCDIR}/doc/logo/gnupg-logo-150x57.bmp"
136 #!define MUI_WELCOMEFINISHPAGE_BITMAP \
137 #               "${TOP_SRCDIR}/doc/logo/gnupg-logo-164x314.bmp"
138
139 # Remember the installer language
140 !define MUI_LANGDLL_REGISTRY_ROOT "HKCU"
141 !define MUI_LANGDLL_REGISTRY_KEY "Software\GNU\GnuPG"
142 !define MUI_LANGDLL_REGISTRY_VALUENAME "Installer Language"
143
144 #
145 # The list of wizard pages.
146 #
147 !define MUI_WELCOMEPAGE_TITLE "$(T_WelcomeTitle)"
148 !define MUI_WELCOMEPAGE_TEXT  "$(T_About)"
149 !insertmacro MUI_PAGE_WELCOME
150
151 !define MUI_LICENSEPAGE_BUTTON "$(^NextBtn)"
152 !define MUI_PAGE_HEADER_SUBTEXT "$(T_GPLHeader)"
153 !define MUI_LICENSEPAGE_TEXT_BOTTOM "$(T_GPLShort)"
154 !insertmacro MUI_PAGE_LICENSE "${TOP_SRCDIR}/COPYING"
155
156 !define MUI_PAGE_CUSTOMFUNCTION_SHOW PrintNonAdminWarning
157 !insertmacro MUI_PAGE_COMPONENTS
158
159 !define MUI_PAGE_CUSTOMFUNCTION_LEAVE CheckExistingVersion
160 !insertmacro MUI_PAGE_DIRECTORY
161
162 !ifdef HAVE_STARTMENU
163
164 Page custom CustomPageOptions
165
166 Var STARTMENU_FOLDER
167
168 !define MUI_PAGE_CUSTOMFUNCTION_PRE CheckIfStartMenuWanted
169 !define MUI_STARTMENUPAGE_NODISABLE
170 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKCU"
171 !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\GNU\GnuPG"
172 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
173 # We need to set the Startmenu name explicitly because a slash in the
174 # name is not possible.
175 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "GnuPG"
176
177 !insertmacro MUI_PAGE_STARTMENU Application $STARTMENU_FOLDER
178
179 !endif
180
181 !define MUI_PAGE_CUSTOMFUNCTION_PRE PrintCloseOtherApps
182 !insertmacro MUI_PAGE_INSTFILES
183
184 #!define MUI_PAGE_CUSTOMFUNCTION_PRE ShowFinalWarnings
185 !define MUI_FINISHPAGE_SHOWREADME "README.txt"
186 !define MUI_FINISHPAGE_SHOWREADME_TEXT "$(T_ShowReadme)"
187 #!define MUI_FINISHPAGE_RUN
188 #!define MUI_FINISHPAGE_RUN_FUNCTION RunOnFinish
189 #!define MUI_FINISHPAGE_RUN_TEXT "$(T_RunKeyManager)"
190 #!define MUI_FINISHPAGE_RUN_NOTCHECKED
191 !define MUI_FINISHPAGE_LINK "$(T_MoreInfo)"
192 !define MUI_FINISHPAGE_LINK_LOCATION "$(T_MoreInfoURL)"
193 !insertmacro MUI_PAGE_FINISH
194
195
196 # Uninstaller pages.
197
198 !insertmacro MUI_UNPAGE_CONFIRM
199 !insertmacro MUI_UNPAGE_INSTFILES
200
201
202 #Page license
203 #Page components
204 #Page directory
205 #Page instfiles
206 #UninstPage uninstConfirm
207 #UninstPage instfiles
208
209
210 # Language support.  This has to be done after defining the pages, but
211 # before defining the translation strings.  Confusing.
212
213 !insertmacro MUI_LANGUAGE "English"
214 !insertmacro MUI_LANGUAGE "German"
215
216 !insertmacro MUI_RESERVEFILE_LANGDLL
217 !insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
218 ReserveFile "${BUILD_DIR}\g4wihelp.dll"
219 #ReserveFile "${TOP_SRCDIR}\doc\logo\gnupg-logo-400px.bmp"
220 #ReserveFile "${W32_SRCDIR}\gnupg-splash.wav"
221 ReserveFile "${TOP_SRCDIR}\COPYING"
222 ReserveFile "${BUILD_DIR}\inst-options.ini"
223 #ReserveFile "${TOP_SRCDIR}\doc\logo\gnupg-logo-164x314.bmp"
224
225 # Language support
226
227 LangString T_LangCode ${LANG_ENGLISH} "en"
228 LangString T_LangCode ${LANG_GERMAN}  "de"
229
230
231 # The WelcomeTitle is displayed on the first page.
232 LangString T_WelcomeTitle ${LANG_ENGLISH} "${WELCOME_TITLE_ENGLISH}"
233 LangString T_WelcomeTitle ${LANG_GERMAN} "${WELCOME_TITLE_GERMAN}"
234
235 # The About string as displayed on the first page.
236 LangString T_About ${LANG_ENGLISH} "${ABOUT_ENGLISH}"
237 LangString T_About ${LANG_GERMAN} "${ABOUT_GERMAN}"
238
239 # Startup page
240 LangString T_GPLHeader ${LANG_ENGLISH} \
241   "This software is licensed under the terms of the GNU General Public \
242    License (GNU GPL)."
243 LangString T_GPLHeader ${LANG_GERMAN}} \
244   "Diese Software ist unter der GNU General Public License \
245    (GNU GPL) lizensiert."
246
247 LangString T_GPLShort ${LANG_ENGLISH} \
248   "In short: You are allowed to run this software for any purpose. \
249    You may distribute it as long as you give the recipients the same \
250    rights you have received."
251 LangString T_GPLShort ${LANG_GERMAN} \
252   "In aller Kürze: Sie haben das Recht, die Software zu jedem Zweck \
253    einzusetzen.  Sie können die Software weitergeben, sofern Sie dem \
254    Empfänger dieselben Rechte einräumen, die auch Sie erhalten haben."
255
256 LangString T_RunKeyManager ${LANG_ENGLISH} \
257    "Run the key manager"
258 LangString T_RunKeyManager ${LANG_GERMAN} \
259    "Die Schlüsselverwaltung aufrufen"
260
261 LangString T_MoreInfo ${LANG_ENGLISH} \
262    "Click here for GnuPG's website"
263 LangString T_MoreInfo ${LANG_GERMAN} \
264    "Hier klicken um zur GnuPG Homepage zu gelangen"
265 LangString T_MoreInfoURL ${LANG_ENGLISH} "https://gnupg.org"
266 LangString T_MoreInfoURL ${LANG_GERMAN}  "https://gnupg.org"
267
268 LangString T_ShowReadme ${LANG_ENGLISH} \
269    "Show the README file"
270 LangString T_ShowReadme ${LANG_GERMAN} \
271    "Die README Datei anzeigen"
272
273 LangString T_NoKeyManager ${LANG_ENGLISH} \
274    "No key manager has been installed, thus we can't run one now."
275 LangString T_NoKeyManager ${LANG_GERMAN} \
276    "Es wurde keine Schlüsselverwaltung installiert. \
277     Deswegen kann sie jetzt auch nicht ausgeführt werden."
278
279 # Functions
280
281 # Custom functions and macros for this installer.
282 LangString T_AlreadyRunning ${LANG_ENGLISH} \
283    "An instance of this installer is already running."
284 LangString T_AlreadyRunning ${LANG_GERMAN} \
285    "Ein Exemplar dieses Installers läuft bereits."
286
287 Function G4wRunOnce
288   Push $R0
289   StrCpy $R0 "gnupg"
290   g4wihelp::runonce
291   StrCmp $R0 0 +3
292      MessageBox MB_OK $(T_AlreadyRunning)
293      Abort
294   Pop $R0
295 FunctionEnd
296
297 #
298 # Control function for the Custom page to select special
299 # install options.
300 #
301 Function CustomPageOptions
302   !insertmacro MUI_HEADER_TEXT "$(T_InstallOptions)" "$(T_InstallOptLinks)"
303
304   # Note, that the default selection is done in the ini file
305   !insertmacro MUI_INSTALLOPTIONS_WRITE "${BUILD_DIR}/inst-options.ini" \
306         "Field 1" "Text"  "$(T_InstOptLabelA)"
307   !insertmacro MUI_INSTALLOPTIONS_WRITE "${BUILD_DIR}/inst-options.ini" \
308         "Field 2" "Text"  "$(T_InstOptFieldA)"
309   !insertmacro MUI_INSTALLOPTIONS_WRITE "${BUILD_DIR}/inst-options.ini" \
310         "Field 3" "Text"  "$(T_InstOptFieldB)"
311   !insertmacro MUI_INSTALLOPTIONS_WRITE "${BUILD_DIR}/inst-options.ini" \
312         "Field 4" "Text"  "$(T_InstOptFieldC)"
313   !insertmacro MUI_INSTALLOPTIONS_WRITE "${BUILD_DIR}/inst-options.ini" \
314         "Field 5" "Text"  "$(T_InstOptLabelB)"
315
316   !insertmacro MUI_INSTALLOPTIONS_DISPLAY "${BUILD_DIR}/inst-options.ini"
317 FunctionEnd
318
319
320 # Check whether GnuPG has already been installed.  This is called as
321 # a leave function from the directory page.  A call to abort will get
322 # back to the directory selection.
323 Function CheckExistingVersion
324   ClearErrors
325   FileOpen $0 "$INSTDIR\VERSION" r
326   IfErrors nexttest
327   FileRead $0 $R0
328   FileRead $0 $R1
329   FileClose $0
330
331   Push $R1
332   Call TrimNewLines
333   Pop $R1
334
335   MessageBox MB_YESNO "$(T_FoundExistingVersion)" IDYES leave
336   Abort
337
338  nexttest:
339   ClearErrors
340   ReadRegStr $0 HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GnuPG" "DisplayVersion"
341   IfErrors leave 0
342      MessageBox MB_YESNO "$(T_FoundExistingVersionB)" IDYES leave
343      Abort
344
345  leave:
346 FunctionEnd
347
348
349
350 # PrintNonAdminWarning
351
352 # Check whether the current user is in the Administrator group or an
353 # OS version without the need for an Administrator is in use.  Print a
354 # diagnostic if this is not the case and abort installation.
355 Function PrintNonAdminWarning
356   ClearErrors
357   UserInfo::GetName
358   IfErrors leave
359   Pop $0
360   UserInfo::GetAccountType
361   Pop $1
362   StrCmp $1 "Admin" leave +1
363   MessageBox MB_OK "$(T_AdminNeeded)"
364   Quit
365
366  leave:
367 FunctionEnd
368
369
370 # Check whether the start menu is actually wanted.
371
372 Function CheckIfStartMenuWanted
373   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "${BUILD_DIR}/inst-options.ini" \
374         "Field 2" "State"
375   IntCmp $R0 1 +2
376     Abort
377 FunctionEnd
378
379
380 # Check whether this is a reinstall and popup a message box to explain
381 # that it is better to close other apps before continuing
382 Function PrintCloseOtherApps
383     IfFileExists $INSTDIR\bin\gpg.exe print_warning
384     IfFileExists $INSTDIR\bin\gpa.exe print_warning
385     Return
386    print_warning:
387     MessageBox MB_OK|MB_ICONEXCLAMATION "$(T_CloseOtherApps)"
388
389 FunctionEnd
390
391 # Called right before the final page to show more warnings.
392 #Function ShowFinalWarnings
393 #   leave:
394 #FunctionEnd
395
396 #-----------------------------------------------
397 # Strings pertaining to the install options page
398 #-----------------------------------------------
399
400 # Installation options title
401 LangString T_InstallOptions ${LANG_ENGLISH} "Install Options"
402 LangString T_InstallOptions ${LANG_GERMAN}  "Installationsoptionen"
403
404 # Installation options subtitle 1
405 LangString T_InstallOptLinks ${LANG_ENGLISH} "Start links"
406 LangString T_InstallOptLinks ${LANG_GERMAN}  "Startlinks"
407
408 LangString T_InstOptLabelA  ${LANG_ENGLISH} \
409      "Please select where GnuPG shall install links:"
410 LangString T_InstOptLabelA  ${LANG_GERMAN} \
411      "Bitte wählen Sie, welche Verknüpfungen angelegt werden sollen:"
412
413 LangString T_InstOptLabelB  ${LANG_ENGLISH} \
414      "(Only programs will be linked into the quick launch bar.)"
415 LangString T_InstOptLabelB  ${LANG_GERMAN} \
416      "(In die Schnellstartleiste werden nur Verknüpfungen für \
417       Programme angelegt.) "
418
419 LangString T_InstOptFieldA  ${LANG_ENGLISH} \
420      "Start Menu"
421 LangString T_InstOptFieldA  ${LANG_GERMAN} \
422      "Startmenü"
423
424 LangString T_InstOptFieldB  ${LANG_ENGLISH} \
425      "Desktop"
426 LangString T_InstOptFieldB  ${LANG_GERMAN} \
427      "Arbeitsfläche"
428
429 LangString T_InstOptFieldC  ${LANG_ENGLISH} \
430      "Quick Launch Bar"
431 LangString T_InstOptFieldC  ${LANG_GERMAN} \
432      "Schnellstartleiste"
433
434 #------------------------------------------------
435 # String pertaining to the existing version check
436 #------------------------------------------------
437 LangString T_FoundExistingVersion ${LANG_ENGLISH} \
438      "Version $R1 has already been installed.  $\r$\n\
439       Do you want to overwrite it with version ${VERSION}?"
440 LangString T_FoundExistingVersion ${LANG_GERMAN} \
441      "Version $R1 ist hier bereits installiert. $\r$\n\
442       Möchten Sie diese mit Version ${VERSION} überschreiben? $\r$\n\
443        $\r$\n\
444       (Sie können in jedem Fall mit JA antworten, falls es sich um \
445        eine neuere oder dieselbe Version handelt.)"
446 LangString T_FoundExistingVersionB ${LANG_ENGLISH} \
447      "A version of GnuPG has already been installed on the system. \
448       There will be no problem installing and thus overwriting this \
449       Version. $\r$\n\
450        $\r$\n\
451       Do you want to continue installing GnuPG?"
452 LangString T_FoundExistingVersionB ${LANG_GERMAN} \
453      "Eine Version von GnuPG ist hier bereits installiert. \
454       Es ist problemlos möglich, die Installation fortzuführen.  $\r$\n\
455         $\r$\n\
456       Möchten die die Installation von GnuPG fortführen?"
457
458
459
460 # From Function PrintNonAdminWarning
461 LangString T_AdminNeeded ${LANG_ENGLISH} \
462    "Warning: Administrator permissions required for a successful installation"
463 LangString T_AdminNeeded ${LANG_GERMAN} \
464    "Achtung: Für eine erfolgreiche Installation werden \
465     Administratorrechte benötigt."
466
467 # From Function PrintCloseOtherApps
468 LangString T_CloseOtherApps ${LANG_ENGLISH} \
469    "Please make sure that other applications are not running. \
470     GnuPG will try to install anyway but a reboot may be required."
471 LangString T_CloseOtherApps ${LANG_GERMAN} \
472    "Bitte stellen Sie sicher, daß alle anderen Anwendugen geschlossen \
473     sind.  GnuPG wird auf jeden Fall versuchen, eine Installation \
474     durchzuführen; es ist dann aber u.U. notwendig, das System neu zu starten."
475
476
477 # TrimNewlines  - taken from the NSIS reference
478 # input, top of stack  (e.g. whatever$\r$\n)
479 # output, top of stack (replaces, with e.g. whatever)
480 # modifies no other variables.
481 Function TrimNewlines
482    Exch $R0
483    Push $R1
484    Push $R2
485    StrCpy $R1 0
486
487  loop:
488    IntOp $R1 $R1 - 1
489    StrCpy $R2 $R0 1 $R1
490    StrCmp $R2 "$\r" loop
491    StrCmp $R2 "$\n" loop
492    IntOp $R1 $R1 + 1
493    IntCmp $R1 0 no_trim_needed
494    StrCpy $R0 $R0 $R1
495
496  no_trim_needed:
497    Pop $R2
498    Pop $R1
499    Exch $R0
500 FunctionEnd
501
502 #
503 # Define the installer sections.
504 #
505
506 Section "-gnupginst"
507   SetOutPath "$INSTDIR"
508
509   File "${BUILD_DIR}/README.txt"
510
511   # Write a version file.
512   FileOpen $0 "$INSTDIR\VERSION" w
513   FileWrite $0 "${PACKAGE}$\r$\n"
514   FileWrite $0 "${VERSION}$\r$\n"
515   FileClose $0
516
517   WriteRegStr HKLM "Software\GNU\GnuPG" "Install Directory" $INSTDIR
518
519   # If we are reinstalling, try to kill a possible running gpa using
520   # an already installed gpa.
521   ifFileExists "$INSTDIR\bin\gpa.exe"  0 no_uiserver
522     ExecWait '"$INSTDIR\bin\gpa" --stop-server'
523
524   no_uiserver:
525
526   # If we are reinstalling, try to kill a possible running agent using
527   # an already installed gpgconf.
528   ifFileExists "$INSTDIR\bin\gpgconf.exe"  0 no_gpgconf
529     ExecWait '"$INSTDIR\bin\gpgconf" --kill gpg-agent'
530
531   no_gpgconf:
532 SectionEnd
533
534 LangString DESC_Menu_gnupg_readme ${LANG_ENGLISH} \
535    "General information on GnuPG"
536 LangString DESC_Menu_gnupg_readme ${LANG_GERMAN} \
537    "Allgemeine Informationen zu GnuPG"
538
539
540 Section "GnuPG" SEC_gnupg
541   SectionIn RO
542
543   SetOutPath "$INSTDIR\bin"
544   File /oname=gpg.exe "bin/gpg2.exe"
545   File "bin/gpgsm.exe"
546   File "bin/gpgconf.exe"
547   File "bin/gpg-connect-agent.exe"
548
549   ClearErrors
550   SetOverwrite try
551   File "bin/gpg-agent.exe"
552   SetOverwrite lastused
553   ifErrors 0 +3
554       File /oname=gpg-agent.exe.tmp "bin/gpg-agent.exe"
555       Rename /REBOOTOK gpg-agent.exe.tmp gpg-agent.exe
556
557   SetOutPath "$INSTDIR\share\gnupg"
558   File "share/gnupg/gpg-conf.skel"
559 SectionEnd
560
561
562 LangString DESC_SEC_gnupg ${LANG_ENGLISH} \
563    "The GnuPG Core is the actual encrypt core and a set of command \
564     line utilities."
565 LangString DESC_SEC_gnupg ${LANG_GERMAN} \
566    "Der GnuPG Core ist, wie der Name schon sagt, der Kernbestandteil \
567     dieser Software.  Der GnuPG Core stellt die eigentliche \
568     Verschlüsselung sowie die Verwaltung der Schlüssel bereit."
569
570 LangString DESC_Menu_gnupg_manual ${LANG_ENGLISH} \
571    "Show the manual for the GnuPG Core"
572 LangString DESC_Menu_gnupg_manual ${LANG_GERMAN} \
573    "Das Handbuch zum GnuPG Kern anzeigen"
574
575 Section "-libgpg-error" SEC_libgpg_error
576   SetOutPath "$INSTDIR\bin"
577   File bin/libgpg-error-0.dll
578 SectionEnd
579
580 Section "-libiconv" SEC_libiconv
581   SetOutPath "$INSTDIR\bin"
582   File bin/libiconv-2.dll
583 SectionEnd
584
585 Section "-zlib" SEC_zlib
586   SetOutPath "$INSTDIR\bin"
587   File bin/zlib1.dll
588 SectionEnd
589
590 Section "-npth" SEC_npth
591   SetOutPath "$INSTDIR\bin"
592   File bin/libnpth-0.dll
593 SectionEnd
594
595 Section "-gcrypt" SEC_gcrypt
596   SetOutPath "$INSTDIR\bin"
597   File bin/libgcrypt-20.dll
598 SectionEnd
599
600 Section "-assuan" SEC_assuan
601   SetOutPath "$INSTDIR\bin"
602   File bin/libassuan-0.dll
603 SectionEnd
604
605 Section "-ksba" SEC_ksba
606   SetOutPath "$INSTDIR\bin"
607   File bin/libksba-8.dll
608 SectionEnd
609
610 Section "-gpgme" SEC_gpgme
611   SetOutPath "$INSTDIR\bin"
612   File bin/libgpgme-11.dll
613   File bin/libgpgme-glib-11.dll
614   File libexec/gpgme-w32spawn.exe
615 SectionEnd
616
617 Section "-gettext" SEC_gettext
618   SetOutPath "$INSTDIR\bin"
619   File bin/libintl-8.dll
620 SectionEnd
621
622 Section "-glib" SEC_glib
623   SetOutPath "$INSTDIR\bin"
624   File bin/libgio-2.0-0.dll
625   File bin/libglib-2.0-0.dll
626   File bin/libgmodule-2.0-0.dll
627   File bin/libgobject-2.0-0.dll
628   File bin/libgthread-2.0-0.dll
629   File bin/gspawn-win32-helper.exe
630   File bin/gspawn-win32-helper-console.exe
631
632   File bin/libffi-6.dll
633 SectionEnd
634
635 Section "-libpng" SEC_libpng
636   SetOutPath "$INSTDIR\bin"
637   File bin/libpng14-14.dll
638 SectionEnd
639
640 #Section "-jpeg" SEC_jpeg
641 #  SetOutPath "$INSTDIR"
642 #  File bin/jpeg62.dll
643 #SectionEnd
644
645 Section "-cairo" SEC_cairo
646   SetOutPath "$INSTDIR\bin"
647   File bin/libcairo-gobject-2.dll
648   File bin/libpangocairo-1.0-0.dll
649   File bin/libcairo-2.dll
650   File bin/libcairo-script-interpreter-2.dll
651 SectionEnd
652
653 Section "-pixman" SEC_pixman
654   SetOutPath "$INSTDIR\bin"
655   File bin/libpixman-1-0.dll
656 SectionEnd
657
658 Section "-pango" SEC_pango
659   SetOutPath "$INSTDIR\bin"
660   File bin/pango-querymodules.exe
661   File bin/libpango-1.0-0.dll
662   File bin/libpangowin32-1.0-0.dll
663
664   SetOutPath "$INSTDIR\lib\pango\1.6.0\modules"
665   File lib/pango/1.6.0/modules/pango-basic-win32.dll
666   File lib/pango/1.6.0/modules/pango-arabic-lang.dll
667   File lib/pango/1.6.0/modules/pango-indic-lang.dll
668
669   SetOutPath "$INSTDIR\etc\pango"
670   File ${W32_SRCDIR}/pango.modules
671 SectionEnd
672
673 Section "-atk" SEC_atk
674   SetOutPath "$INSTDIR\bin"
675   File bin/libatk-1.0-0.dll
676 SectionEnd
677
678 Section "-gtk+" SEC_gtk_
679   SetOutPath "$INSTDIR\bin"
680   File bin/libgdk_pixbuf-2.0-0.dll
681   File bin/libgdk-win32-2.0-0.dll
682   File bin/libgtk-win32-2.0-0.dll
683
684   SetOutPath "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0"
685   File /oname=loaders.cache ${W32_SRCDIR}/gdk-pixbuf-loaders.cache
686   SetOutPath "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders"
687   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-ani.dll
688   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-bmp.dll
689   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-emf.dll
690   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-gif.dll
691   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-ico.dll
692   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-jpeg.dll
693   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-tiff.dll
694   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-gdip-wmf.dll
695   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-icns.dll
696   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-pcx.dll
697   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-png.dll
698   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-pnm.dll
699   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-qtif.dll
700   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-ras.dll
701   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-tga.dll
702   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-wbmp.dll
703   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-xbm.dll
704   File lib/gdk-pixbuf-2.0/2.10.0/loaders/libpixbufloader-xpm.dll
705
706   SetOutPath "$INSTDIR\lib\gtk-2.0\2.10.0\engines"
707   File lib/gtk-2.0/2.10.0/engines/libwimp.dll
708   File lib/gtk-2.0/2.10.0/engines/libpixmap.dll
709
710   SetOutPath "$INSTDIR\lib\gtk-2.0\2.10.0\immodules"
711   File lib/gtk-2.0/2.10.0/immodules/im-thai.dll
712   File lib/gtk-2.0/2.10.0/immodules/im-cyrillic-translit.dll
713   File lib/gtk-2.0/2.10.0/immodules/im-multipress.dll
714   File lib/gtk-2.0/2.10.0/immodules/im-ti-er.dll
715   File lib/gtk-2.0/2.10.0/immodules/im-am-et.dll
716   File lib/gtk-2.0/2.10.0/immodules/im-cedilla.dll
717   File lib/gtk-2.0/2.10.0/immodules/im-inuktitut.dll
718   File lib/gtk-2.0/2.10.0/immodules/im-viqr.dll
719   File lib/gtk-2.0/2.10.0/immodules/im-ti-et.dll
720   File lib/gtk-2.0/2.10.0/immodules/im-ipa.dll
721   File lib/gtk-2.0/2.10.0/immodules/im-ime.dll
722
723   SetOutPath "$INSTDIR\share\themes\Default\gtk-2.0-key"
724   File share/themes/Default/gtk-2.0-key/gtkrc
725
726   SetOutPath "$INSTDIR\share\themes\MS-Windows\gtk-2.0"
727   File share/themes/MS-Windows/gtk-2.0/gtkrc
728
729   SetOutPath "$INSTDIR\etc\gtk-2.0"
730   File etc/gtk-2.0/im-multipress.conf
731 SectionEnd
732
733 Section "-pinentry" SEC_pinentry
734   SetOutPath "$INSTDIR\bin"
735   File /oname=pinentry.exe "bin/pinentry-gtk-2.exe"
736 SectionEnd
737
738 Section "gpa" SEC_gpa
739   SectionIn RO
740   SetOutPath "$INSTDIR\bin"
741   File bin/gpa.exe
742   File bin/launch-gpa.exe
743 SectionEnd
744
745 LangString DESC_SEC_gpa ${LANG_ENGLISH} \
746    "The GnuPG Assistant is the graphical interface of GnuPG"
747 LangString DESC_SEC_gpa ${LANG_GERMAN} \
748    "Der GnuPG Assistent ist die graphische Oberfläche von GnuPG."
749
750 LangString DESC_Menu_gpa ${LANG_ENGLISH} \
751    "Run the GnuGP Assistant."
752 LangString DESC_Menu_gpa ${LANG_GERMAN} \
753    "Den GnuPG Assistenten starten."
754
755 Section "gpgex" SEC_gpgex
756   SetOutPath "$INSTDIR\bin"
757
758   ClearErrors
759   SetOverwrite try
760   File bin/gpgex.dll
761   SetOverwrite lastused
762   ifErrors 0 do_reg
763       File /oname=gpgex.dll.tmp bin/gpgex.dll
764       Rename /REBOOTOK gpgex.dll.tmp gpgex.dll
765
766  do_reg:
767   ClearErrors
768   RegDLL "$INSTDIR\bin\gpgex.dll"
769   ifErrors 0 +2
770      MessageBox MB_OK "$(T_GPGEX_RegFailed)"
771
772 ${If} ${RunningX64}
773   # Install the 64 bit version of the plugin.
774   # Note that we install this in addition to the 32 bit version so that
775   # the 32 bit version can be used by file dialogs of 32 bit programs.
776   ClearErrors
777   SetOverwrite try
778   File /oname=gpgex6.dll "${INST6_DIR}/bin/gpgex.dll"
779   SetOverwrite lastused
780   ifErrors 0 do_reg64
781       File /oname=gpgex6.dll.tmp "${INST6_DIR}/bin/gpgex.dll"
782       Rename /REBOOTOK gpgex6.dll.tmp gpgex6.dll
783
784  do_reg64:
785   # Register the DLL. We need to register both versions.  However
786   # RegDLL can't be used for 64 bit and InstallLib seems to be a
787   # registry hack.
788   ClearErrors
789   ExecWait '"$SYSDIR\regsvr32" /s "$INSTDIR\bin\gpgex6.dll"'
790   ifErrors 0 +2
791      MessageBox MB_OK "$(T_GPGEX_RegFailed) (64 bit)"
792
793   # Note: There is no need to install the help an mo files because
794   # they are identical to those installed by the 32 bit version.
795 ${EndIf}
796 SectionEnd
797
798 LangString T_GPGEX_RegFailed ${LANG_ENGLISH} \
799    "Warning: Registration of the Explorer plugin failed."
800
801 LangString DESC_SEC_gpgex ${LANG_ENGLISH} \
802    "GnuPG Explorer Extension"
803
804
805 Section "-gnupglast" SEC_gnupglast
806   SetOutPath "$INSTDIR"
807 SectionEnd
808
809
810 #
811 # Define the uninstaller sections.
812 #
813 # (reverse order of the installer sections!)
814 #
815
816 Section "-un.gnupglast"
817   ifFileExists "$INSTDIR\bin\gpa.exe"  0 no_uiserver
818     ExecWait '"$INSTDIR\bin\gpa" --stop-server'
819   no_uiserver:
820   ifFileExists "$INSTDIR\bin\gpgconf.exe"  0 no_gpgconf
821     ExecWait '"$INSTDIR\bin\gpgconf" --kill gpg-agent'
822   no_gpgconf:
823 SectionEnd
824
825 Section "-un.gpgex"
826   UnRegDLL "$INSTDIR\bin\gpgex.dll"
827
828   Delete /REBOOTOK "$INSTDIR\bin\gpgex.dll"
829
830 ${If} ${RunningX64}
831   ExecWait '"$SYSDIR\regsvr32" /u /s "$INSTDIR\bin\gpgex6.dll"'
832   Delete /REBOOTOK "$INSTDIR\bin\gpgex6.dll"
833 ${EndIf}
834 SectionEnd
835
836
837 Section "-un.gpa"
838   Delete "$INSTDIR\bin\gpa.exe"
839   Delete "$INSTDIR\bin\launch-gpa.exe"
840
841   RMDir "$INSTDIR\share\gpa"
842 SectionEnd
843
844 Section "-un.pinentry"
845   Delete "$INSTDIR\bin\pinentry.exe"
846 SectionEnd
847
848
849 Section "-un.gtk+"
850   Delete "$INSTDIR\bin\libgdk_pixbuf-2.0-0.dll"
851   Delete "$INSTDIR\bin\libgdk-win32-2.0-0.dll"
852   Delete "$INSTDIR\bin\libgtk-win32-2.0-0.dll"
853
854   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders.cache"
855
856   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-ani.dll"
857   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-bmp.dll"
858   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-emf.dll"
859   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-gif.dll"
860   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-ico.dll"
861   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-jpeg.dll"
862   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-tiff.dll"
863   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-gdip-wmf.dll"
864   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-icns.dll"
865   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-pcx.dll"
866   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-png.dll"
867   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-pnm.dll"
868   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-qtif.dll"
869   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-ras.dll"
870   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-tga.dll"
871   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-wbmp.dll"
872   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-xbm.dll"
873   Delete "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders\libpixbufloader-xpm.dll"
874   RMDir  "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0\loaders"
875   RMDir  "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0"
876   RMDir  "$INSTDIR\lib\gdk-pixbuf-2.0"
877
878   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\engines\libwimp.dll"
879   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\engines\libpixmap.dll"
880   RMDir  "$INSTDIR\lib\gtk-2.0\2.10.0\engines"
881
882   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-thai.dll"
883   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-cyrillic-translit.dll"
884   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-multipress.dll"
885   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-ti-er.dll"
886   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-am-et.dll"
887   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-cedilla.dll"
888   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-inuktitut.dll"
889   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-viqr.dll"
890   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-ti-et.dll"
891   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-ipa.dll"
892   Delete "$INSTDIR\lib\gtk-2.0\2.10.0\immodules\im-ime.dll"
893   RMDir  "$INSTDIR\lib\gtk-2.0\2.10.0\immodules"
894
895   RMDir  "$INSTDIR\lib\gtk-2.0\2.10.0"
896   RMDir  "$INSTDIR\lib\gtk-2.0"
897
898   Delete "$INSTDIR\share\themes\Default\gtk-2.0-key\gtkrc"
899   RMDir  "$INSTDIR\share\themes\Default\gtk-2.0-key"
900   RMDir  "$INSTDIR\share\themes\Default"
901
902   Delete "$INSTDIR\share\themes\MS-Windows\gtk-2.0\gtkrc"
903   RMDir  "$INSTDIR\share\themes\MS-Windows\gtk-2.0"
904   RMDir  "$INSTDIR\share\themes\MS-Windows"
905
906   RMDir  "$INSTDIR\share\themes"
907
908   Delete "$INSTDIR\etc\gtk-2.0\im-multipress.conf"
909   RMDir  "$INSTDIR\etc\gtk-2.0"
910 SectionEnd
911
912 Section "-un.atk"
913   Delete "$INSTDIR\bin\libatk-1.0-0.dll"
914 SectionEnd
915
916 Section "-un.pango"
917   Delete "$INSTDIR\bin\pango-querymodules.exe"
918   Delete "$INSTDIR\bin\libpango-1.0-0.dll"
919   Delete "$INSTDIR\bin\libpangowin32-1.0-0.dll"
920
921   Delete "$INSTDIR\lib\pango\1.6.0\modules\pango-basic-win32.dll"
922   Delete "$INSTDIR\lib\pango\1.6.0\modules\pango-arabic-lang.dll"
923   Delete "$INSTDIR\lib\pango\1.6.0\modules\pango-indic-lang.dll"
924   RMDir  "$INSTDIR\lib\pango\1.6.0\modules"
925   RMDir  "$INSTDIR\lib\pango\1.6.0"
926   RMDir  "$INSTDIR\lib\pango"
927
928   Delete "$INSTDIR\etc\pango\pango.modules"
929   RMDir  "$INSTDIR\etc\pango"
930 SectionEnd
931
932 Section "-un.pixman"
933   Delete "$INSTDIR\bin\libpixman-1-0.dll"
934 SectionEnd
935
936 Section "-un.cairo"
937   Delete "$INSTDIR\bin\libcairo-gobject-2.dll"
938   Delete "$INSTDIR\bin\libpangocairo-1.0-0.dll"
939   Delete "$INSTDIR\bin\libcairo-2.dll"
940   Delete "$INSTDIR\bin\libcairo-script-interpreter-2.dll"
941 SectionEnd
942
943 Section "-un.libpng"
944   Delete "$INSTDIR\bin\libpng14-14.dll"
945 SectionEnd
946
947 Section "-un.glib"
948   Delete "$INSTDIR\bin\libgio-2.0-0.dll"
949   Delete "$INSTDIR\bin\libglib-2.0-0.dll"
950   Delete "$INSTDIR\bin\libgmodule-2.0-0.dll"
951   Delete "$INSTDIR\bin\libgobject-2.0-0.dll"
952   Delete "$INSTDIR\bin\libgthread-2.0-0.dll"
953   Delete "$INSTDIR\bin\gspawn-win32-helper.exe"
954   Delete "$INSTDIR\bin\gspawn-win32-helper-console.exe"
955   Delete "$INSTDIR\bin\libffi-6.dll"
956 SectionEnd
957
958 Section "-un.gettext"
959   Delete "$INSTDIR\bin\libintl-8.dll"
960 SectionEnd
961
962 Section "-un.gpgme"
963   Delete "$INSTDIR\bin\libgpgme-11.dll"
964   Delete "$INSTDIR\bin\libgpgme-glib-11.dll"
965   Delete "$INSTDIR\bin\gpgme-w32spawn.exe"
966 SectionEnd
967
968 Section "-un.ksba"
969   Delete "$INSTDIR\bin\libksba-8.dll"
970 SectionEnd
971
972 Section "-un.assuan"
973   Delete "$INSTDIR\bin\libassuan-0.dll"
974 SectionEnd
975
976 Section "-un.gcrypt"
977   Delete "$INSTDIR\bin\libgcrypt-20.dll"
978 SectionEnd
979
980 Section "-un.npth"
981   Delete "$INSTDIR\bin\libnpth-0.dll"
982 SectionEnd
983
984 Section "-un.zlib"
985   Delete "$INSTDIR\bin\zlib1.dll"
986 SectionEnd
987
988 Section "-un.libiconv"
989   Delete "$INSTDIR\bin\libiconv-2.dll"
990 SectionEnd
991
992 Section "-un.libgpg-error"
993   Delete "$INSTDIR\bin\libgpg-error-0.dll"
994 SectionEnd
995
996 Section "-un.gnupg"
997   Delete "$INSTDIR\bin\gpg.exe"
998   Delete "$INSTDIR\bin\gpgsm.exe"
999   Delete "$INSTDIR\bin\gpg-agent.exe"
1000   Delete "$INSTDIR\bin\gpgconf.exe"
1001   Delete "$INSTDIR\bin\gpg-connect-agent.exe"
1002
1003   Delete "$INSTDIR\share\gnupg\gpg-conf.skel"
1004   RMDir  "$INSTDIR\share\gnupg"
1005 SectionEnd
1006
1007 Section "-un.gnupginst"
1008   # Delete standard stuff.
1009   Delete "$INSTDIR\README.txt"
1010
1011   Delete "$INSTDIR\VERSION"
1012
1013   # Try to remove the top level directories.
1014   RMDir "$INSTDIR\bin"
1015   RMDir "$INSTDIR\lib"
1016   RMDir "$INSTDIR\share"
1017   RMDir "$INSTDIR\etc"
1018   RMDir "$INSTDIR"
1019
1020   # Clean the registry.
1021   DeleteRegValue HKLM "Software\GNU\GnuPG" "Install Directory"
1022 SectionEnd
1023
1024
1025 Function .onInit
1026   ;;!define MUI_LANGDLL_ALWAYSSHOW
1027   !insertmacro MUI_LANGDLL_DISPLAY
1028
1029   Call G4wRunOnce
1030
1031   SetOutPath $TEMP
1032 #!ifdef SOURCES
1033 #  File /oname=gpgspltmp.bmp "${TOP_SRCDIR}/doc/logo/gnupg-logo-400px.bmp"
1034 #  # We play the tune only for the soruce installer
1035 #  File /oname=gpgspltmp.wav "${TOP_SRCDIR}/src/gnupg-splash.wav"
1036 #  g4wihelp::playsound $TEMP\gpgspltmp.wav
1037 #  g4wihelp::showsplash 2500 $TEMP\gpgspltmp.bmp
1038
1039 #  Delete $TEMP\gpgspltmp.bmp
1040 #  # Note that we delete gpgspltmp.wav in .onInst{Failed,Success}
1041 #!endif
1042
1043   # We can't use TOP_SRCDIR dir as the name of the file needs to be
1044   # the same while building and running the installer.  Thus we
1045   # generate the file from a template.
1046   !insertmacro MUI_INSTALLOPTIONS_EXTRACT "${BUILD_DIR}/inst-options.ini"
1047
1048   #Call CalcDepends
1049 FunctionEnd
1050
1051
1052 #Function .onInstFailed
1053 #  Delete $TEMP\gpgspltmp.wav
1054 #FunctionEnd
1055
1056 #Function .onInstSuccess
1057 #  Delete $TEMP\gpgspltmp.wav
1058 #FunctionEnd
1059
1060 #Function .onSelChange
1061 #  Call CalcDepends
1062 #FunctionEnd
1063
1064
1065 # This must be in a central place.  Urgs.
1066
1067 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
1068 !insertmacro MUI_DESCRIPTION_TEXT ${SEC_gnupg} $(DESC_SEC_gnupg)
1069 !insertmacro MUI_DESCRIPTION_TEXT ${SEC_gpa}   $(DESC_SEC_gpa)
1070 !insertmacro MUI_DESCRIPTION_TEXT ${SEC_gpgex} $(DESC_SEC_gpgex)
1071 !insertmacro MUI_FUNCTION_DESCRIPTION_END
1072
1073
1074 # This also must be in a central place.  Also Urgs.
1075
1076 Section "-startmenu"
1077
1078 !ifdef HAVE_STARTMENU
1079   # Make sure that the context of the automatic variables has been set to
1080   # the "all users" shell folder.  This guarantees that the menu gets written
1081   # for all users.  We have already checked that we are running as Admin; or
1082   # we printed a warning that installation will not succeed.
1083   SetShellVarContext all
1084
1085   # Check if the start menu entries where requested.
1086   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "${BUILD_DIR}/inst-options.ini" \
1087         "Field 2" "State"
1088   IntCmp $R0 0 no_start_menu
1089
1090 !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
1091     CreateDirectory "$SMPROGRAMS\$STARTMENU_FOLDER"
1092
1093     SectionGetFlags ${SEC_gpa} $R0
1094     IntOp $R0 $R0 & ${SF_SELECTED}
1095     IntCmp $R0 ${SF_SELECTED} 0 no_gpa_menu
1096     CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GPA.lnk" \
1097         "$INSTDIR\bin\launch-gpa.exe" \
1098         "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gpa)
1099   no_gpa_menu:
1100
1101
1102     CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GnuPG Manual.lnk" \
1103                    "$INSTDIR\share\gnupg\gnupg.html" \
1104                    "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gnupg_manual)
1105
1106     CreateShortCut "$SMPROGRAMS\$STARTMENU_FOLDER\GnuPG README.lnk" \
1107                    "$INSTDIR\README.txt" \
1108                    "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gnupg_readme)
1109
1110 !insertmacro MUI_STARTMENU_WRITE_END
1111
1112
1113
1114 no_start_menu:
1115
1116
1117   # Check if the desktop entries where requested.
1118   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "${BUILD_DIR}/inst-options.ini" \
1119         "Field 3" "State"
1120   IntCmp $R0 0 no_desktop
1121
1122     SectionGetFlags ${SEC_gpa} $R0
1123     IntOp $R0 $R0 & ${SF_SELECTED}
1124     IntCmp $R0 ${SF_SELECTED} 0 no_gpa_desktop
1125     CreateShortCut "$DESKTOP\GPA.lnk" \
1126         "$INSTDIR\bin\launch-gpa.exe" \
1127         "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gpa)
1128   no_gpa_desktop:
1129
1130
1131     CreateShortCut "$DESKTOP\GPA Manual.lnk" \
1132                    "$INSTDIR\share\gpa\gpa.html" \
1133                    "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gpa_manual)
1134
1135 no_desktop:
1136
1137
1138   # Check if the quick launch bar entries where requested.
1139   !insertmacro MUI_INSTALLOPTIONS_READ $R0 "${BUILD_DIR}/inst-options.ini" \
1140         "Field 4" "State"
1141   IntCmp $R0 0 no_quick_launch
1142   StrCmp $QUICKLAUNCH $TEMP no_quick_launch
1143
1144     SectionGetFlags ${SEC_gpa} $R0
1145     IntOp $R0 $R0 & ${SF_SELECTED}
1146     IntCmp $R0 ${SF_SELECTED} 0 no_gpa_quicklaunch
1147     CreateShortCut "$QUICKLAUNCH\GPA.lnk" \
1148         "$INSTDIR\bin\launch-gpa.exe" \
1149         "" "" "" SW_SHOWNORMAL "" $(DESC_Menu_gpa)
1150 no_gpa_quicklaunch:
1151
1152
1153 no_quick_launch:
1154
1155
1156 !endif
1157 SectionEnd
1158
1159
1160
1161 #
1162 # Now for the generic parts to end the installation.
1163 #
1164 Var MYTMP
1165
1166 # Last section is a hidden one.
1167 Section
1168   WriteUninstaller "$INSTDIR\gnupg-uninstall.exe"
1169
1170   # Windows Add/Remove Programs support
1171   StrCpy $MYTMP "Software\Microsoft\Windows\CurrentVersion\Uninstall\GnuPG"
1172   WriteRegExpandStr HKLM $MYTMP "UninstallString" '"$INSTDIR\gnupg-uninstall.exe"'
1173   WriteRegExpandStr HKLM $MYTMP "InstallLocation" "$INSTDIR"
1174   WriteRegStr       HKLM $MYTMP "DisplayName"     "${PRETTY_PACKAGE}"
1175   WriteRegStr       HKLM $MYTMP "DisplayIcon"     "$INSTDIR\bin\gpa.exe,0"
1176   WriteRegStr       HKLM $MYTMP "DisplayVersion"  "${VERSION}"
1177   WriteRegStr       HKLM $MYTMP "Publisher"       "The GnuPG Project"
1178   WriteRegStr       HKLM $MYTMP "URLInfoAbout"    "https://gnupg.org"
1179   WriteRegDWORD     HKLM $MYTMP "NoModify"        "1"
1180   WriteRegDWORD     HKLM $MYTMP "NoRepair"        "1"
1181 SectionEnd
1182
1183
1184 Section Uninstall
1185
1186 !ifdef HAVE_STARTMENU
1187   # Make sure that the context of the automatic variables has been set to
1188   # the "all users" shell folder.  This guarantees that the menu gets written
1189   # for all users.  We have already checked that we are running as Admin; or
1190   # we printed a warning that installation will not succeed.
1191   SetShellVarContext all
1192
1193   #---------------------------------------------------
1194   # Delete the menu entries and any empty parent menus
1195   #---------------------------------------------------
1196   !insertmacro MUI_STARTMENU_GETFOLDER Application $MYTMP
1197   Delete "$SMPROGRAMS\$MYTMP\GPA.lnk"
1198   Delete "$SMPROGRAMS\$MYTMP\GnuPG Manual.lnk"
1199   Delete "$SMPROGRAMS\$MYTMP\GnuPG README.lnk"
1200   Delete "$SMPROGRAMS\$MYTMP\*.lnk"
1201   StrCpy $MYTMP "$SMPROGRAMS\$MYTMP"
1202   startMenuDeleteLoop:
1203     ClearErrors
1204     RMDir $MYTMP
1205     GetFullPathName $MYTMP "$MYTMP\.."
1206     IfErrors startMenuDeleteLoopDone
1207     StrCmp $MYTMP $SMPROGRAMS startMenuDeleteLoopDone startMenuDeleteLoop
1208   startMenuDeleteLoopDone:
1209
1210   DeleteRegValue HKLM "Software\GNU\GnuPG" "Start Menu Folder"
1211
1212   # Delete Desktop links.
1213   Delete "$DESKTOP\GPA.lnk"
1214   Delete "$DESKTOP\GnuPG Manual.lnk"
1215   Delete "$DESKTOP\GnuPG README.lnk"
1216
1217   # Delete Quick Launch Bar links.
1218   StrCmp $QUICKLAUNCH $TEMP no_quick_launch_uninstall
1219   Delete "$QUICKLAUNCH\GPA.lnk"
1220 no_quick_launch_uninstall:
1221
1222 !endif
1223
1224
1225   Delete "$INSTDIR\gnupg-uninstall.exe"
1226   RMDir "$INSTDIR"
1227
1228   # Clean the registry.
1229   DeleteRegValue HKLM "Software\GNU\GnuPG" "Install Directory"
1230   DeleteRegKey /ifempty HKLM "Software\GNU\GnuPG"
1231   # Remove Windows Add/Remove Programs support.
1232   DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\GnuPG"
1233 SectionEnd